hwloc/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   3 # Contributor: Sylvain HENRY <hsyl20@yahoo.fr>
   4 # Contributor: Hervé YVIQUEL <elldekaa@gmail.com>
   5
   6 pkgname=hwloc
   7 pkgver=2.8.0
   8 pkgrel=1
   9 pkgdesc='Portable Hardware Locality is a portable abstraction of hierarchical architectures'
  10 url='https://www.open-mpi.org/projects/hwloc/'
  11 arch=('x86_64')
  12 license=('BSD')
  13 depends=('glibc' 'libtool' 'systemd-libs' 'libpciaccess')
  14 makedepends=('cairo' 'libxml2' 'pciutils' 'systemd' 'libx11')
  15 optdepends=('cairo' 'libxml2' 'pciutils' 'libx11')
  16 options=('!docs')
  17 source=(https://www.open-mpi.org/software/hwloc/v${pkgver%.*}/downloads/${pkgname}-${pkgver}.tar.bz2)
  18 sha512sums=('025c8ebc2945bdf696cc66fe2cfea0195694713a6098603fb4eaeac409d2f6c3386a7c2b4d7f3758d828f6b621e7f06ffb5745224cb1df2f8ff4f19b2a8a4a7b')
  19 b2sums=('33f75987ee904d5ee9c62268695a2f7f59b0adc2e1601fc4407f525664b78a7fab04c75823ce9d190c8cb9ffc0ce983d7137555625d47bc1451a2d0c6f330055')
  20
  21 build() {
  22   cd hwloc-${pkgver}
  23   ./configure \
  24     --prefix=/usr \
  25     --sbindir=/usr/bin \
  26     --enable-plugins \
  27     --sysconfdir=/etc
  28   make
  29 }
  30
  31 check() {
  32   cd hwloc-${pkgver}
  33   make check
  34 }
  35
  36 package() {
  37   cd hwloc-${pkgver}
  38   make DESTDIR="${pkgdir}" install
  39   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  40 }
  41
  42 # vim: ts=2 sw=2 et: