enchant/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@gmail.com>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: dorphell <dorphell@archlinux.org>
   4
   5 pkgname=enchant
   6 pkgver=2.3.1
   7 pkgrel=2
   8 pkgdesc="A wrapper library for generic spell checking"
   9 arch=('x86_64')
  10 url="https://abiword.github.io/enchant/"
  11 license=('LGPL')
  12 depends=('glib2')
  13 makedepends=('aspell' 'hunspell' 'hspell' 'nuspell' 'libvoikko')
  14 checkdepends=('unittestpp')
  15 optdepends=('aspell: for aspell based spell checking support'
  16             'hunspell: for hunspell based spell checking support'
  17             'libvoikko: for libvoikko based spell checking support'
  18             'hspell: for hspell based spell checking support'
  19             'nuspell: for nuspell based spell checking support')
  20 provides=('libenchant-2.so') # enchant_voikko.so enchant_nuspell.so enchant_hunspell.so enchant_hspell.so enchant_aspell.so)
  21 source=("https://github.com/AbiWord/enchant/releases/download/v$pkgver/enchant-$pkgver.tar.gz")
  22 sha512sums=('c6fb8498d34a55040c2791124c2975952497e5a1b8999958691279b1a60a37473a1d2e3e11504f7cc877370be7772c2db621022040ea7035b21e40e8367606f5')
  23
  24 prepare() {
  25   cd $pkgname-$pkgver
  26   autoreconf -vfi
  27 }
  28
  29 build() {
  30   cd $pkgname-$pkgver
  31   ./configure --prefix=/usr \
  32     --disable-static \
  33     --enable-relocatable
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 check() {
  39   cd $pkgname-$pkgver
  40   make check
  41 }
  42
  43 package() {
  44   cd $pkgname-$pkgver
  45   make DESTDIR="$pkgdir" install
  46 }