ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREQ(2.57)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7 AC_ISC_POSIX
   8
   9 changequote(,)dnl
  10 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  11 changequote([,])dnl
  12 AM_INIT_AUTOMAKE(ld, ${BFD_VERSION})
  13
  14 AM_PROG_LIBTOOL
  15
  16 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  17 AC_ARG_ENABLE(targets,
  18 [  --enable-targets        alternative target configurations],
  19 [case "${enableval}" in
  20   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  21             ;;
  22   no)       enable_targets= ;;
  23   *)        enable_targets=$enableval ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(64-bit-bfd,
  26 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  27 [case "${enableval}" in
  28   yes)  want64=true  ;;
  29   no)   want64=false ;;
  30   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  31 esac],[want64=false])dnl
  32
  33 AC_ARG_WITH(sysroot,
  34 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  35 [
  36  case ${with_sysroot} in
  37  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  38  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  39  esac
  40
  41  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  42  use_sysroot=yes
  43
  44  if test "x$exec_prefix" = xNONE; then
  45   if test "x$prefix" = xNONE; then
  46    test_prefix=/usr/local
  47   else
  48    test_prefix=$prefix
  49   fi
  50  else
  51   test_prefix=$exec_prefix
  52  fi
  53  case ${TARGET_SYSTEM_ROOT} in
  54  "${test_prefix}"|"${test_prefix}/"*|\
  55  '${exec_prefix}'|'${exec_prefix}/'*)
  56    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  57    TARGET_SYSTEM_ROOT_DEFINE="$t"
  58    ;;
  59  esac
  60 ], [
  61  use_sysroot=no
  62  TARGET_SYSTEM_ROOT=
  63  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  64 ])
  65 AC_SUBST(use_sysroot)
  66 AC_SUBST(TARGET_SYSTEM_ROOT)
  67 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  68
  69 AM_BINUTILS_WARNINGS
  70
  71 AM_CONFIG_HEADER(config.h:config.in)
  72
  73 if test -z "$target" ; then
  74     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  75 fi
  76 if test -z "$host" ; then
  77     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  78 fi
  79
  80 # host-specific stuff:
  81
  82 AC_PROG_CC
  83 AC_PROG_INSTALL
  84
  85 ALL_LINGUAS="fr sv tr es da vi zh_CN"
  86 ZW_GNU_GETTEXT_SISTER_DIR
  87 AM_PO_SUBDIRS
  88
  89 AC_EXEEXT
  90
  91 AC_PROG_YACC
  92 AM_PROG_LEX
  93
  94 AM_MAINTAINER_MODE
  95
  96 . ${srcdir}/configure.host
  97
  98 AC_SUBST(HDEFINES)
  99 AC_SUBST(HOSTING_CRT0)
 100 AC_SUBST(HOSTING_LIBS)
 101 AC_SUBST(NATIVE_LIB_DIRS)
 102
 103 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h)
 104 AC_CHECK_FUNCS(sbrk realpath glob)
 105 AC_HEADER_DIRENT
 106
 107 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 108 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 109 [AC_TRY_COMPILE([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);],
 110 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 111 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 112 if test $ld_cv_decl_getopt_unistd_h = yes; then
 113   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 114             [Is the prototype for getopt in <unistd.h> in the expected format?])
 115 fi
 116
 117 BFD_BINARY_FOPEN
 118
 119 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 120
 121 # When converting linker scripts into strings for use in emulation
 122 # files, use astring.sed if the compiler supports ANSI string
 123 # concatenation, or ostring.sed otherwise.  This is to support the
 124 # broken Microsoft MSVC compiler, which limits the length of string
 125 # constants, while still supporting pre-ANSI compilers which do not
 126 # support string concatenation.
 127 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 128 AC_CACHE_VAL(ld_cv_string_concatenation,
 129 [AC_TRY_COMPILE(,[char *a = "a" "a";],
 130   [ld_cv_string_concatenation=yes],
 131   [ld_cv_string_concatenation=no])])
 132 AC_MSG_RESULT($ld_cv_string_concatenation)
 133 if test "$ld_cv_string_concatenation" = "yes"; then
 134   STRINGIFY=astring.sed
 135 else
 136   STRINGIFY=ostring.sed
 137 fi
 138 AC_SUBST(STRINGIFY)
 139
 140 # target-specific stuff:
 141
 142 all_targets=
 143 EMUL=
 144 all_emuls=
 145 all_emul_extras=
 146 all_libpath=
 147
 148 dnl We need to get an arbitrary number of tdir definitions into
 149 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 150 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 151 dnl file.
 152 rm -f tdirs
 153
 154 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 155 do
 156   if test "$targ_alias" = "all"; then
 157     all_targets=true
 158   else
 159     # Canonicalize the secondary target names.
 160     result=`$ac_config_sub $targ_alias 2>/dev/null`
 161     if test -n "$result"; then
 162         targ=$result
 163     else
 164         targ=$targ_alias
 165     fi
 166
 167     . ${srcdir}/configure.tgt
 168
 169     if test "$targ" = "$target"; then
 170       EMUL=$targ_emul
 171     fi
 172
 173     if test x${want64} = xfalse; then
 174       . ${srcdir}/../bfd/config.bfd
 175     fi
 176
 177     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 178         case " $all_emuls " in
 179         *" e${i}.o "*) ;;
 180         *)
 181           all_emuls="$all_emuls e${i}.o"
 182           eval result=\$tdir_$i
 183           test -z "$result" && result=$targ_alias
 184           echo tdir_$i=$result >> tdirs
 185           ;;
 186         esac
 187     done
 188
 189     for i in $targ_emul $targ_extra_libpath; do
 190         case " $all_libpath " in
 191         *" ${i} "*) ;;
 192         *)
 193           if test -z "$all_libpath"; then
 194             all_libpath=${i}
 195           else
 196             all_libpath="$all_libpath ${i}"
 197           fi
 198           ;;
 199         esac
 200     done
 201
 202     for i in $targ_extra_ofiles; do
 203         case " $all_emul_extras " in
 204         *" ${i} "*) ;;
 205         *)
 206           all_emul_extras="$all_emul_extras ${i}"
 207           ;;
 208         esac
 209     done
 210   fi
 211 done
 212
 213 AC_SUBST(EMUL)
 214
 215 TDIRS=tdirs
 216 AC_SUBST_FILE(TDIRS)
 217
 218 if test x${all_targets} = xtrue; then
 219   if test x${want64} = xfalse; then
 220     AC_CHECK_SIZEOF(long)
 221     if test "x${ac_cv_sizeof_long}" = "x8"; then
 222       want64=true
 223     fi
 224   fi
 225   if test x${want64} = xtrue; then
 226     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 227   else
 228     EMULATION_OFILES='$(ALL_EMULATIONS)'
 229   fi
 230   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 231 else
 232   EMULATION_OFILES=$all_emuls
 233   EMUL_EXTRA_OFILES=$all_emul_extras
 234 fi
 235 AC_SUBST(EMULATION_OFILES)
 236 AC_SUBST(EMUL_EXTRA_OFILES)
 237 AC_SUBST(LIB_PATH)
 238
 239 EMULATION_LIBPATH=$all_libpath
 240 AC_SUBST(EMULATION_LIBPATH)
 241
 242 if test x${enable_static} = xno; then
 243   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 244 else
 245   TESTBFDLIB="../bfd/.libs/libbfd.a"
 246 fi
 247 AC_SUBST(TESTBFDLIB)
 248
 249 target_vendor=${target_vendor=$host_vendor}
 250 case "$target_vendor" in
 251   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 252   *)  EXTRA_SHLIB_EXTENSION= ;;
 253 esac
 254
 255 case "$target_os" in
 256   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 257 esac
 258
 259 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 260   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 261    [Additional extension a shared object might have.])
 262 fi
 263
 264 dnl Required by html and install-html
 265 AC_SUBST(datarootdir)
 266 AC_SUBST(docdir)
 267 AC_SUBST(htmldir)
 268
 269 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in)