seahorse-nautilus/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=seahorse-nautilus
   5 pkgver=3.11.92+66+g02c81f1
   6 pkgrel=1
   7 pkgdesc="PGP encryption and signing for nautilus"
   8 arch=(x86_64)
   9 url="https://gitlab.gnome.org/GNOME/seahorse-nautilus.git/"
  10 license=(GPL)
  11 depends=(libcryptui nautilus libgnome-keyring)
  12 makedepends=(meson git)
  13 _commit=02c81f1dda64571f837fc2cc9180fe2a86d8d8b6  # master
  14 source=("git+https://gitlab.gnome.org/GNOME/seahorse-nautilus.git#commit=$_commit"
  15         1.patch)
  16 sha256sums=('SKIP'
  17             '7e27ab3bc132bc3c3039da1490c1a972297469b97caeb7236a01779933251a47')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26
  27   # https://bugs.archlinux.org/task/61061
  28   # https://gitlab.gnome.org/GNOME/seahorse-nautilus/merge_requests/1
  29   git apply -3 ../1.patch
  30 }
  31
  32 build() {
  33   arch-meson $pkgname build
  34   ninja -C build
  35 }
  36
  37 package() {
  38   DESTDIR="$pkgdir" meson install -C build
  39 }