latex2rtf/trunk/PKGBUILD

   1 # Maintainer: Rémy Oudompheng <remy@archlinux.org>
   2 # Contributor: John Proctor <jproctor@prium.net>
   3
   4 pkgname=latex2rtf
   5 pkgver=2.3.18
   6 pkgrel=1
   7 pkgdesc="LaTeX to RTF converter"
   8 arch=('x86_64')
   9 url="http://latex2rtf.sourceforge.net/"
  10 license=('GPL')
  11 depends=('glibc' 'imagemagick' 'ghostscript')
  12 makedepends=('texinfo' 'texlive-bin' 'texlive-plainextra')
  13 checkdepends=('texlive-latexextra') # for a4wide package
  14 source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}a.tar.gz")
  15 md5sums=('b984073a9481eae26760ce03015d0373')
  16 sha1sums=('7fe41c82465921405bbbc6667694bf2731c7dfd1')
  17
  18 build() {
  19   cd "${srcdir}/${pkgname}-${pkgver}"
  20   make PREFIX=/usr latex2rtf
  21 }
  22
  23 check() {
  24   cd "${srcdir}/${pkgname}-${pkgver}"
  25   sed -i 's,s/\\\\,s/\\\\\\,' test/bracecheck
  26   chmod u+x test/bracecheck
  27   RTFPATH="$PWD"/cfg make check
  28 }
  29
  30 package() {
  31   cd "${srcdir}/${pkgname}-${pkgver}"
  32   make DESTDIR="${pkgdir}" PREFIX=/usr install install-info
  33   chmod 755 "${pkgdir}/usr/bin/latex2png"
  34   sed -i -e 's|error "no input file specified"| echo "error: no input file specified"|' "${pkgdir}/usr/bin/latex2png"
  35 }