compiler-rt/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
   3
   4 pkgname=compiler-rt
   5 pkgver=13.0.1
   6 pkgrel=1
   7 pkgdesc="Compiler runtime libraries for clang"
   8 arch=('x86_64')
   9 url="https://compiler-rt.llvm.org/"
  10 license=('custom:Apache 2.0 with LLVM Exception')
  11 depends=('gcc-libs')
  12 makedepends=('llvm' 'cmake' 'ninja' 'python')
  13 # Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
  14 makedepends_x86_64=('lib32-gcc-libs')
  15 options=('staticlibs')
  16 _source_base=https://github.com/llvm/llvm-project/releases/download/llvmorg-$pkgver
  17 source=($_source_base/$pkgname-$pkgver.src.tar.xz{,.sig})
  18 sha256sums=('7b33955031f9a9c5d63077dedb0f99d77e4e7c996266952c1cec55626dca5dfc'
  19             'SKIP')
  20 validpgpkeys+=('B6C8F98282B944E3B0D5C2530FC3042E345AD05D') # Hans Wennborg <hans@chromium.org>
  21 validpgpkeys+=('474E22316ABF4785A88C6E8EA2C794A986419D8A') # Tom Stellard <tstellar@redhat.com>
  22
  23 prepare() {
  24   cd "$srcdir/$pkgname-$pkgver.src"
  25   mkdir build
  26 }
  27
  28 build() {
  29   cd "$srcdir/$pkgname-$pkgver.src/build"
  30
  31   cmake .. -G Ninja \
  32     -DCMAKE_BUILD_TYPE=Release \
  33     -DCMAKE_INSTALL_PREFIX=/usr \
  34     -DCMAKE_SKIP_RPATH=ON \
  35     -DCOMPILER_RT_INSTALL_PATH=/usr/lib/clang/$pkgver
  36   ninja
  37 }
  38
  39 package() {
  40   cd "$srcdir/$pkgname-$pkgver.src/build"
  41
  42   DESTDIR="$pkgdir" ninja install
  43   install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  44 }
  45
  46 # vim:set ts=2 sw=2 et: