mutt/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: tobias [tobias [at] archlinux.org]
   4
   5 pkgname=mutt
   6 pkgver=2.1.3
   7 pkgrel=1
   8 pkgdesc="Small but very powerful text-based mail client"
   9 url="http://www.mutt.org/"
  10 license=('GPL2')
  11 arch=('x86_64')
  12 depends=('gdbm' 'glibc' 'libgpg-error' 'openssl' 'libsasl' 'mime-types'
  13 'sqlite' 'zlib')
  14 makedepends=('docbook-xml' 'docbook-xsl' 'elinks' 'git' 'gpgme' 'krb5'
  15 'libidn2' 'lynx' 'ncurses' 'libxslt')
  16 optdepends=('perl: for smime_keys'
  17             'python: for experimental mutt_oath2.py'
  18             'smtp-forwarder: to send mail')
  19 backup=('etc/Muttrc')
  20 source=("git+https://gitlab.com/muttmua/${pkgname}.git#tag=${pkgname}-${pkgver//./-}-rel?signed")
  21 sha512sums=('SKIP')
  22 b2sums=('SKIP')
  23 validpgpkeys=('8975A9B33AA37910385C5308ADEF768480316BDA') # Kevin J. McCarthy <kevin@8t8.us>
  24
  25 prepare() {
  26   cd "${pkgname}"
  27   autoreconf -fiv
  28 }
  29
  30 build() {
  31   cd "${pkgname}"
  32   ./configure --prefix=/usr \
  33               --sysconfdir=/etc \
  34               --enable-debug \
  35               --enable-gpgme \
  36               --enable-pop \
  37               --enable-imap \
  38               --enable-smtp \
  39               --enable-hcache \
  40               --enable-sidebar \
  41               --enable-autocrypt \
  42               --with-curses=/usr \
  43               --with-gss=/usr \
  44               --with-ssl=/usr \
  45               --with-sqlite3 \
  46               --with-sasl \
  47               --with-idn2
  48   make
  49 }
  50
  51 package() {
  52   depends+=('libgpgme.so' 'libgssapi_krb5.so' 'libidn2.so' 'libncursesw.so')
  53
  54   cd "${pkgname}"
  55   make DESTDIR="${pkgdir}" install
  56   install -vDm 644 contrib/gpg.rc "${pkgdir}/etc/Muttrc.gpg.dist"
  57
  58   # /etc/mime.types is provided by mailcap
  59   rm "${pkgdir}"/etc/mime.types{,.dist}
  60 }