ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.13)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 build_warnings="-W -Wall -Wstrict-prototypes -Wmissing-prototypes"
  70
  71 AC_ARG_ENABLE(werror,
  72   [  --enable-werror    treat compile warnings as errors],
  73   [case "${enableval}" in
  74      yes | y) ERROR_ON_WARNING="yes" ;;
  75      no | n)  ERROR_ON_WARNING="no" ;;
  76      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  77    esac])
  78
  79 # Enable -Werror by default, suppressing it only for --disable-werror
  80 # or --disable-build-warnings.
  81 if test "${ERROR_ON_WARNING}" != no
  82 then
  83   build_warnings="$build_warnings -Werror"
  84 fi
  85
  86 AC_ARG_ENABLE(build-warnings,
  87 [  --enable-build-warnings enable build-time compiler warnings if gcc is used],
  88 [case "${enableval}" in
  89   yes)  ;;
  90   no)   build_warnings="-w";;
  91   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  92         build_warnings="${build_warnings} ${t}";;
  93   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  94         build_warnings="${t} ${build_warnings}";;
  95   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  96 esac
  97 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  98   echo "Setting warning flags = $build_warnings" 6>&1
  99 fi])dnl
 100 WARN_CFLAGS=""
 101 if test "x${build_warnings}" != x -a "x$GCC" = xyes ; then
 102     WARN_CFLAGS="${build_warnings}"
 103 fi
 104 AC_SUBST(WARN_CFLAGS)
 105
 106 AM_CONFIG_HEADER(config.h:config.in)
 107
 108 if test -z "$target" ; then
 109     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 110 fi
 111 if test -z "$host" ; then
 112     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 113 fi
 114
 115 # host-specific stuff:
 116
 117 AC_PROG_CC
 118 AC_PROG_INSTALL
 119
 120 ALL_LINGUAS="fr sv tr es da"
 121 CY_GNU_GETTEXT
 122
 123 AC_EXEEXT
 124
 125 AC_PROG_YACC
 126 AM_PROG_LEX
 127
 128 AM_MAINTAINER_MODE
 129
 130 . ${srcdir}/configure.host
 131
 132 AC_SUBST(HDEFINES)
 133 AC_SUBST(HOSTING_CRT0)
 134 AC_SUBST(HOSTING_LIBS)
 135 AC_SUBST(NATIVE_LIB_DIRS)
 136
 137 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
 138 AC_CHECK_FUNCS(sbrk realpath glob)
 139 AC_HEADER_DIRENT
 140
 141 BFD_BINARY_FOPEN
 142
 143 BFD_NEED_DECLARATION(strstr)
 144 BFD_NEED_DECLARATION(free)
 145 BFD_NEED_DECLARATION(sbrk)
 146 BFD_NEED_DECLARATION(getenv)
 147 BFD_NEED_DECLARATION(environ)
 148
 149 # When converting linker scripts into strings for use in emulation
 150 # files, use astring.sed if the compiler supports ANSI string
 151 # concatenation, or ostring.sed otherwise.  This is to support the
 152 # broken Microsoft MSVC compiler, which limits the length of string
 153 # constants, while still supporting pre-ANSI compilers which do not
 154 # support string concatenation.
 155 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 156 AC_CACHE_VAL(ld_cv_string_concatenation,
 157 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 158   [ld_cv_string_concatenation=yes],
 159   [ld_cv_string_concatenation=no])])
 160 AC_MSG_RESULT($ld_cv_string_concatenation)
 161 if test "$ld_cv_string_concatenation" = "yes"; then
 162   STRINGIFY=astring.sed
 163 else
 164   STRINGIFY=ostring.sed
 165 fi
 166 AC_SUBST(STRINGIFY)
 167
 168 # target-specific stuff:
 169
 170 all_targets=
 171 EMUL=
 172 all_emuls=
 173 all_emul_extras=
 174 all_libpath=
 175
 176 dnl We need to get an arbitrary number of tdir definitions into
 177 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 178 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 179 dnl file.
 180 rm -f tdirs
 181
 182 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 183 do
 184   if test "$targ_alias" = "all"; then
 185     all_targets=true
 186   else
 187     # Canonicalize the secondary target names.
 188     result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ_alias 2>/dev/null`
 189     if test -n "$result"; then
 190         targ=$result
 191     else
 192         targ=$targ_alias
 193     fi
 194
 195     . ${srcdir}/configure.tgt
 196
 197     if test "$targ" = "$target"; then
 198       EMUL=$targ_emul
 199     fi
 200
 201     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 202         case " $all_emuls " in
 203         *" e${i}.o "*) ;;
 204         *)
 205           all_emuls="$all_emuls e${i}.o"
 206           eval result=\$tdir_$i
 207           test -z "$result" && result=$targ_alias
 208           echo tdir_$i=$result >> tdirs
 209           ;;
 210         esac
 211     done
 212
 213     for i in $targ_emul $targ_extra_libpath; do
 214         case " $all_libpath " in
 215         *" ${i} "*) ;;
 216         *)
 217           if test -z "$all_libpath"; then
 218             all_libpath=${i}
 219           else
 220             all_libpath="$all_libpath ${i}"
 221           fi
 222           ;;
 223         esac
 224     done
 225
 226     for i in $targ_extra_ofiles; do
 227         case " $all_emul_extras " in
 228         *" ${i} "*) ;;
 229         *)
 230           all_emul_extras="$all_emul_extras ${i}"
 231           ;;
 232         esac
 233     done
 234   fi
 235 done
 236
 237 AC_SUBST(EMUL)
 238
 239 TDIRS=tdirs
 240 AC_SUBST_FILE(TDIRS)
 241
 242 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 243 dnl target, and in those cases we should also build the 64 bit
 244 dnl emulations.
 245 if test x${all_targets} = xtrue; then
 246   if test x${want64} = xtrue; then
 247     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 248   else
 249     EMULATION_OFILES='$(ALL_EMULATIONS)'
 250   fi
 251   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 252 else
 253   EMULATION_OFILES=$all_emuls
 254   EMUL_EXTRA_OFILES=$all_emul_extras
 255 fi
 256 AC_SUBST(EMULATION_OFILES)
 257 AC_SUBST(EMUL_EXTRA_OFILES)
 258 AC_SUBST(LIB_PATH)
 259
 260 EMULATION_LIBPATH=$all_libpath
 261 AC_SUBST(EMULATION_LIBPATH)
 262
 263 if test x${enable_static} = xno; then
 264   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 265 else
 266   TESTBFDLIB="../bfd/.libs/libbfd.a"
 267 fi
 268 AC_SUBST(TESTBFDLIB)
 269
 270 target_vendor=${target_vendor=$host_vendor}
 271 case "$target_vendor" in
 272   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 273   *)  EXTRA_SHLIB_EXTENSION= ;;
 274 esac
 275
 276 case "$target_os" in
 277   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 278 esac
 279
 280 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 281   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 282    [Additional extension a shared object might have.])
 283 fi
 284
 285 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 286 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])