configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 m4_pattern_forbid([^_?DPKG_])
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([dpkg], m4_esyscmd([build-aux/get-version]),
   7         [debian-dpkg@lists.debian.org], [dpkg],
   8         [https://wiki.debian.org/Teams/Dpkg])
   9 DPKG_DIST_IS_RELEASE
  10 AC_SUBST([PACKAGE_COPYRIGHT_HOLDER], ['Dpkg Developers'])
  11 AC_SUBST([PACKAGE_VCS_TYPE], [git])
  12 AC_SUBST([PACKAGE_VCS_URL], [https://git.dpkg.org/git/dpkg/dpkg.git])
  13 AC_SUBST([PACKAGE_VCS_WEB], [https://git.dpkg.org/cgit/dpkg/dpkg.git])
  14 AC_SUBST([PACKAGE_BUG_WEB], [https://bugs.debian.org/src:dpkg])
  15 AC_SUBST([PACKAGE_CPAN_NAME], [Dpkg])
  16 AC_CONFIG_SRCDIR([lib/dpkg/dpkg.h])
  17 AC_CONFIG_MACRO_DIR([m4])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 AM_INIT_AUTOMAKE(
  23   [1.11]
  24   [-Wall]
  25   [foreign]
  26   [nostdinc]
  27   [subdir-objects]
  28   [tar-ustar no-dist-gzip dist-xz]
  29 )
  30 AM_SILENT_RULES([yes])
  31
  32 # Require at least this gettext version, but will take any later version too.
  33 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
  34 # XXX: We cannot remove the following macro due to backwards compatibility
  35 # reasons. The above macro is set unconditionally to the minimal version
  36 # required, and the below is set to 0.19.6, the first version introducing
  37 # the AM_GNU_GETTEXT_REQUIRE_VERSION macro.
  38 AM_GNU_GETTEXT_VERSION([0.19.6])
  39 AM_GNU_GETTEXT([external])
  40 DPKG_DIST_CHECK([test "$GMSGFMT" = ":" && test "$USE_NLS" = "yes"],
  41   [gettext required when NLS support enabled])
  42
  43 # Shared libraries are disabled on purpose, currently there is no ABI stability
  44 # guarantee, and it will be broken at will. The infrastructure is in place just
  45 # to be able to test that its future activation will work.
  46 AM_PROG_AR
  47 LT_INIT([disable-shared])
  48 DPKG_BUILD_SHARED_LIBS
  49 DPKG_LINKER_AS_NEEDED
  50 DPKG_LINKER_VERSION_SCRIPT
  51
  52 # Allow compilation without optional programs
  53 DPKG_BUILD_PROG([dselect])
  54 DPKG_BUILD_PROG([start-stop-daemon])
  55 DPKG_BUILD_PROG([update-alternatives])
  56
  57 DPKG_BUILD_RELEASE_DATE
  58 DPKG_BUILD_DEVEL_DOCS
  59
  60 # Allow alternate directories
  61 DPKG_WITH_DIR([devlibdir], [${libdir}],
  62   [dpkg development library directory [LIBDIR]])
  63 DPKG_WITH_DIR([pkgconfdir], [${sysconfdir}/${PACKAGE_NAME}],
  64   [dpkg configuration directory [SYSCONFDIR/dpkg]])
  65 DPKG_WITH_DIR([admindir], [${localstatedir}/lib/${PACKAGE_NAME}],
  66   [dpkg database directory [LOCALSTATEDIR/lib/dpkg]])
  67 DPKG_WITH_DIR([backupsdir], [${localstatedir}/backups],
  68   [dpkg database backups directory [LOCALSTATEDIR/backups]])
  69 DPKG_WITH_DIR([logdir], [${localstatedir}/log],
  70   [system logging directory [LOCALSTATEDIR/log]])
  71 DPKG_WITH_DIR([zshcompletionsdir], [${datadir}/zsh/vendor-completions],
  72   [zsh vendor completions directory [DATADIR/zsh/vendor-completions]])
  73
  74 # Set default dpkg-deb values
  75 DPKG_DEB_COMPRESSOR([xz])
  76
  77 # Checks for programs.
  78 AC_PROG_SED
  79 AC_PROG_GREP
  80 AC_PROG_EGREP
  81 AC_PROG_CC
  82 DPKG_C_C99
  83 AC_PROG_CXX
  84 DPKG_CXX_CXX11
  85 DPKG_PROG_PATCH
  86 AC_CHECK_PROGS([DOXYGEN], [doxygen])
  87 AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
  88 DPKG_PROG_TAR
  89 DPKG_PROG_PO4A
  90 DPKG_PROG_PERL
  91 DPKG_PROG_POD2MAN
  92 DPKG_CODE_COVERAGE
  93
  94 # Checks for operating system services and capabilities.
  95 AC_SYS_LARGEFILE
  96
  97 # Checks for libraries.
  98 DPKG_LIB_RT
  99 DPKG_LIB_MD
 100 DPKG_LIB_Z
 101 DPKG_LIB_BZ2
 102 DPKG_LIB_LZMA
 103 DPKG_LIB_ZSTD
 104 DPKG_LIB_SELINUX
 105 AS_IF([test "x$build_dselect" = "xyes"], [
 106   DPKG_LIB_CURSES
 107 ])
 108 AS_IF([test "x$build_start_stop_daemon" = "xyes"], [
 109   DPKG_LIB_SOCKET
 110   DPKG_LIB_PS
 111   DPKG_LIB_KVM
 112 ])
 113
 114 # Checks for header files.
 115 AC_CHECK_HEADERS([\
 116   stddef.h \
 117   error.h \
 118   err.h \
 119   locale.h \
 120   xlocale.h \
 121   libintl.h \
 122   kvm.h \
 123   sys/sysmacros.h \
 124   sys/param.h \
 125   sys/syscall.h \
 126   sys/user.h \
 127   sys/procfs.h \
 128   sys/pstat.h \
 129   linux/fiemap.h \
 130 ])
 131 AS_CASE([$host_os],
 132   [linux-gnu*], [
 133     # The glibc project has deprecated the <sys/sysctl.h> header and emits
 134     # warnings on its usage, and removed it in 2.32. The Linux kernel removed
 135     # support for it in 5.5.
 136   ], [
 137     # On other systems, we need to check whether to use it.
 138     AC_CHECK_HEADERS([\
 139       sys/sysctl.h \
 140     ])
 141   ]
 142 )
 143 AC_CHECK_HEADERS([sys/proc.h], [], [], [
 144 #ifdef HAVE_SYS_PARAM_H
 145 #include <sys/param.h>
 146 #endif
 147 ])
 148
 149 AS_IF([test "x$build_dselect" = "xyes"], [
 150   AC_LANG_PUSH([C++])
 151   AC_CHECK_HEADERS([cxxabi.h])
 152   AC_LANG_POP([C++])
 153 ])
 154
 155 # Checks for typedefs, structures, and compiler characteristics.
 156 DPKG_ARCH_ABI
 157 AC_C_CONST
 158 AC_C_INLINE
 159 AC_C_VOLATILE
 160 AC_TYPE_MODE_T
 161 AC_TYPE_PID_T
 162 AC_TYPE_SIZE_T
 163 DPKG_TYPE_PTRDIFF_T
 164 DPKG_DECL_SYS_SIGLIST
 165 DPKG_DECL_SYS_ERRLIST
 166
 167 # Checks for library functions.
 168 DPKG_FUNC_VA_COPY
 169 DPKG_FUNC_C99_SNPRINTF
 170 DPKG_FUNC_FSYNC_DIR
 171 DPKG_CHECK_DECL([offsetof], [stddef.h])
 172 DPKG_CHECK_DECL([makedev], [sys/types.h])
 173 DPKG_CHECK_DECL([WCOREDUMP], [sys/wait.h])
 174 DPKG_CHECK_DECL([TIOCNOTTY], [sys/ioctl.h])
 175 DPKG_CHECK_DECL([O_NOFOLLOW], [fcntl.h])
 176 DPKG_CHECK_DECL([F_ALLOCSP64], [fcntl.h])
 177 DPKG_CHECK_DECL([F_PREALLOCATE], [fcntl.h])
 178 DPKG_CHECK_DECL([P_tmpdir], [stdio.h])
 179 DPKG_CHECK_PROGNAME
 180 DPKG_CHECK_COMPAT_FUNCS([\
 181   getopt \
 182   getopt_long \
 183   obstack_free \
 184   strchrnul \
 185   strnlen \
 186   strndup \
 187   strerror \
 188   strsignal \
 189   asprintf \
 190   scandir \
 191   alphasort \
 192   unsetenv \
 193 ])
 194 AC_CHECK_FUNCS([memcpy lchown],
 195   [], [AC_MSG_ERROR([missing required function])])
 196 AC_CHECK_FUNCS([\
 197   strtoimax \
 198   isascii \
 199   setsid \
 200   getdtablesize \
 201   getprocs64 \
 202   getprogname \
 203   getexecname \
 204   lutimes \
 205   fallocate \
 206   posix_fallocate \
 207   posix_fadvise \
 208   uselocale \
 209 ])
 210
 211 AS_IF([test "x$build_dselect" = "xyes"], [
 212   AC_LANG_PUSH([C++])
 213   AC_CHECK_FUNCS([__cxa_pure_virtual])
 214   AC_LANG_POP([C++])
 215 ])
 216
 217 DPKG_USE_MMAP
 218 DPKG_USE_DISK_PREALLOCATE
 219
 220 # Checks for the build machinery.
 221 AC_DEFINE([LIBDPKG_VOLATILE_API], [1], [Acknowledge the volatility of the API.])
 222 DPKG_COMPILER_WARNINGS
 223 DPKG_COMPILER_OPTIMIZATIONS
 224 DPKG_LINKER_OPTIMIZATIONS
 225 DPKG_ARCHITECTURE
 226 AC_DEFINE([PACKAGE_RELEASE], [PACKAGE_VERSION " (" ARCHITECTURE ")"],
 227   [Define the project release information, version and architecture])
 228
 229 AC_CONFIG_TESTDIR([src/at])
 230 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 231
 232 AC_CONFIG_FILES([
 233   Makefile
 234   dselect/Makefile
 235   dselect/methods/Makefile
 236   dselect/po/Makefile.in
 237   lib/Makefile
 238   lib/compat/Makefile
 239   lib/dpkg/Makefile
 240   lib/dpkg/libdpkg.pc
 241   doc/Doxyfile
 242   man/Makefile
 243   po/Makefile.in
 244   scripts/Build.PL
 245   scripts/Makefile
 246   scripts/README.cpan
 247   scripts/mk/Makefile
 248   scripts/po/Makefile.in
 249   src/Makefile
 250   src/at/atlocal
 251   utils/Makefile
 252 ])
 253 AC_CONFIG_HEADERS([config.h])
 254 AC_OUTPUT
 255
 256 # Print the current configuration
 257 cat <<CONFIG
 258
 259 Configuration:
 260   Arch attributes:
 261     cpu name  . . . . . . . . . . : ${cpu_type}
 262     os name . . . . . . . . . . . : ${os_type}
 263     arch name . . . . . . . . . . : ${dpkg_arch}
 264     arch bits . . . . . . . . . . : ${dpkg_arch_bits}
 265     arch endian . . . . . . . . . : ${dpkg_arch_endian}
 266     char bits . . . . . . . . . . : ${dpkg_char_bits}
 267     char sign . . . . . . . . . . : ${dpkg_char_sign}
 268     sizeof(short) . . . . . . . . : ${ac_cv_sizeof_short}
 269     sizeof(int) . . . . . . . . . : ${ac_cv_sizeof_int}
 270     sizeof(long)  . . . . . . . . : ${ac_cv_sizeof_long}
 271     sizeof(long long) . . . . . . : ${ac_cv_sizeof_long_long}
 272     sizeof(float) . . . . . . . . : ${ac_cv_sizeof_float}
 273     sizeof(double)  . . . . . . . : ${ac_cv_sizeof_double}
 274     sizeof(long double) . . . . . : ${ac_cv_sizeof_long_double}
 275     sizeof(void *)  . . . . . . . : ${ac_cv_sizeof_void_p}
 276     alignof(max_align_t)  . . . . : ${ac_cv_alignof_max_align_t}
 277
 278   Features:
 279     native language support . . . : $USE_NLS
 280     unicode support . . . . . . . : $USE_UNICODE
 281     development documentation . . : $build_devel_docs
 282     code coverage . . . . . . . . : $enable_coverage
 283     build shared libraries  . . . : $enable_shared
 284     mmap loaders  . . . . . . . . : $enable_mmap
 285     disk pre-allocation . . . . . : $enable_disk_preallocate
 286     default dpkg-deb compressor . : $with_dpkg_deb_compressor
 287
 288   Paths:
 289     devlibdir . . . . . . . . . . : $devlibdir
 290     pkgconfdir  . . . . . . . . . : $pkgconfdir
 291     admindir  . . . . . . . . . . : $admindir
 292     backupsdir  . . . . . . . . . : $backupsdir
 293     logdir  . . . . . . . . . . . : $logdir
 294     perl interpreter  . . . . . . : $PERL
 295     perl libdir . . . . . . . . . : $PERL_LIBDIR
 296
 297   Programs:
 298     update-alternatives . . . . . : $build_update_alternatives
 299     start-stop-daemon . . . . . . : $build_start_stop_daemon
 300     dselect . . . . . . . . . . . : $build_dselect
 301
 302   System Libraries:
 303     librt . . . . . . . . . . . . : $have_librt
 304     libsocket . . . . . . . . . . : ${have_libsocket:-no}
 305     libps . . . . . . . . . . . . : ${have_libps:-no}
 306     libkvm  . . . . . . . . . . . : ${have_libkvm:-no}
 307     libselinux  . . . . . . . . . : $have_libselinux
 308     libmd . . . . . . . . . . . . : $have_libmd
 309     libz  . . . . . . . . . . . . : $have_libz_impl
 310     liblzma . . . . . . . . . . . : $have_liblzma
 311     libzstd . . . . . . . . . . . : $have_libzstd
 312     libbz2  . . . . . . . . . . . : $have_libbz2
 313     libcurses . . . . . . . . . . : ${have_libcurses:-no}
 314 CONFIG