render_povray/templates_pov/float5.pov

   1 // This work is licensed under the Creative Commons Attribution-ShareAlike 3.0 Unported License.
   2 // To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/3.0/ or send a
   3 // letter to Creative Commons, 444 Castro Street, Suite 900, Mountain View, California, 94041, USA.
   4
   5 // Persistence of Vision Raytracer Scene Description File
   6 // File: float5.pov
   7 // Description: Demonstrates various new float math functions and #while loop
   8 // Modified for 3.5: changed "log()" to "ln()".
   9 //
  10 // -w320 -h240
  11 // -w800 -h600 +a0.3
  12
  13 #version 3.6;
  14
  15 global_settings {
  16   assumed_gamma 1.0
  17   }
  18
  19 #include "colors.inc"
  20
  21 #declare Rad=1/8;
  22 #declare Font="cyrvetic.ttf"
  23
  24 #declare Xval=-6.0;
  25
  26 #while (Xval <= 6.0)
  27   sphere{<Xval,exp(Xval),0>,Rad pigment{color rgb<1,0.2,0>}}
  28
  29   #if (Xval != 0.0)
  30     sphere{<Xval,pow(Xval,-1),0>,Rad pigment{color rgb<0.2,0.7,0>}}
  31   #end
  32
  33   sphere{<Xval,pow(Xval,2),0>,Rad pigment{Blue}}
  34   sphere{<Xval,pow(Xval,3),0>,Rad pigment{Cyan}}
  35
  36   #if (Xval > 0.0)
  37     sphere{<Xval,ln(Xval),0>,Rad pigment{Magenta}}
  38   #end
  39
  40   #declare Xval=Xval+0.02;
  41 #end
  42
  43  text{ttf Font "Y=exp(X)",0.1,0    translate <-6.5, 0.5,0> pigment{color rgb<1,0.2,0>}}
  44  text{ttf Font "Y=pow(X,-1)",0.1,0 translate <-6.5,-1.5,0> pigment{color rgb<0.2,0.7,0>}}
  45  text{ttf Font "Y=pow(X,2)",0.1,0  translate <-6.5, 3,0>   pigment{Blue}}
  46  text{ttf Font "Y=pow(X,3)",0.1,0  translate <-6.5,-4,0>   pigment{Cyan}}
  47  text{ttf Font "Y=ln(X)",0.1,0    translate < 2.5, 2,0>   pigment{Magenta}}
  48
  49 camera {
  50    location  <0, 0, -120>
  51    angle 7 // direction <0, 0,  12>
  52    right x*image_width/image_height
  53    look_at   <0, 0,   0>
  54 }
  55
  56 light_source { <5000, 10000, -20000> color White}
  57 light_source { <-500, -1000, 2000> color White}
  58 plane { -z, -Rad pigment {checker color rgb <1,1,1>*1.2 color rgb <1,1,.8>} }
  59
  60 union{ // X-axis
  61  cylinder{-x*5.5,x*5.5,.1}
  62  cone{-x*6.5,0,-x*5.5,.2}
  63  cone{ x*6.5,0, x*5.5,.2}
  64  translate z*Rad
  65  pigment{rgb<1,.8,1>}
  66 }
  67
  68 union{ // Y-axis
  69  cylinder{-y*4,y*4,.1}
  70  cone{-y*5,0,-y*4,.2}
  71  cone{ y*5,0, y*4,.2}
  72  translate z*Rad
  73  pigment{rgb<.8,1,1>}
  74 }
  75
  76 union{ // Axes labels
  77  text{ttf Font "X",0.1,0 translate <5.5,-1,0>}
  78  text{ttf Font "Y",0.1,0 translate <-.75,4,0>}
  79  pigment{rgb<1,.4,0>}
  80 }
  81