ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 AM_BINUTILS_WARNINGS
  70
  71 AM_CONFIG_HEADER(config.h:config.in)
  72
  73 if test -z "$target" ; then
  74     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  75 fi
  76 if test -z "$host" ; then
  77     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  78 fi
  79
  80 # host-specific stuff:
  81
  82 AC_PROG_CC
  83 AC_PROG_INSTALL
  84
  85 ALL_LINGUAS="fr sv tr es da vi zh_CN"
  86 CY_GNU_GETTEXT
  87
  88 AC_EXEEXT
  89
  90 AC_PROG_YACC
  91 AM_PROG_LEX
  92
  93 AM_MAINTAINER_MODE
  94
  95 . ${srcdir}/configure.host
  96
  97 AC_SUBST(HDEFINES)
  98 AC_SUBST(HOSTING_CRT0)
  99 AC_SUBST(HOSTING_LIBS)
 100 AC_SUBST(NATIVE_LIB_DIRS)
 101
 102 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h)
 103 AC_CHECK_FUNCS(sbrk realpath glob)
 104 AC_HEADER_DIRENT
 105
 106 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 107 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 108 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 109 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 110 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 111 if test $ld_cv_decl_getopt_unistd_h = yes; then
 112   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 113             [Is the prototype for getopt in <unistd.h> in the expected format?])
 114 fi
 115
 116 BFD_BINARY_FOPEN
 117
 118 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 119
 120 # When converting linker scripts into strings for use in emulation
 121 # files, use astring.sed if the compiler supports ANSI string
 122 # concatenation, or ostring.sed otherwise.  This is to support the
 123 # broken Microsoft MSVC compiler, which limits the length of string
 124 # constants, while still supporting pre-ANSI compilers which do not
 125 # support string concatenation.
 126 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 127 AC_CACHE_VAL(ld_cv_string_concatenation,
 128 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 129   [ld_cv_string_concatenation=yes],
 130   [ld_cv_string_concatenation=no])])
 131 AC_MSG_RESULT($ld_cv_string_concatenation)
 132 if test "$ld_cv_string_concatenation" = "yes"; then
 133   STRINGIFY=astring.sed
 134 else
 135   STRINGIFY=ostring.sed
 136 fi
 137 AC_SUBST(STRINGIFY)
 138
 139 # target-specific stuff:
 140
 141 all_targets=
 142 EMUL=
 143 all_emuls=
 144 all_emul_extras=
 145 all_libpath=
 146
 147 dnl We need to get an arbitrary number of tdir definitions into
 148 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 149 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 150 dnl file.
 151 rm -f tdirs
 152
 153 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 154 do
 155   if test "$targ_alias" = "all"; then
 156     all_targets=true
 157   else
 158     # Canonicalize the secondary target names.
 159     result=`$ac_config_sub $targ_alias 2>/dev/null`
 160     if test -n "$result"; then
 161         targ=$result
 162     else
 163         targ=$targ_alias
 164     fi
 165
 166     . ${srcdir}/configure.tgt
 167
 168     if test "$targ" = "$target"; then
 169       EMUL=$targ_emul
 170     fi
 171
 172     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 173         case " $all_emuls " in
 174         *" e${i}.o "*) ;;
 175         *)
 176           all_emuls="$all_emuls e${i}.o"
 177           eval result=\$tdir_$i
 178           test -z "$result" && result=$targ_alias
 179           echo tdir_$i=$result >> tdirs
 180           ;;
 181         esac
 182     done
 183
 184     for i in $targ_emul $targ_extra_libpath; do
 185         case " $all_libpath " in
 186         *" ${i} "*) ;;
 187         *)
 188           if test -z "$all_libpath"; then
 189             all_libpath=${i}
 190           else
 191             all_libpath="$all_libpath ${i}"
 192           fi
 193           ;;
 194         esac
 195     done
 196
 197     for i in $targ_extra_ofiles; do
 198         case " $all_emul_extras " in
 199         *" ${i} "*) ;;
 200         *)
 201           all_emul_extras="$all_emul_extras ${i}"
 202           ;;
 203         esac
 204     done
 205   fi
 206 done
 207
 208 AC_SUBST(EMUL)
 209
 210 TDIRS=tdirs
 211 AC_SUBST_FILE(TDIRS)
 212
 213 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 214 dnl target, and in those cases we should also build the 64 bit
 215 dnl emulations.
 216 if test x${all_targets} = xtrue; then
 217   if test x${want64} = xtrue; then
 218     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 219   else
 220     EMULATION_OFILES='$(ALL_EMULATIONS)'
 221   fi
 222   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 223 else
 224   EMULATION_OFILES=$all_emuls
 225   EMUL_EXTRA_OFILES=$all_emul_extras
 226 fi
 227 AC_SUBST(EMULATION_OFILES)
 228 AC_SUBST(EMUL_EXTRA_OFILES)
 229 AC_SUBST(LIB_PATH)
 230
 231 EMULATION_LIBPATH=$all_libpath
 232 AC_SUBST(EMULATION_LIBPATH)
 233
 234 if test x${enable_static} = xno; then
 235   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 236 else
 237   TESTBFDLIB="../bfd/.libs/libbfd.a"
 238 fi
 239 AC_SUBST(TESTBFDLIB)
 240
 241 target_vendor=${target_vendor=$host_vendor}
 242 case "$target_vendor" in
 243   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 244   *)  EXTRA_SHLIB_EXTENSION= ;;
 245 esac
 246
 247 case "$target_os" in
 248   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 249 esac
 250
 251 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 252   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 253    [Additional extension a shared object might have.])
 254 fi
 255
 256 dnl Required by html and install-html
 257 AC_SUBST(datarootdir)
 258 AC_SUBST(docdir)
 259 AC_SUBST(htmldir)
 260
 261 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 262 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])