skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 if (cpu_arch == "arm") {
   8   import("//build/config/arm.gni")
   9 }
  10
  11 skia_support_gpu = !is_ios
  12 skia_support_pdf = !is_ios && enable_printing != 0
  13
  14 # The list of Skia defines that are to be set for chromium.
  15 gypi_skia_defines = exec_script(
  16     "//build/gypi_to_gn.py",
  17     [ rebase_path("//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  18       "--replace=<(skia_include_path)=//third_party/skia/include",
  19       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  20     "scope",
  21     [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  22
  23 # The list of Skia core sources that are to be set for chromium.
  24 gypi_skia_core = exec_script(
  25     "//build/gypi_to_gn.py",
  26     [ rebase_path("//third_party/skia/gyp/core.gypi"),
  27       "--replace=<(skia_include_path)=//third_party/skia/include",
  28       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  29     "scope",
  30     [ "//third_party/skia/gyp/core.gypi" ])
  31
  32 # The list of Skia gpu sources that are to be set for chromium.
  33 gypi_skia_gpu = exec_script(
  34     "//build/gypi_to_gn.py",
  35     [ rebase_path("//third_party/skia/gyp/gpu.gypi"),
  36       "--replace=<(skia_include_path)=//third_party/skia/include",
  37       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  38     "scope",
  39     [ "//third_party/skia/gyp/gpu.gypi" ])
  40
  41 # The list of Skia pdf sources that are to be set for chromium.
  42 gypi_skia_pdf = exec_script(
  43     "//build/gypi_to_gn.py",
  44     [ rebase_path("//third_party/skia/gyp/pdf.gypi"),
  45       "--replace=<(skia_include_path)=//third_party/skia/include",
  46       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  47     "scope",
  48     [ "//third_party/skia/gyp/pdf.gypi" ])
  49
  50 # The list of Skia effects that are to be set for chromium.
  51 gypi_skia_effects = exec_script(
  52     "//build/gypi_to_gn.py",
  53     [ rebase_path("//third_party/skia/gyp/effects.gypi"),
  54       "--replace=<(skia_include_path)=//third_party/skia/include",
  55       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  56     "scope",
  57     [ "//third_party/skia/gyp/effects.gypi" ])
  58
  59 # The list of Skia utilss that are to be set for chromium.
  60 gypi_skia_utils = exec_script(
  61     "//build/gypi_to_gn.py",
  62     [ rebase_path("//third_party/skia/gyp/utils.gypi"),
  63       "--replace=<(skia_include_path)=//third_party/skia/include",
  64       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  65     "scope",
  66     [ "//third_party/skia/gyp/utils.gypi" ])
  67
  68 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
  69 gypi_values = exec_script(
  70     "//build/gypi_to_gn.py",
  71     [ rebase_path("skia_gn_files.gypi"),
  72       "--replace=<(skia_include_path)=//third_party/skia/include",
  73       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  74     "scope",
  75     [ "skia_gn_files.gypi" ])
  76
  77 # External-facing config for dependent code.
  78 config("skia_config") {
  79   include_dirs = [
  80     "config",
  81     "ext",
  82     "//third_party/skia/include/config",
  83     "//third_party/skia/include/core",
  84     "//third_party/skia/include/effects",
  85     "//third_party/skia/include/images",
  86     "//third_party/skia/include/lazy",
  87     "//third_party/skia/include/pathops",
  88     "//third_party/skia/include/pdf",
  89     "//third_party/skia/include/pipe",
  90     "//third_party/skia/include/ports",
  91     "//third_party/skia/include/utils",
  92     "//third_party/skia/src/core",
  93     "//third_party/skia/src/image",
  94     "//third_party/skia/src/opts",
  95     "//third_party/skia/src/ports",
  96     "//third_party/skia/src/sfnt",
  97     "//third_party/skia/src/utils",
  98     "//third_party/skia/src/lazy",
  99   ]
 100
 101   defines = gypi_skia_defines.skia_for_chromium_defines
 102
 103   defines += [
 104     "SK_ENABLE_INST_COUNT=0",
 105     "GR_GL_CUSTOM_SETUP_HEADER=\"GrGLConfig_chrome.h\"",
 106     "SK_ENABLE_LEGACY_API_ALIASING=1",
 107     "SK_ATTR_DEPRECATED=SK_NOTHING_ARG1",
 108     "GR_GL_IGNORE_ES3_MSAA=0",
 109     "SK_WILL_NEVER_DRAW_PERSPECTIVE_TEXT",
 110     "SK_SUPPORT_LEGACY_GETTOTALCLIP",
 111   ]
 112
 113   if (component_mode == "shared_library") {
 114     defines += [ "SKIA_DLL" ]
 115   }
 116
 117   if (skia_support_gpu) {
 118     include_dirs += [
 119       "//third_party/skia/include/gpu",
 120       "//third_party/skia/src/gpu",
 121     ]
 122     defines += [ "SK_SUPPORT_GPU=1" ]
 123   } else {
 124     defines += [ "SK_SUPPORT_GPU=0" ]
 125   }
 126
 127   # For POSIX platforms, prefer the Mutex implementation provided by Skia
 128   # since it does not generate static initializers.
 129   if (is_posix) {
 130     defines += [ "SK_USE_POSIX_THREADS" ]
 131   }
 132
 133   if (is_android) {
 134     defines += [
 135       "SK_BUILD_FOR_ANDROID",
 136       "USE_CHROMIUM_SKIA",
 137     ]
 138   }
 139
 140   if (is_mac) {
 141     defines += [ "SK_BUILD_FOR_MAC" ]
 142   }
 143 }
 144
 145 # Internal-facing config for Skia library code.
 146 config("skia_library_config") {
 147   # These include directories are only included for Skia code and are not
 148   # exported to dependents. It's not clear if this is on purpose, but this
 149   # matches the GYP build.
 150   include_dirs = []
 151   if (is_mac || is_ios) {
 152     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 153   }
 154   if (is_mac) {
 155     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 156   }
 157
 158   defines = [
 159     #skia_export_defines ???) TODO
 160
 161     # skia uses static initializers to initialize the serialization logic
 162     # of its "pictures" library. This is currently not used in chrome; if
 163     # it ever gets used the processes that use it need to call
 164     # SkGraphics::Init().
 165     "SK_ALLOW_STATIC_GLOBAL_INITIALIZERS=0",
 166
 167     # Forcing the unoptimized path for the offset image filter in skia until
 168     # all filters used in Blink support the optimized path properly
 169     "SK_DISABLE_OFFSETIMAGEFILTER_OPTIMIZATION",
 170
 171     "IGNORE_ROT_AA_RECT_OPT",
 172
 173     "SK_IGNORE_BLURRED_RRECT_OPT",
 174
 175     "SK_IGNORE_QUAD_RR_CORNERS_OPT",
 176
 177     # this flag forces Skia not to use typographic metrics with GDI.
 178     "SK_GDI_ALWAYS_USE_TEXTMETRICS_FOR_FONT_METRICS",
 179
 180     "SK_USE_DISCARDABLE_SCALEDIMAGECACHE",
 181   ]
 182
 183   # Settings for text blitting, chosen to approximate the system browser.
 184   if (is_linux) {
 185     defines += [
 186       "SK_GAMMA_EXPONENT=1.2",
 187       "SK_GAMMA_CONTRAST=0.2",
 188       "SK_HIGH_QUALITY_IS_LANCZOS",
 189     ]
 190   } else if (is_android) {
 191     defines += [
 192       "SK_GAMMA_APPLY_TO_A8",
 193       "SK_GAMMA_EXPONENT=1.4",
 194       "SK_GAMMA_CONTRAST=0.0",
 195     ]
 196   } else if (is_win) {
 197     defines += [
 198       "SK_GAMMA_SRGB",
 199       "SK_GAMMA_CONTRAST=0.5",
 200       "SK_HIGH_QUALITY_IS_LANCZOS",
 201     ]
 202   } else if (is_mac) {
 203     defines += [
 204       "SK_GAMMA_SRGB",
 205       "SK_GAMMA_CONTRAST=0.0",
 206       "SK_HIGH_QUALITY_IS_LANCZOS",
 207     ]
 208   }
 209
 210   if (is_android) {
 211     defines += [
 212       # Android devices are typically more memory constrained, so default to a
 213       # smaller glyph cache (it may be overriden at runtime when the renderer
 214       # starts up, depending on the actual device memory).
 215       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576"  # 1024 * 1024
 216     ]
 217   } else {
 218     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 219   }
 220
 221   if (is_win) {
 222     include_dirs = [
 223       "//third_party/skia/include/utils/win",
 224       "//third_party/skia/src/utils/win",
 225     ]
 226
 227     defines += [ "SK_FONTHOST_USES_FONTMGR" ]
 228
 229     cflags = [
 230       # TODO(brettw) comment what these are.
 231       "/wd4244",
 232       "/wd4267",
 233       "/wd4341",
 234       "/wd4345",
 235       "/wd4390",
 236       "/wd4554",
 237       "/wd4748",
 238       "/wd4800",
 239     ]
 240   }
 241 }
 242
 243 component("skia") {
 244   sources = [
 245     # Chrome sources.
 246     "ext/analysis_canvas.cc",
 247     "ext/analysis_canvas.h",
 248     "ext/benchmarking_canvas.cc",
 249     "ext/benchmarking_canvas.h",
 250     "ext/bitmap_platform_device.h",
 251     "ext/bitmap_platform_device_cairo.cc",
 252     "ext/bitmap_platform_device_cairo.h",
 253     "ext/bitmap_platform_device_mac.cc",
 254     "ext/bitmap_platform_device_mac.h",
 255     #"ext/bitmap_platform_device_skia.cc",
 256     #"ext/bitmap_platform_device_skia.h",
 257     "ext/bitmap_platform_device_win.cc",
 258     "ext/bitmap_platform_device_win.h",
 259     "ext/convolver.cc",
 260     "ext/convolver.h",
 261     "ext/event_tracer_impl.cc",
 262     "ext/event_tracer_impl.h",
 263     "ext/fontmgr_default_win.cc",
 264     "ext/fontmgr_default_win.h",
 265     "ext/google_logging.cc",
 266     "ext/image_operations.cc",
 267     "ext/image_operations.h",
 268     "ext/lazy_pixel_ref.cc",
 269     "ext/lazy_pixel_ref.h",
 270     "ext/SkThread_chrome.cc",
 271     "ext/opacity_draw_filter.cc",
 272     "ext/opacity_draw_filter.h",
 273     "ext/paint_simplifier.cc",
 274     "ext/paint_simplifier.h",
 275     "ext/pixel_ref_utils.cc",
 276     "ext/pixel_ref_utils.h",
 277     "ext/platform_canvas.cc",
 278     "ext/platform_canvas.h",
 279     "ext/platform_device.cc",
 280     "ext/platform_device.h",
 281     "ext/platform_device_linux.cc",
 282     "ext/platform_device_mac.cc",
 283     "ext/platform_device_win.cc",
 284     "ext/recursive_gaussian_convolution.cc",
 285     "ext/recursive_gaussian_convolution.h",
 286     "ext/refptr.h",
 287     "ext/SkDiscardableMemory_chrome.h",
 288     "ext/SkDiscardableMemory_chrome.cc",
 289     "ext/SkMemory_new_handler.cpp",
 290     "ext/skia_trace_shim.h",
 291     "ext/skia_utils_base.cc",
 292     "ext/skia_utils_base.h",
 293     "ext/skia_utils_ios.mm",
 294     "ext/skia_utils_ios.h",
 295     "ext/skia_utils_mac.mm",
 296     "ext/skia_utils_mac.h",
 297     "ext/skia_utils_win.cc",
 298     "ext/skia_utils_win.h",
 299     "ext/vector_canvas.h",
 300     "ext/vector_platform_device_emf_win.cc",
 301     "ext/vector_platform_device_emf_win.h",
 302     "ext/vector_platform_device_skia.cc",
 303     "ext/vector_platform_device_skia.h",
 304   ]
 305
 306   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 307   sources += gypi_skia_core.sources
 308   sources += gypi_skia_effects.sources
 309   sources += gypi_skia_utils.sources
 310   sources += gypi_skia_pdf.sources
 311   sources += gypi_values.skia_library_sources
 312
 313   # GPU
 314   if (skia_support_gpu) {
 315     sources += gypi_skia_gpu.skgpu_sources
 316     sources += gypi_skia_gpu.skgpu_null_gl_sources
 317   }
 318
 319   # Remove unused util files include in utils.gypi
 320   sources -= [
 321   "//third_party/skia/include/utils/SkCondVar.h",
 322   "//third_party/skia/include/utils/SkRunnable.h",
 323   "//third_party/skia/include/utils/SkThreadPool.h",
 324   "//third_party/skia/src/utils/SkCondVar.cpp",
 325
 326   "//third_party/skia/include/utils/SkBoundaryPatch.h",
 327   "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 328   "//third_party/skia/include/utils/SkCamera.h",
 329   "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 330   "//third_party/skia/include/utils/SkCubicInterval.h",
 331   "//third_party/skia/include/utils/SkCullPoints.h",
 332   "//third_party/skia/include/utils/SkDebugUtils.h",
 333   "//third_party/skia/include/utils/SkDumpCanvas.h",
 334   "//third_party/skia/include/utils/SkEventTracer.h",
 335   "//third_party/skia/include/utils/SkInterpolator.h",
 336   "//third_party/skia/include/utils/SkLayer.h",
 337   "//third_party/skia/include/utils/SkMeshUtils.h",
 338   "//third_party/skia/include/utils/SkNinePatch.h",
 339   "//third_party/skia/include/utils/SkParse.h",
 340   "//third_party/skia/include/utils/SkParsePaint.h",
 341   "//third_party/skia/include/utils/SkParsePath.h",
 342   "//third_party/skia/include/utils/SkRandom.h",
 343   "//third_party/skia/include/utils/SkWGL.h",
 344
 345   "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 346   "//third_party/skia/src/utils/SkBitmapHasher.h",
 347   "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 348   "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 349   "//third_party/skia/src/utils/SkCamera.cpp",
 350   "//third_party/skia/src/utils/SkCanvasStack.h",
 351   "//third_party/skia/src/utils/SkCubicInterval.cpp",
 352   "//third_party/skia/src/utils/SkCullPoints.cpp",
 353   "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 354   "//third_party/skia/src/utils/SkFloatUtils.h",
 355   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.cpp",
 356   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.h",
 357   "//third_party/skia/src/utils/SkInterpolator.cpp",
 358   "//third_party/skia/src/utils/SkLayer.cpp",
 359   "//third_party/skia/src/utils/SkMD5.cpp",
 360   "//third_party/skia/src/utils/SkMD5.h",
 361   "//third_party/skia/src/utils/SkMeshUtils.cpp",
 362   "//third_party/skia/src/utils/SkNinePatch.cpp",
 363   "//third_party/skia/src/utils/SkOSFile.cpp",
 364   "//third_party/skia/src/utils/SkParse.cpp",
 365   "//third_party/skia/src/utils/SkParseColor.cpp",
 366   "//third_party/skia/src/utils/SkParsePath.cpp",
 367   "//third_party/skia/src/utils/SkPathUtils.cpp",
 368   "//third_party/skia/src/utils/SkSHA1.cpp",
 369   "//third_party/skia/src/utils/SkSHA1.h",
 370   "//third_party/skia/src/utils/SkThreadUtils.h",
 371   "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 372   "//third_party/skia/src/utils/SkThreadUtils_pthread.h",
 373   "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 374   "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 375   "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 376   "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 377   "//third_party/skia/src/utils/SkTFitsIn.h",
 378   "//third_party/skia/src/utils/SkTLogic.h",
 379
 380   #testing
 381   "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 382   "//third_party/skia/src/fonts/SkGScalerContext.h",
 383   ]
 384
 385   # need separate win section to handle chromes auto gn filter (build/config/BUILDCONFIG.gn)
 386   if (is_win) {
 387     sources -= [
 388       "//third_party/skia/src/utils/SkThreadUtils_win.h",
 389
 390       #windows
 391       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 392       "//third_party/skia/include/utils/win/SkHRESULT.h",
 393       "//third_party/skia/include/utils/win/SkIStream.h",
 394       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 395       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 396       "//third_party/skia/src/utils/win/SkIStream.cpp",
 397       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 398     ]
 399   }
 400
 401   # Fixup Chrome sources.
 402   if (is_posix) {
 403     sources -= [ "ext/SkThread_chrome.cc" ]
 404   }
 405   if (is_ios) {
 406     sources -= [ "ext/vector_platform_device_skia.cc" ]
 407   }
 408   if (is_win) {
 409     sources -= [ "ext/SkThread_chrome.cc" ]
 410   }
 411   if (is_android && enable_printing == 0) {
 412     sources -= [
 413       "ext/skia_utils_base.cc",
 414       "ext/vector_platform_device_skia.cc"
 415     ]
 416   }
 417
 418   # Fixup skia library sources.
 419   if (is_win) {
 420     sources -= [
 421       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 422       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 423       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 424     ]
 425   } else {
 426     sources -= [
 427       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 428       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 429       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 430       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 431       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 432       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 433       "//third_party/skia/src/ports/SkTLS_win.cpp",
 434       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 435       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 436     ]
 437   }
 438   if (!is_android) {
 439     sources -= [
 440       "//third_party/skia/src/ports/SkFontConfigInterface_android.cpp",
 441       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 442     ]
 443   }
 444   if (!is_mac) {
 445     sources -= [
 446       "//third_party/skia/src/ports/SkFontHost_mac.cpp",
 447     ]
 448   }
 449
 450   if (!is_linux) {
 451     sources -= [
 452       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 453       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 454       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 455       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 456       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 457     ]
 458   }
 459
 460   if (!use_cairo) {
 461     sources -= [
 462       "ext/bitmap_platform_device_cairo.cc",
 463       "ext/bitmap_platform_device_cairo.h",
 464     ]
 465   }
 466
 467   if (is_clang) {
 468     # Skia won't compile with some of the more strict clang warnings.
 469     # e.g. it does:
 470     #  SkASSERT(!"sk_out_of_memory");
 471     configs -= [ "//build/config/clang:extra_warnings" ]
 472   }
 473
 474   configs -= [ "//build/config/compiler:chromium_code" ]
 475   configs += [
 476     ":skia_library_config",
 477     "//build/config/compiler:no_chromium_code"
 478   ]
 479   direct_dependent_configs = [ ":skia_config" ]
 480
 481   deps = [
 482     ":skia_opts",
 483     "//base",
 484     "//base/third_party/dynamic_annotations",
 485     "//third_party/zlib",
 486   ]
 487
 488   if (component_mode == "shared_library") {
 489     defines = [ "SKIA_IMPLEMENTATION=1" ]
 490   }
 491
 492   if (is_win) {
 493     configs -= [
 494       # Some files define WIN32_LEAN_AND_MEAN and we want to avoid a duplicate
 495       # definition warning.
 496       "//build/config/win:lean_and_mean",
 497     ]
 498   }
 499
 500   if (is_linux) {
 501     configs += [
 502       "//build/config/linux:fontconfig",
 503       "//build/config/linux:freetype2",
 504       "//build/config/linux:pangocairo",
 505     ]
 506     deps += [
 507       "//third_party/icu:icuuc",
 508     ]
 509   }
 510
 511   if (is_android) {
 512     deps += [
 513       "//third_party/expat",
 514       "//third_party/freetype",
 515     ]
 516   }
 517
 518   if (skia_support_pdf) {
 519     deps += [ "//third_party/sfntly" ]
 520   }
 521 }
 522
 523 # Separated out so it can be compiled with different flags for SSE.
 524 source_set("skia_opts") {
 525   cflags = []
 526   defines = []
 527
 528   if (cpu_arch == "x86" || cpu_arch == "x64") {
 529     sources = [
 530       # SSE 2
 531       "//third_party/skia/src/opts/opts_check_x86.cpp",
 532       "//third_party/skia/src/opts/SkBitmapFilter_opts_SSE2.cpp",
 533       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSE2.cpp",
 534       "//third_party/skia/src/opts/SkBlitRect_opts_SSE2.cpp",
 535       "//third_party/skia/src/opts/SkBlitRow_opts_SSE2.cpp",
 536       "//third_party/skia/src/opts/SkBlurImage_opts_SSE2.cpp",
 537       "//third_party/skia/src/opts/SkMorphology_opts_SSE2.cpp",
 538       "//third_party/skia/src/opts/SkUtils_opts_SSE2.cpp",
 539       "//third_party/skia/src/opts/SkXfermode_opts_SSE2.cpp",
 540
 541       # SSSE 3
 542       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSSE3.cpp",
 543
 544       # SSE 4
 545       "//third_party/skia/src/opts/SkBlurImage_opts_SSE4.cpp",
 546
 547       # Chrome-specific.
 548       "ext/convolver_SSE2.cc",
 549
 550       # These are header files used by this target from the skia one above.
 551       "ext/convolver.h",
 552       "//third_party/skia/include/core/SkTypes.h",
 553     ]
 554
 555     # SSE 4
 556     if (cpu_arch == "x86") {
 557       sources += [ "//third_party/skia/src/opts/SkBlitRow_opts_SSE4_asm.S" ]
 558     } else {  # x64
 559       sources += [ "//third_party/skia/src/opts/SkBlitRow_opts_SSE4_x64_asm.S" ]
 560     }
 561
 562     if (is_linux || is_mac) {
 563       cflags += [ "-msse4.1" ]
 564     }
 565   } else if (cpu_arch == "arm") {
 566     sources = [
 567       "//third_party/skia/src/opts/SkBitmapProcState_opts_arm.cpp",
 568     ]
 569
 570     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 571     # ARM), the compiler doesn't like that.
 572     cflags += [ "-fomit-frame-pointer" ]
 573
 574     if (arm_version >= 7) {
 575       if (arm_use_neon || arm_optionally_use_neon) {
 576         sources += [
 577           "//third_party/skia/src/opts/memset16_neon.S",
 578           "//third_party/skia/src/opts/memset32_neon.S",
 579           "//third_party/skia/src/opts/SkBitmapProcState_arm_neon.cpp",
 580           "//third_party/skia/src/opts/SkBitmapProcState_matrixProcs_neon.cpp",
 581           "//third_party/skia/src/opts/SkBitmapProcState_matrix_clamp_neon.h",
 582           "//third_party/skia/src/opts/SkBitmapProcState_matrix_repeat_neon.h",
 583           "//third_party/skia/src/opts/SkBlitMask_opts_arm_neon.cpp",
 584           "//third_party/skia/src/opts/SkBlitRow_opts_arm_neon.cpp",
 585           "//third_party/skia/src/opts/SkXfermode_opts_arm_neon.cpp",
 586           "//third_party/skia/src/opts/SkBlurImage_opts_neon.cpp",
 587           "//third_party/skia/src/opts/SkMorphology_opts_neon.cpp",
 588         ]
 589
 590         cflags += [
 591           # The neon assembly contains conditional instructions which aren't
 592           # enclosed in an IT block. The assembler complains without this
 593           # option. See #86592.
 594           "-Wa,-mimplicit-it=always",
 595         ]
 596
 597         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 598         # when running this.
 599         assert(arm_fpu == "neon")
 600
 601         #ldflags = [
 602         #  "-march=armv7-a",
 603         #  "-Wl,--fix-cortex-a8",
 604         #]
 605       }
 606
 607       if (arm_use_neon) {
 608         defines += [ "__ARM_HAVE_NEON" ]
 609       }
 610       if (arm_optionally_use_neon) {
 611         defines += [ "__ARM_HAVE_OPTIONAL_NEON_SUPPORT" ]
 612       }
 613     }
 614
 615     # Non-Neon ARM code.
 616     if (arm_version < 7 || (!arm_use_neon && arm_optionally_use_neon)) {
 617       sources += [ "//third_party/skia/src/opts/memset.arm.S" ]
 618     }
 619
 620     if (arm_version < 6) {
 621       sources += [
 622         "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 623         "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 624         "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 625         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 626         "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 627         "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 628       ]
 629     } else {
 630       # arm version >= 6.
 631       sources += [
 632         "//third_party/skia/src/opts/SkBlitMask_opts_arm.cpp",
 633         "//third_party/skia/src/opts/SkBlitRow_opts_arm.cpp",
 634         "//third_party/skia/src/opts/SkBlitRow_opts_arm.h",
 635         "//third_party/skia/src/opts/SkBlurImage_opts_arm.cpp",
 636         "//third_party/skia/src/opts/SkMorphology_opts_arm.cpp",
 637         "//third_party/skia/src/opts/SkUtils_opts_arm.cpp",
 638         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 639       ]
 640     }
 641
 642   } else if (cpu_arch == "mipsel") {
 643     cflags += [ "-fomit-frame-pointer" ]
 644     sources = [
 645       "//third_party/skia/src/opts/SkBitmapProcState_opts_none.cpp",
 646       "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 647       "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 648       "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 649       "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 650       "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 651       "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 652     ]
 653   } else {
 654     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 655   }
 656
 657   configs -= [ "//build/config/compiler:chromium_code" ]
 658   configs += [
 659     ":skia_config",
 660     "//build/config/compiler:no_chromium_code"
 661   ]
 662
 663   deps = [
 664     "//base",
 665   ]
 666
 667   visibility = ":skia"
 668 }