gdb/testsuite/gdb.dwarf2/implref-array.exp

   1 # Copyright 2016-2023 Free Software Foundation, Inc.
   2
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Test a C++ reference marked with DW_OP_GNU_implicit_pointer.
  17 # The referenced value is a global array whose location is a DW_OP_addr.
  18
  19 if [skip_cplus_tests] {
  20     return
  21 }
  22
  23 load_lib dwarf.exp
  24
  25 # This test can only be run on targets which support DWARF-2 and use gas.
  26 if ![dwarf2_support] {
  27     return 0
  28 }
  29
  30 # We'll place the output of Dwarf::assemble in implref-array.S.
  31 standard_testfile .c .S
  32
  33 # ${testfile} is now "implref-array".  srcfile2 is "implref-array.S".
  34 set executable ${testfile}
  35 set asm_file [standard_output_file ${srcfile2}]
  36
  37 # We need to know the size of integer and address types in order
  38 # to write some of the debugging info we'd like to generate.
  39 #
  40 # For that, we ask GDB by debugging our implref-array program.
  41 # Any program would do, but since we already have implref-array
  42 # specifically for this testcase, might as well use that.
  43 if { [prepare_for_testing "failed to prepare" ${testfile} ${srcfile}] } {
  44     return -1
  45 }
  46
  47 set array_length [get_valueof "/u" "sizeof(array) / sizeof(array\[0\])" -1]
  48
  49 # Create the DWARF.  We need a regular variable which represents the array, and
  50 # a reference to it that'll be marked with DW_OP_GNU_implicit_pointer.
  51 # The variable must be global so that its name is an exported symbol that we
  52 # can reference from the DWARF using gdb_target_symbol.
  53 Dwarf::assemble ${asm_file} {
  54     global array_length
  55
  56     cu {} {
  57         DW_TAG_compile_unit {
  58             {DW_AT_language @DW_LANG_C_plus_plus}
  59         } {
  60             declare_labels int_label sizetype_label array_label variable_label ref_label
  61             set int_size [get_sizeof "int" -1]
  62             set upper_bound [expr ${array_length} - 1]
  63
  64             # gdb always assumes references are implemented as pointers.
  65             set addr_size [get_sizeof "void *" -1]
  66
  67             int_label: DW_TAG_base_type {
  68                 {DW_AT_byte_size ${int_size} DW_FORM_udata}
  69                 {DW_AT_encoding @DW_ATE_signed}
  70                 {DW_AT_name "int"}
  71             }
  72
  73             sizetype_label: DW_TAG_base_type {
  74                 {DW_AT_byte_size ${int_size} DW_FORM_udata}
  75                 {DW_AT_encoding @DW_ATE_unsigned}
  76                 {DW_AT_name "sizetype"}
  77             }
  78
  79             array_label: DW_TAG_array_type {
  80                     {DW_AT_type :${int_label}}
  81             } {
  82                 DW_TAG_subrange_type {
  83                     {DW_AT_type :${sizetype_label}}
  84                     {DW_AT_lower_bound 0 DW_FORM_udata}
  85                     {DW_AT_upper_bound ${upper_bound} DW_FORM_udata}
  86                 }
  87             }
  88
  89             ref_label: DW_TAG_reference_type {
  90                 {DW_AT_byte_size ${addr_size} DW_FORM_udata}
  91                 {DW_AT_type :${array_label}}
  92             }
  93
  94             variable_label: DW_TAG_variable {
  95                 {DW_AT_name "array"}
  96                 {DW_AT_type :${array_label}}
  97                 {DW_AT_external 1 DW_FORM_flag}
  98                 {DW_AT_location {DW_OP_addr [gdb_target_symbol "array"]} SPECIAL_expr}
  99             }
 100
 101             DW_TAG_subprogram {
 102                 {MACRO_AT_func { "main" }}
 103                 {DW_AT_type :${int_label}}
 104                 {DW_AT_external 1 DW_FORM_flag}
 105             } {
 106                 DW_TAG_variable {
 107                     {DW_AT_name "ref"}
 108                     {DW_AT_type :${ref_label}}
 109                     {DW_AT_location {DW_OP_GNU_implicit_pointer ${variable_label} 0} SPECIAL_expr}
 110                 }
 111             }
 112         }
 113     }
 114 }
 115
 116 if [prepare_for_testing "failed to prepare" ${executable} [list ${asm_file} ${srcfile}] {}] {
 117     return -1
 118 }
 119
 120 # DW_OP_GNU_implicit_pointer implementation requires a valid frame.
 121 if ![runto_main] {
 122     return -1
 123 }
 124
 125 # This matches e.g. '(int (&)[5])'
 126 set ref_type [format {\(int \(&\)\[%d\]\)} ${array_length}]
 127
 128 # This matches e.g. '(int (*)[5])'
 129 set ptr_type [format {\(int \(\*\)\[%d\]\)} ${array_length}]
 130
 131 # Contents of the array.  Trim leading/trailing whitespace, '{' and '}'
 132 # since they confuse TCL to no end.
 133 set contents [get_valueof "" "array" ""]
 134 set contents [string trim ${contents}]
 135 set contents [string trim ${contents} "{}"]
 136
 137 # Address of the referenced value.
 138 set address [get_hexadecimal_valueof "&array" ""]
 139
 140 # Doing 'print ref' should show us e.g. '(int (&)[5]) 0xdeadbeef: {0, 1, 2, 3, 4}'.
 141 gdb_test "print ref" " = ${ref_type} @${address}: \\{${contents}\\}"
 142
 143 # Doing 'print &ref' should show us e.g. '(int (*)[5]) 0xdeadbeef <array>'.
 144 gdb_test "print &ref" " = ${ptr_type} ${address} <array>"
 145
 146 # gdb assumes C++ references are implemented as pointers, and print &(&ref)
 147 # shows us the underlying pointer's address.  Since in this case there's no
 148 # physical pointer, gdb should tell us so.
 149 gdb_test "print &(&ref)" "Attempt to take address of value not located in memory."
 150
 151 # Test assignment through the synthetic reference.
 152 set first_value 10
 153 gdb_test_no_output "set (ref\[0\] = ${first_value})"
 154
 155 # This matches '{10, 1, 2, 3, 4}'.
 156 set new_contents [format {\{%d, 1, 2, 3, 4\}} ${first_value}]
 157
 158 # Doing 'print ref' should now show us e.g.
 159 # '(int (&)[5]) <synthetic pointer>: {10, 1, 2, 3, 4}'.
 160 gdb_test "print ref" " = ${ref_type} @${address}: ${new_contents}" "print ref after assignment"
 161 gdb_test "print array" " = ${new_contents}" "print array after assignment"
 162
 163 # Test treating the array as a pointer.
 164 set second_value 20
 165 set new_contents [format {\{%d, %d, 2, 3, 4\}} ${first_value} ${second_value}]
 166
 167 gdb_test "print *ref" " = ${first_value}"
 168 gdb_test_no_output "set (*(ref + 1) = ${second_value})"
 169 gdb_test "print ref\[1\]" " = ${second_value}"
 170 gdb_test "print array" " = ${new_contents}" "print array after second assignment"