folks/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=folks
   5 pkgver=0.15.3+6+gdb1de866
   6 pkgrel=1
   7 pkgdesc="Library to aggregates people into metacontacts"
   8 arch=(x86_64)
   9 url="https://wiki.gnome.org/Projects/Folks"
  10 license=(LGPL2.1)
  11 depends=(libgee libxml2 evolution-data-server)
  12 makedepends=(gobject-introspection gtk-doc vala git meson python-dbusmock)
  13 provides=(libfolks.so libfolks-{dummy,eds}.so)
  14 _commit=db1de866217d98f6b25edc92ca54d82c4dc082a8  # master
  15 source=("git+https://gitlab.gnome.org/GNOME/folks.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25 }
  26
  27 build() {
  28   local meson_args=(
  29     -D b_lto=false  # LTO copies some GType constructors
  30     -D docs=true
  31     -D telepathy_backend=false
  32   )
  33   arch-meson $pkgname build "${meson_args[@]}"
  34   meson compile -C build
  35 }
  36
  37 check() {
  38   meson test -C build --print-errorlogs -t 4
  39 }
  40
  41 package() {
  42   meson install -C build --destdir "$pkgdir"
  43 }
  44
  45 # vim:set sw=2 et: