system-config-printer/trunk/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3
   4 pkgname=system-config-printer
   5 pkgver=1.5.15
   6 pkgrel=2
   7 pkgdesc="A CUPS printer configuration tool and status applet"
   8 url="https://github.com/OpenPrinting/system-config-printer"
   9 arch=('x86_64')
  10 license=('GPL')
  11 depends=('python-pycups' 'python-dbus' 'python-pycurl' 'libnotify'
  12          'python-requests' 'python-gobject' 'gtk3' 'python-cairo')
  13 makedepends=('intltool' 'xmlto' 'docbook-xsl' 'desktop-file-utils' 'libsecret')
  14 optdepends=('libsecret: password management'
  15             'python-pysmbc: SMB browser support'
  16             'cups-pk-helper: PolicyKit helper to configure cups with fine-grained privileges')
  17 source=(https://github.com/OpenPrinting/system-config-printer/releases/download/v${pkgver}/system-config-printer-${pkgver}.tar.xz{,.asc})
  18 sha256sums=('fbd226ce215bf014213dded81b43b9d4d90470524f5bf7cd21ecc71d4aefa689'
  19             'SKIP')
  20 validpgpkeys=('7ADB58203CA5F046F28025B215AA6A7F4D4227D7') # "Zdenek Dohnal (Associate Software Engineer) <zdohnal@redhat.com>"
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24
  25   ./configure --prefix=/usr \
  26     --sbindir=/usr/bin \
  27     --sysconfdir=/etc \
  28     --with-systemdsystemunitdir=/usr/lib/systemd/system \
  29     --with-udevdir=/usr/lib/udev \
  30     --with-udev-rules
  31   make
  32 }
  33
  34 package() {
  35   cd ${pkgname}-${pkgver}
  36   make DESTDIR="$pkgdir" install
  37
  38   # Compile *.pyc
  39   find "$pkgdir" -name '*.py' -exec python -mpy_compile {} +
  40   # Compile *.pyo
  41   find "$pkgdir" -name '*.py' -exec python -O -mpy_compile {} +
  42
  43   # fix dbus policy location
  44   install -dm755 "$pkgdir"/usr/share/dbus-1/system.d
  45   mv "$pkgdir"/etc/dbus-1/system.d/* "$pkgdir"/usr/share/dbus-1/system.d
  46   rm -rf "$pkgdir"/etc/dbus-1
  47 }