polari/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=polari
   4 pkgver=43.0
   5 pkgrel=1
   6 pkgdesc="An IRC Client for GNOME"
   7 url="https://wiki.gnome.org/Apps/Polari"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(gjs gtk4 telepathy-glib telepathy-idle telepathy-mission-control
  11          telepathy-logger gspell libsoup3 libadwaita)
  12 makedepends=(gobject-introspection yelp-tools appstream-glib git meson)
  13 groups=(gnome-extra)
  14 _commit=0cf049c1c5704cf5fa0a4b80194860e2c4e433a9  # tags/43.0^0
  15 source=("git+https://gitlab.gnome.org/GNOME/polari.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd polari
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd polari
  25 }
  26
  27 build() {
  28   arch-meson polari build
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38 }
  39
  40 # vim:set sw=2 sts=-1 et: