gupnp/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: György Balló <ballogy@freestart.hu>
   3
   4 pkgname=gupnp
   5 pkgver=1.4.3
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc="An object-oriented UPNP framework"
   9 url="https://wiki.gnome.org/Projects/GUPnP"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glib2 gssdp util-linux libxml2)
  13 makedepends=(gobject-introspection gtk-doc vala meson git)
  14 optdepends=('python: gupnp-binding-tool')
  15 _commit=1e752b11dc51673c71c70bbf6deb34c96e3abd19  # tags/gupnp-1.4.3^0
  16 source=("git+https://gitlab.gnome.org/GNOME/gupnp.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd gupnp
  21   git describe --tags | sed 's/^gupnp-//;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd gupnp
  26
  27   # Unbreak man page build
  28   git revert -n 8795626a07963a91400773cfe04d4f2f1c37ff14
  29 }
  30
  31 build() {
  32   arch-meson gupnp build -D gtk_doc=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   depends+=(libg{lib,object,io,module}-2.0.so libgssdp-1.2.so libsoup-2.4.so
  42             libuuid.so)
  43   provides+=(libgupnp-1.2.so)
  44
  45   meson install -C build --destdir "$pkgdir"
  46 }