gnome-console/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>
   3 # Contributor: Igor Dyatlov <dyatlov.igor@gmail.com>
   4
   5 pkgname=gnome-console
   6 pkgver=43.0
   7 pkgrel=1
   8 pkgdesc="A simple user-friendly terminal emulator for the GNOME desktop"
   9 url="https://gitlab.gnome.org/GNOME/console"
  10 arch=(x86_64)
  11 license=(GPL3)
  12 depends=(libgtop libadwaita vte4)
  13 makedepends=(appstream-glib git meson)
  14 groups=(gnome)
  15 options=(debug)
  16 _commit=cffddb1a7bbf8ad1b1616cc026909411e218db1a  # tags/43.0^0
  17 source=("$pkgname::git+https://gitlab.gnome.org/GNOME/console.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   local meson_options=(
  31     -D tests=true
  32   )
  33
  34   arch-meson $pkgname build "${meson_options[@]}"
  35   meson compile -C build
  36 }
  37
  38 check() {
  39   meson test -C build --print-errorlogs
  40 }
  41
  42 package() {
  43   meson install -C build --destdir "$pkgdir"
  44 }
  45
  46 # vim:set sw=2 sts=-1 et: