pango/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=pango
   5 pkgname=(pango pango-docs)
   6 pkgver=1.50.8
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="A library for layout and rendering of text"
  10 url="https://www.pango.org/"
  11 arch=(x86_64)
  12 license=(LGPL)
  13 depends=(libthai cairo libxft harfbuzz fribidi)
  14 makedepends=(gobject-introspection help2man git meson gi-docgen)
  15 options=(debug)
  16 _commit=641d8a2b056621fd1f1d5d58e6a9e4dbdfe8e7ae  # tags/1.50.8^0
  17 source=("git+https://gitlab.gnome.org/GNOME/pango.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd pango
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd pango
  27 }
  28
  29 build() {
  30   arch-meson pango build -D gtk_doc=true
  31   meson compile -C build
  32 }
  33
  34 # not running checks: validation breaks when deps
  35 # (especially harfbuzz) don't match upstream CI
  36
  37 package_pango() {
  38   provides=(libpango{,cairo,ft2,xft}-1.0.so)
  39
  40   meson install -C build --destdir "$pkgdir"
  41
  42   mkdir -p doc/usr/share
  43   mv {"$pkgdir",doc}/usr/share/doc
  44 }
  45
  46 package_pango-docs() {
  47   pkgdesc+=" (documentation)"
  48   depends=()
  49
  50   mv doc/* "$pkgdir"
  51 }
  52
  53 # vim:set sw=2 et: