xfwm4/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: tobias <tobias funnychar archlinux.org>
   3
   4 pkgname=xfwm4
   5 pkgver=4.16.1
   6 pkgrel=3
   7 pkgdesc="Xfce's window manager"
   8 arch=('x86_64')
   9 url="https://docs.xfce.org/xfce/xfwm4/start"
  10 license=('GPL2')
  11 groups=('xfce4')
  12 depends=('libxfce4ui' 'xfconf' 'libwnck3' 'libepoxy' 'libxpresent'
  13          'hicolor-icon-theme')
  14 makedepends=('intltool')
  15 source=(https://archive.xfce.org/src/xfce/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2
  16         client-Handle-removal-of-GTK_FRAME_EXTENTS.patch)
  17 sha256sums=('b5b24ca04bd73c642db0a4b4df81d262381d758f01b51108257d48b391b8718c'
  18             'cc49d8c0932dc3f630073e87c8fffaddd811306dc32d74a8127fe0de7baccd4d')
  19
  20 prepare() {
  21   cd "$srcdir/$pkgname-$pkgver"
  22   # https://gitlab.xfce.org/xfce/xfwm4/-/issues/603
  23   patch -Np1 -i ../client-Handle-removal-of-GTK_FRAME_EXTENTS.patch
  24 }
  25
  26 build() {
  27   cd "$srcdir/$pkgname-$pkgver"
  28
  29   ./configure \
  30     --prefix=/usr \
  31     --sysconfdir=/etc \
  32     --libexecdir=/usr/lib \
  33     --localstatedir=/var \
  34     --disable-static \
  35     --enable-startup-notification \
  36     --enable-randr \
  37     --enable-compositor \
  38     --enable-xsync \
  39     --disable-debug
  40   make
  41 }
  42
  43 package() {
  44   cd "$srcdir/$pkgname-$pkgver"
  45   make DESTDIR="$pkgdir" install
  46 }
  47
  48 # vim:set ts=2 sw=2 et: