libnice/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3 # Contributor: William Díaz <wdiaz@archlinux.us>
   4
   5 pkgname=libnice
   6 pkgver=0.1.21
   7 pkgrel=1
   8 pkgdesc="An implementation of the IETF's draft ICE (for p2p UDP data streams)"
   9 url="https://nice.freedesktop.org"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glib2 gnutls gupnp-igd)
  13 makedepends=(gstreamer gtk-doc git meson gobject-introspection graphviz)
  14 optdepends=('gstreamer: "nice" GStreamer plugin')
  15 provides=(libnice.so)
  16 _commit=3d9cae16a5094aadb1651572644cb5786a8b4e2d  # tags/0.1.21^0
  17 source=("git+https://gitlab.freedesktop.org/libnice/libnice.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd libnice
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd libnice
  27 }
  28
  29 build() {
  30   arch-meson libnice build -D gtk_doc=enabled
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40 }
  41
  42 # vim:set sw=2 sts=-1 et: