tracker/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Alexander Fehr <pizzapunk gmail com>
   4
   5 pkgname=tracker
   6 pkgver=2.3.6+7+gb27396252
   7 pkgrel=3
   8 pkgdesc="Desktop-neutral user information store, search tool and indexer"
   9 url="https://wiki.gnome.org/Projects/Tracker"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(sqlite icu glib2 libffi util-linux libstemmer libseccomp libsoup
  13          json-glib upower libnm)
  14 makedepends=(gobject-introspection vala git bash-completion meson)
  15 checkdepends=(python-gobject python-dbus)
  16 provides=(libtracker-{control,miner,sparql}-2.0.so)
  17 groups=(gnome)
  18 _commit=b2739625209c564192b339814264084046e1cf17  # tracker-2.3
  19 source=("git+https://gitlab.gnome.org/GNOME/tracker.git#commit=$_commit"
  20         0001-libtracker-data-Workaround-SQLite-3.35.x-bug.patch)
  21 sha256sums=('SKIP'
  22             '00885d437f9257dbba0acad7bae0b9827c1ea09e3ff32727e3217469f3662920')
  23
  24 pkgver() {
  25   cd $pkgname
  26   git describe --tags | sed 's/_/./g;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd $pkgname
  31
  32   # https://gitlab.gnome.org/GNOME/tracker/-/merge_requests/382
  33   git apply -3 ../0001-libtracker-data-Workaround-SQLite-3.35.x-bug.patch
  34
  35   # test crashes meson: https://github.com/mesonbuild/meson/issues/8591
  36   sed -i '/tracker-steroids/d' tests/meson.build
  37 }
  38
  39 build() {
  40   arch-meson $pkgname build
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   dbus-run-session meson test -C build --print-errorlogs -t 3
  46 }
  47
  48 package() {
  49   DESTDIR="$pkgdir" meson install -C build
  50 }