usbutils/repos/core-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3 # Contributor: Tom Gundersen <teg@jklm.no>
   4 # Contributor: Judd Vinet <jvinet@zeroflux.org>
   5 # Contributor: Curtis Campbell <curtisjamescampbell@hotmail.com>
   6
   7 pkgname=usbutils
   8 pkgver=014
   9 pkgrel=1
  10 pkgdesc="A collection of USB tools to query connected USB devices"
  11 arch=('x86_64')
  12 url="https://git.kernel.org/pub/scm/linux/kernel/git/gregkh/usbutils.git/"
  13 license=('GPL2' 'GPL3')
  14 depends=('glibc' 'hwids')
  15 makedepends=('libusb' 'systemd')
  16 optdepends=('python: for lsusb.py usage'
  17             'coreutils: for lsusb.py usage')
  18 source=("https://www.kernel.org/pub/linux/utils/usb/usbutils/${pkgname}-${pkgver}.tar"{.xz,.sign})
  19 sha512sums=('43c9f6ed14f8d01e014ef39a5d50b3b09031c6bda8261e0945b4cb4287c9107104175b386c2adc61dc7f9f476afb30f9a647a6ece6dee26b4133a4f10af72792'
  20             'SKIP')
  21 b2sums=('aea4f8edd3c7d7bc400fd63a8702b6d0bb50b8ed07196c4a0ed20a615eacf6373794afb9e7d5d81408dc3382848e965ecf8bc1bbec20837e4d1f96ba47cc40b5'
  22         'SKIP')
  23 validpgpkeys=('647F28654894E3BD457199BE38DBBDC86092693E') # Greg Kroah-Hartman <gregkh@linuxfoundation.org>
  24
  25 prepare() {
  26   cd "$pkgname-$pkgver"
  27   autoreconf -fiv
  28 }
  29
  30 build() {
  31   cd "$pkgname-$pkgver"
  32   ./configure --prefix=/usr \
  33               --datadir=/usr/share/hwdata
  34   make
  35 }
  36
  37 package() {
  38   depends+=('libusb-1.0.so' 'libudev.so')
  39   cd "$pkgname-$pkgver"
  40   make DESTDIR="$pkgdir" install
  41   install -vDm 644 NEWS -t "${pkgdir}/usr/share/doc/${pkgname}/"
  42 }