gnome-settings-daemon/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-settings-daemon
   4 pkgver=43.0
   5 pkgrel=2
   6 pkgdesc="GNOME Settings Daemon"
   7 url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse
  11          libnotify systemd libwacom pulseaudio pulseaudio-alsa upower librsvg
  12          libgweather-4 geocode-glib-2 geoclue nss libgudev gtk3 libnm gcr-4)
  13 makedepends=(libxslt docbook-xsl python git meson usbguard)
  14 checkdepends=(python-gobject python-dbusmock)
  15 optdepends=('usbguard: USB protection support')
  16 groups=(gnome)
  17 backup=(etc/xdg/Xwayland-session.d/00-xrdb)
  18 _commit=7bde651053bdf18fe66cbd4ce697cb97a6ea556b  # tags/43.0^0
  19 source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git#commit=$_commit"
  20         "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
  21 sha256sums=('SKIP'
  22             'SKIP')
  23
  24 pkgver() {
  25   cd $pkgname
  26   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd $pkgname
  31
  32   git submodule init
  33   git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
  34   git -c protocol.file.allow=always submodule update
  35 }
  36
  37 build() {
  38   arch-meson $pkgname build
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   meson test -C build --print-errorlogs
  44 }
  45
  46 package() {
  47   meson install -C build --destdir "$pkgdir"
  48 }
  49
  50 # vim:set sw=2 sts=-1 et: