lightdm/trunk/PKGBUILD

   1 # Maintainer: Maxime Gauduin <alucryd@archlinux.org>
   2 # Contributor: Morfeo <morfeo89@hotmail.it>
   3
   4 pkgbase=lightdm
   5 pkgname=(
   6   lightdm
   7   liblightdm-qt5
   8 )
   9 pkgver=1.30.0
  10 pkgrel=4
  11 epoch=1
  12 pkgdesc='A lightweight display manager'
  13 arch=(x86_64)
  14 url=https://github.com/canonical/lightdm
  15 license=(
  16   GPL3
  17   LGPL3
  18 )
  19 makedepends=(
  20   glib2
  21   git
  22   gobject-introspection
  23   gtk-doc
  24   intltool
  25   itstool
  26   libgcrypt
  27   libx11
  28   libxcb
  29   libxdmcp
  30   libxklavier
  31   pam
  32   polkit
  33   qt5-base
  34   vala
  35   yelp-tools
  36 )
  37 source=(
  38   git+https://github.com/CanonicalLtd/lightdm.git?signed#tag=${pkgver}
  39   lightdm.service
  40   lightdm.sysusers
  41   lightdm.tmpfiles
  42   lightdm.pam
  43   lightdm-autologin.pam
  44   lightdm.rules
  45   lightdm-default-config.patch
  46   Xsession
  47 )
  48 validpgpkeys=(497851B5D455C606543F2B9318EAA1890F7C882E) # Robert Ancell <robert.ancell@gmail.com>
  49 sha256sums=('SKIP'
  50             '0db37a14521be729411a767f157fbd07adb738b14006277def53a1efe4dacfb8'
  51             'fd93291bfc9985f0a1bb288472866aa0a9bcd259e024c3a29d20ca158bc08403'
  52             'cd69f928a1a5b30a30ba916e1b64c9f3657597cb28f3f0e220494d6e5e4bf587'
  53             'e8c4c5fd3b801a390d201166fd1fb9730e78a5c62928768103b870b6bd980ea0'
  54             'e111a484f98c1449e1cf10c31532748d98e850eff1ab9f3a3b8eec485f44198f'
  55             'a89566307e1c81c24f037d854cbd472d2f94f8a4b759877a01563a332319f7d6'
  56             '782a52dc39a7d6f2c6ee31e66897e3502fc14864e3e4ede8e3d1a0da74b8dfdf'
  57             'd30321a1b490500483b8ed7825fcff2c24a7c760ac627789ff517693888ec3c5')
  58
  59 prepare() {
  60   cd lightdm
  61
  62   patch -Np1 -i ../lightdm-default-config.patch
  63
  64   NOCONFIGURE=1 ./autogen.sh
  65 }
  66
  67 build() {
  68   cd lightdm
  69
  70   export MOC5=moc-qt5
  71
  72   ./configure \
  73     --prefix=/usr \
  74     --libexecdir=/usr/lib/lightdm \
  75     --localstatedir=/var \
  76     --sbindir=/usr/bin \
  77     --sysconfdir=/etc \
  78     --disable-static \
  79     --disable-tests \
  80     --enable-gtk-doc \
  81     --with-greeter-user=lightdm \
  82     --with-greeter-session=lightdm-gtk-greeter
  83   make
  84 }
  85
  86 package_lightdm() {
  87   depends=(
  88     glib2
  89     libgcrypt
  90     libx11
  91     libxcb
  92     libxdmcp
  93     libxklavier
  94     pam
  95     polkit
  96   )
  97   optdepends=(
  98     'accountsservice: Enhanced user accounts handling'
  99     'lightdm-gtk-greeter: GTK greeter'
 100     'xorg-server-xephyr: LightDM test mode'
 101   )
 102   backup=(
 103     etc/apparmor.d/lightdm-guest-session
 104     etc/lightdm/keys.conf
 105     etc/lightdm/lightdm.conf
 106     etc/lightdm/users.conf
 107     etc/lightdm/Xsession
 108     etc/pam.d/lightdm
 109     etc/pam.d/lightdm-autologin
 110     etc/pam.d/lightdm-greeter
 111   )
 112
 113   cd lightdm
 114
 115   make DESTDIR="${pkgdir}" install
 116   make DESTDIR="${pkgdir}" -C liblightdm-qt uninstall
 117   install -m 755 ../Xsession "${pkgdir}"/etc/lightdm/Xsession
 118   rm -rf "${pkgdir}"/etc/init
 119   rm -rf "${pkgdir}"/usr/include/lightdm-qt{,5}-*
 120
 121   # Dbus
 122   mv "${pkgdir}"/{etc,usr/share}/dbus-1/system.d
 123   rmdir "${pkgdir}"/etc/dbus-1
 124
 125   # PAM
 126   install -m 644 ../lightdm.pam "${pkgdir}"/etc/pam.d/lightdm
 127   install -m 644 ../lightdm-autologin.pam "${pkgdir}"/etc/pam.d/lightdm-autologin
 128
 129   # PolicyKit
 130   install -dm 750 -g 102 "${pkgdir}"/usr/share/polkit-1/rules.d
 131   install -m 644 ../lightdm.rules "${pkgdir}"/usr/share/polkit-1/rules.d/lightdm.rules
 132
 133   # Systemd
 134   install -dm 755 "${pkgdir}"/usr/lib/{systemd/system,sysusers.d,tmpfiles.d}
 135   install -m 644 ../lightdm.service "${pkgdir}"/usr/lib/systemd/system/lightdm.service
 136   install -m 644 ../lightdm.sysusers "${pkgdir}"/usr/lib/sysusers.d/lightdm.conf
 137   install -m 644 ../lightdm.tmpfiles "${pkgdir}"/usr/lib/tmpfiles.d/lightdm.conf
 138 }
 139
 140 package_liblightdm-qt5() {
 141   pkgdesc='LightDM Qt client library'
 142   depends=(
 143     lightdm
 144     qt5-base
 145   )
 146   options=(!emptydirs)
 147
 148   cd lightdm
 149
 150   make DESTDIR="${pkgdir}" -C liblightdm-gobject install
 151   make DESTDIR="${pkgdir}" -C liblightdm-qt install
 152   make DESTDIR="${pkgdir}" -C liblightdm-gobject uninstall
 153   find "${pkgdir}" -type d -name *qt[!5]* -exec rm -rf {} +
 154   find "${pkgdir}" -type f  -name *qt[!5]* -exec rm {} +
 155   find "${pkgdir}" -type l  -name *qt[!5]* -exec rm {} +
 156 }
 157
 158 # vim: ts=2 sw=2 et: