chrome/common/net/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6
   7 # GYP version: chrome/chrome_common.gypi:common_net
   8 static_library("net") {
   9   sources = [
  10     "net_resource_provider.cc",
  11     "net_resource_provider.h",
  12     "url_util.cc",
  13     "url_util.h",
  14     "x509_certificate_model.cc",
  15     "x509_certificate_model.h",
  16     "x509_certificate_model_nss.cc",
  17     "x509_certificate_model_openssl.cc",
  18   ]
  19
  20   deps = [
  21     "//base",
  22     "//chrome:resources",
  23     "//chrome:strings",
  24     "//components/error_page/common",
  25     "//crypto",
  26     "//net",
  27     "//net:net_resources",
  28     "//third_party/icu",
  29     "//ui/base/",
  30   ]
  31
  32   if (is_ios) {
  33     sources -= [
  34       "net_resource_provider.cc",
  35       "x509_certificate_model.cc",
  36     ]
  37   } else {
  38     deps += [ "//gpu/ipc" ]
  39   }
  40
  41   if (is_win || is_mac || is_ios) {
  42     sources -= [
  43       "x509_certificate_model_nss.cc",
  44       "x509_certificate_model_openssl.cc",
  45     ]
  46   } else if (use_openssl) {
  47     sources -= [ "x509_certificate_model_nss.cc" ]
  48   } else {
  49     sources -= [ "x509_certificate_model_openssl.cc" ]
  50   }
  51
  52   if (is_android) {
  53     sources -= [
  54       "x509_certificate_model.cc",
  55       "x509_certificate_model_openssl.cc",
  56     ]
  57     deps += [ "//third_party/boringssl" ]
  58   }
  59
  60   if (is_win) {
  61     cflags = [ "/wd4267" ]
  62   }
  63 }