mutt/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: tobias [tobias [at] archlinux.org]
   4
   5 pkgname=mutt
   6 pkgver=2.1.4
   7 pkgrel=1
   8 pkgdesc="Small but very powerful text-based mail client"
   9 arch=(x86_64)
  10 url="http://www.mutt.org/"
  11 license=(GPL2)
  12 depends=(gdbm glibc libgpg-error openssl libsasl mime-types sqlite zlib)
  13 makedepends=(docbook-xml docbook-xsl elinks git gpgme krb5 libidn2 libxslt lynx
  14 ncurses)
  15 optdepends=(
  16   'perl: for smime_keys'
  17   'python: for experimental mutt_oath2.py'
  18   'smtp-forwarder: to send mail'
  19 )
  20 backup=(etc/Muttrc)
  21 source=("git+https://gitlab.com/muttmua/${pkgname}.git#tag=${pkgname}-${pkgver//./-}-rel?signed")
  22 sha512sums=('SKIP')
  23 b2sums=('SKIP')
  24 validpgpkeys=('8975A9B33AA37910385C5308ADEF768480316BDA') # Kevin J. McCarthy <kevin@8t8.us>
  25
  26 prepare() {
  27   cd "${pkgname}"
  28   autoreconf -fiv
  29 }
  30
  31 build() {
  32   cd "${pkgname}"
  33   ./configure --prefix=/usr \
  34               --sysconfdir=/etc \
  35               --enable-debug \
  36               --enable-gpgme \
  37               --enable-pop \
  38               --enable-imap \
  39               --enable-smtp \
  40               --enable-hcache \
  41               --enable-sidebar \
  42               --enable-autocrypt \
  43               --with-curses=/usr \
  44               --with-gss=/usr \
  45               --with-ssl=/usr \
  46               --with-sqlite3 \
  47               --with-sasl \
  48               --with-idn2
  49   make
  50 }
  51
  52 package() {
  53   depends+=(libgpgme.so libgssapi_krb5.so libidn2.so libncursesw.so)
  54
  55   cd "${pkgname}"
  56   make DESTDIR="${pkgdir}" install
  57   install -vDm 644 contrib/gpg.rc "${pkgdir}/etc/Muttrc.gpg.dist"
  58
  59   # /etc/mime.types is provided by mailcap
  60   rm "${pkgdir}"/etc/mime.types{,.dist}
  61 }