system-config-printer/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3
   4 pkgname=system-config-printer
   5 pkgver=1.5.16
   6 pkgrel=1
   7 pkgdesc="A CUPS printer configuration tool and status applet"
   8 url="https://github.com/OpenPrinting/system-config-printer"
   9 arch=('x86_64')
  10 license=('GPL')
  11 depends=('python-pycups' 'python-dbus' 'python-pycurl' 'libnotify'
  12          'python-gobject' 'gtk3' 'python-cairo')
  13 makedepends=('xmlto' 'docbook-xsl' 'desktop-file-utils' 'libsecret')
  14 optdepends=('libsecret: password management'
  15             'python-pysmbc: SMB browser support'
  16             'cups-pk-helper: PolicyKit helper to configure cups with fine-grained privileges')
  17 source=(https://github.com/OpenPrinting/system-config-printer/releases/download/v${pkgver}/system-config-printer-${pkgver}.tar.xz #{,.asc}
  18 )
  19 sha256sums=('cbca8409947e4f17877106989aa61ad02bb696c7207c6c353b8815e9e2db37fd')
  20 #            'SKIP')
  21 #validpgpkeys=('7ADB58203CA5F046F28025B215AA6A7F4D4227D7') # "Zdenek Dohnal (Associate Software Engineer) <zdohnal@redhat.com>"
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25
  26   ./configure --prefix=/usr \
  27     --sbindir=/usr/bin \
  28     --sysconfdir=/etc \
  29     --with-systemdsystemunitdir=/usr/lib/systemd/system \
  30     --with-udevdir=/usr/lib/udev \
  31     --with-udev-rules
  32   make
  33 }
  34
  35 package() {
  36   cd ${pkgname}-${pkgver}
  37   make DESTDIR="$pkgdir" install
  38
  39   # Compile *.pyc
  40   find "$pkgdir" -name '*.py' -exec python -mpy_compile {} +
  41   # Compile *.pyo
  42   find "$pkgdir" -name '*.py' -exec python -O -mpy_compile {} +
  43
  44   # fix dbus policy location
  45   install -dm755 "$pkgdir"/usr/share/dbus-1/system.d
  46   mv "$pkgdir"/etc/dbus-1/system.d/* "$pkgdir"/usr/share/dbus-1/system.d
  47   rm -rf "$pkgdir"/etc/dbus-1
  48 }