folks/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=folks
   5 pkgver=0.15.5
   6 pkgrel=2
   7 pkgdesc="Library to aggregates people into metacontacts"
   8 arch=(x86_64)
   9 url="https://wiki.gnome.org/Projects/Folks"
  10 license=(LGPL)
  11 depends=(libgee libxml2 evolution-data-server)
  12 makedepends=(gobject-introspection gtk-doc vala git meson python-dbusmock)
  13 provides=(libfolks.so libfolks-{dummy,eds}.so)
  14 options=(!lto debug)
  15 _commit=c75c2a55f171ec778a78d3d510add6993b353487  # tags/0.15.5^0
  16 source=("git+https://gitlab.gnome.org/GNOME/folks.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd folks
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd folks
  26
  27   # Fix bindings
  28   git cherry-pick -n fe4ee7e7857ad73b3e4503ad626f7d8aa070b3cd
  29
  30   # python-dbusmock API change
  31   git cherry-pick -n b6b7d41aad9e36e0d0e6ec9822ed2e310923c8fd
  32 }
  33
  34 build() {
  35   local meson_options=(
  36     -D b_lto=false  # LTO copies some GType constructors
  37     -D docs=true
  38     -D telepathy_backend=false
  39   )
  40
  41   arch-meson folks build "${meson_options[@]}"
  42   meson compile -C build
  43 }
  44
  45 check() {
  46   meson test -C build --print-errorlogs -t 4
  47 }
  48
  49 package() {
  50   meson install -C build --destdir "$pkgdir"
  51 }
  52
  53 # vim:set sw=2 sts=-1 et: