ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 AM_BINUTILS_WARNINGS
  70
  71 AM_CONFIG_HEADER(config.h:config.in)
  72
  73 if test -z "$target" ; then
  74     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  75 fi
  76 if test -z "$host" ; then
  77     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  78 fi
  79
  80 # host-specific stuff:
  81
  82 AC_PROG_CC
  83 AC_PROG_INSTALL
  84
  85 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga"
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87 AM_PO_SUBDIRS
  88
  89 AC_EXEEXT
  90
  91 AC_PROG_YACC
  92 AM_PROG_LEX
  93
  94 AM_MAINTAINER_MODE
  95 AM_CONDITIONAL(GENINSRC_NEVER, false)
  96
  97 . ${srcdir}/configure.host
  98
  99 AC_SUBST(HDEFINES)
 100 AC_SUBST(HOSTING_CRT0)
 101 AC_SUBST(HOSTING_LIBS)
 102 AC_SUBST(NATIVE_LIB_DIRS)
 103
 104 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h sys/param.h)
 105 AC_CHECK_FUNCS(sbrk realpath glob)
 106 AC_HEADER_DIRENT
 107
 108 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 109 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 110 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 111 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 112 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 113 if test $ld_cv_decl_getopt_unistd_h = yes; then
 114   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 115             [Is the prototype for getopt in <unistd.h> in the expected format?])
 116 fi
 117
 118 BFD_BINARY_FOPEN
 119
 120 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 121
 122 # When converting linker scripts into strings for use in emulation
 123 # files, use astring.sed if the compiler supports ANSI string
 124 # concatenation, or ostring.sed otherwise.  This is to support the
 125 # broken Microsoft MSVC compiler, which limits the length of string
 126 # constants, while still supporting pre-ANSI compilers which do not
 127 # support string concatenation.
 128 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 129 AC_CACHE_VAL(ld_cv_string_concatenation,
 130 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 131   [ld_cv_string_concatenation=yes],
 132   [ld_cv_string_concatenation=no])])
 133 AC_MSG_RESULT($ld_cv_string_concatenation)
 134 if test "$ld_cv_string_concatenation" = "yes"; then
 135   STRINGIFY=astring.sed
 136 else
 137   STRINGIFY=ostring.sed
 138 fi
 139 AC_SUBST(STRINGIFY)
 140
 141 # target-specific stuff:
 142
 143 all_targets=
 144 EMUL=
 145 all_emuls=
 146 all_emul_extras=
 147 all_libpath=
 148
 149 dnl We need to get an arbitrary number of tdir definitions into
 150 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 151 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 152 dnl file.
 153 rm -f tdirs
 154
 155 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 156 do
 157   if test "$targ_alias" = "all"; then
 158     all_targets=true
 159   else
 160     # Canonicalize the secondary target names.
 161     result=`$ac_config_sub $targ_alias 2>/dev/null`
 162     if test -n "$result"; then
 163         targ=$result
 164     else
 165         targ=$targ_alias
 166     fi
 167
 168     . ${srcdir}/configure.tgt
 169
 170     if test "$targ" = "$target"; then
 171       EMUL=$targ_emul
 172     fi
 173
 174     if test x${want64} = xfalse; then
 175       . ${srcdir}/../bfd/config.bfd
 176     fi
 177
 178     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 179         case " $all_emuls " in
 180         *" e${i}.o "*) ;;
 181         *)
 182           all_emuls="$all_emuls e${i}.o"
 183           eval result=\$tdir_$i
 184           test -z "$result" && result=$targ_alias
 185           echo tdir_$i=$result >> tdirs
 186           ;;
 187         esac
 188     done
 189
 190     for i in $targ_emul $targ_extra_libpath; do
 191         case " $all_libpath " in
 192         *" ${i} "*) ;;
 193         *)
 194           if test -z "$all_libpath"; then
 195             all_libpath=${i}
 196           else
 197             all_libpath="$all_libpath ${i}"
 198           fi
 199           ;;
 200         esac
 201     done
 202
 203     for i in $targ_extra_ofiles; do
 204         case " $all_emul_extras " in
 205         *" ${i} "*) ;;
 206         *)
 207           all_emul_extras="$all_emul_extras ${i}"
 208           ;;
 209         esac
 210     done
 211   fi
 212 done
 213
 214 AC_SUBST(EMUL)
 215
 216 TDIRS=tdirs
 217 AC_SUBST_FILE(TDIRS)
 218
 219 if test x${all_targets} = xtrue; then
 220   if test x${want64} = xfalse; then
 221     AC_CHECK_SIZEOF(long)
 222     if test "x${ac_cv_sizeof_long}" = "x8"; then
 223       want64=true
 224     fi
 225   fi
 226   if test x${want64} = xtrue; then
 227     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 228   else
 229     EMULATION_OFILES='$(ALL_EMULATIONS)'
 230   fi
 231   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 232 else
 233   EMULATION_OFILES=$all_emuls
 234   EMUL_EXTRA_OFILES=$all_emul_extras
 235 fi
 236 AC_SUBST(EMULATION_OFILES)
 237 AC_SUBST(EMUL_EXTRA_OFILES)
 238 AC_SUBST(LIB_PATH)
 239
 240 EMULATION_LIBPATH=$all_libpath
 241 AC_SUBST(EMULATION_LIBPATH)
 242
 243 if test x${enable_static} = xno; then
 244   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 245 else
 246   TESTBFDLIB="../bfd/.libs/libbfd.a"
 247 fi
 248 AC_SUBST(TESTBFDLIB)
 249
 250 target_vendor=${target_vendor=$host_vendor}
 251 case "$target_vendor" in
 252   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 253   *)  EXTRA_SHLIB_EXTENSION= ;;
 254 esac
 255
 256 case "$target_os" in
 257   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 258 esac
 259
 260 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 261   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 262    [Additional extension a shared object might have.])
 263 fi
 264
 265 dnl Required by html and install-html
 266 AC_SUBST(datarootdir)
 267 AC_SUBST(docdir)
 268 AC_SUBST(htmldir)
 269
 270 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)