chrome/common/net/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6
   7 # GYP version: chrome/chrome_common.gypi:common_net
   8 static_library("net") {
   9   sources = [
  10     "net_resource_provider.cc",
  11     "net_resource_provider.h",
  12     "x509_certificate_model.cc",
  13     "x509_certificate_model.h",
  14     "x509_certificate_model_nss.cc",
  15     "x509_certificate_model_openssl.cc",
  16   ]
  17
  18   deps = [
  19     "//base",
  20     "//chrome:resources",
  21     "//chrome:strings",
  22     "//components/error_page/common",
  23     "//components/network_hints/common",
  24     "//crypto",
  25     "//net",
  26     "//net:net_resources",
  27     "//third_party/icu",
  28     "//ui/base/",
  29   ]
  30
  31   if (is_ios) {
  32     sources -= [ "net_resource_provider.cc" ]
  33   } else {
  34     deps += [ "//gpu/ipc" ]
  35   }
  36
  37   if (is_android || is_ios) {
  38     sources -= [ "x509_certificate_model.cc" ]
  39   }
  40
  41   if (use_openssl_certs && !is_android) {
  42     deps += [ "//third_party/boringssl" ]
  43   } else {
  44     sources -= [ "x509_certificate_model_openssl.cc" ]
  45   }
  46
  47   if (use_nss_certs) {
  48     deps += [ "//crypto:platform" ]
  49   } else {
  50     sources -= [ "x509_certificate_model_nss.cc" ]
  51   }
  52
  53   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  54 }