gjs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=gjs
   5 pkgver=1.76.0
   6 pkgrel=1
   7 epoch=2
   8 pkgdesc="Javascript Bindings for GNOME"
   9 url="https://wiki.gnome.org/Projects/Gjs"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(
  13   cairo
  14   dconf
  15   gobject-introspection-runtime
  16   js102
  17   libsysprof-capture
  18   readline
  19 )
  20 makedepends=(
  21   dbus
  22   git
  23   gobject-introspection
  24   meson
  25 )
  26 checkdepends=(
  27   gtk3
  28   gtk4
  29   xorg-server-xvfb
  30 )
  31 provides=(libgjs.so)
  32 _commit=ff2e1b2f15cf246eb391a356a0ac0ea09fafc2e6  # tags/1.76.0^0
  33 source=("git+https://gitlab.gnome.org/GNOME/gjs.git#commit=$_commit")
  34 sha256sums=('SKIP')
  35
  36 pkgver() {
  37   cd gjs
  38   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  39 }
  40
  41 prepare() {
  42   cd gjs
  43 }
  44
  45 build() {
  46   local meson_options=(
  47     -D installed_tests=false
  48   )
  49
  50   CFLAGS="${CFLAGS/-O2/-O3} -fno-semantic-interposition"
  51   CXXFLAGS="${CXXFLAGS/-O2/-O3} -fno-semantic-interposition"
  52   LDFLAGS+=" -Wl,-Bsymbolic-functions"
  53
  54   arch-meson gjs build "${meson_options[@]}"
  55   meson compile -C build
  56 }
  57
  58 check() {
  59   dbus-run-session xvfb-run -s '-nolisten local' \
  60     meson test -C build --print-errorlogs
  61 }
  62
  63 package() {
  64   depends+=(libreadline.so)
  65   meson install -C build --destdir "$pkgdir"
  66 }
  67
  68 # vim:set sw=2 sts=-1 et: