configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 m4_pattern_forbid([^_?DPKG_])
   4
   5 AC_PREREQ(2.60)
   6 AC_INIT([dpkg], m4_esyscmd([build-aux/get-version]),
   7         [debian-dpkg@lists.debian.org], [dpkg],
   8         [https://wiki.debian.org/Teams/Dpkg])
   9 DPKG_DIST_IS_RELEASE
  10 AC_SUBST([PACKAGE_COPYRIGHT_HOLDER], ['Dpkg Developers'])
  11 AC_SUBST([PACKAGE_VCS_TYPE], [git])
  12 AC_SUBST([PACKAGE_VCS_URL], [https://git.dpkg.org/git/dpkg/dpkg.git])
  13 AC_SUBST([PACKAGE_VCS_WEB], [https://git.dpkg.org/cgit/dpkg/dpkg.git])
  14 AC_SUBST([PACKAGE_BUG_WEB], [https://bugs.debian.org/src:dpkg])
  15 AC_SUBST([PACKAGE_CPAN_NAME], [Dpkg])
  16 AC_CONFIG_SRCDIR([lib/dpkg/dpkg.h])
  17 AC_CONFIG_MACRO_DIR([m4])
  18 AC_CONFIG_AUX_DIR([build-aux])
  19
  20 AC_USE_SYSTEM_EXTENSIONS
  21
  22 AM_INIT_AUTOMAKE(
  23   [1.11]
  24   [-Wall]
  25   [foreign]
  26   [nostdinc]
  27   [subdir-objects]
  28   [tar-ustar no-dist-gzip dist-xz]
  29 )
  30 AM_SILENT_RULES([yes])
  31
  32 # Require at least this gettext version, but will take any later version too.
  33 AM_GNU_GETTEXT_REQUIRE_VERSION([0.19.8])
  34 # XXX: We cannot remove the following macro due to backwards compatibility
  35 # reasons. The above macro is set unconditionally to the minimal version
  36 # required, and the below is set to 0.19.6, the first version introducing
  37 # the AM_GNU_GETTEXT_REQUIRE_VERSION macro.
  38 AM_GNU_GETTEXT_VERSION([0.19.6])
  39 AM_GNU_GETTEXT([external])
  40 DPKG_DIST_CHECK([test "$GMSGFMT" = ":" && test "$USE_NLS" = "yes"],
  41   [gettext required when NLS support enabled])
  42
  43 # Shared libraries are disabled on purpose, currently there is no ABI stability
  44 # guarantee, and it will be broken at will. The infrastructure is in place just
  45 # to be able to test that its future activation will work.
  46 AM_PROG_AR
  47 LT_INIT([disable-shared])
  48 DPKG_BUILD_SHARED_LIBS
  49 DPKG_LINKER_AS_NEEDED
  50 DPKG_LINKER_VERSION_SCRIPT
  51
  52 # Allow compilation without optional programs
  53 DPKG_BUILD_PROG([dselect])
  54 DPKG_BUILD_PROG([start-stop-daemon])
  55 DPKG_BUILD_PROG([update-alternatives])
  56
  57 DPKG_BUILD_RELEASE_DATE
  58 DPKG_BUILD_DEVEL_DOCS
  59
  60 # Allow alternate directories
  61 DPKG_WITH_DIR([devlibdir], [${libdir}],
  62   [dpkg development library directory [LIBDIR]])
  63 DPKG_WITH_DIR([pkgconfdir], [${sysconfdir}/${PACKAGE_NAME}],
  64   [dpkg configuration directory [SYSCONFDIR/dpkg]])
  65 DPKG_WITH_DIR([admindir], [${localstatedir}/lib/${PACKAGE_NAME}],
  66   [dpkg database directory [LOCALSTATEDIR/lib/dpkg]])
  67 DPKG_WITH_DIR([backupsdir], [${localstatedir}/backups],
  68   [dpkg database backups directory [LOCALSTATEDIR/backups]])
  69 DPKG_WITH_DIR([logdir], [${localstatedir}/log],
  70   [system logging directory [LOCALSTATEDIR/log]])
  71 DPKG_WITH_DIR([zshcompletionsdir], [${datadir}/zsh/vendor-completions],
  72   [zsh vendor completions directory [DATADIR/zsh/vendor-completions]])
  73
  74 # Set default dpkg-deb values
  75 DPKG_DEB_COMPRESSOR([xz])
  76
  77 # Checks for programs.
  78 DPKG_PROG_SHELL
  79 DPKG_PROG_PAGER
  80 AC_PROG_SED
  81 AC_PROG_GREP
  82 AC_PROG_EGREP
  83 AC_PROG_CC
  84 DPKG_C_C99
  85 AC_PROG_CXX
  86 DPKG_CXX_CXX11
  87 DPKG_PROG_PATCH
  88 AC_CHECK_PROGS([DOXYGEN], [doxygen])
  89 AC_CHECK_PROG([HAVE_DOT], [dot], [YES], [NO])
  90 DPKG_PROG_TAR
  91 DPKG_PROG_PO4A
  92 DPKG_PROG_PERL
  93 DPKG_PROG_POD2MAN
  94 DPKG_CODE_COVERAGE
  95
  96 # Checks for operating system services and capabilities.
  97 AC_SYS_LARGEFILE
  98
  99 # Checks for libraries.
 100 DPKG_LIB_RT
 101 DPKG_LIB_MD
 102 DPKG_LIB_Z
 103 DPKG_LIB_BZ2
 104 DPKG_LIB_LZMA
 105 DPKG_LIB_ZSTD
 106 DPKG_LIB_SELINUX
 107 AS_IF([test "x$build_dselect" = "xyes"], [
 108   DPKG_LIB_CURSES
 109 ])
 110 AS_IF([test "x$build_start_stop_daemon" = "xyes"], [
 111   DPKG_LIB_SOCKET
 112   DPKG_LIB_PS
 113   DPKG_LIB_KVM
 114 ])
 115
 116 # Checks for header files.
 117 AC_CHECK_HEADERS([\
 118   stddef.h \
 119   error.h \
 120   err.h \
 121   locale.h \
 122   xlocale.h \
 123   libintl.h \
 124   kvm.h \
 125   sys/sysmacros.h \
 126   sys/param.h \
 127   sys/syscall.h \
 128   sys/user.h \
 129   sys/mkdev.h \
 130   sys/pstat.h \
 131   linux/fiemap.h \
 132 ])
 133 AS_CASE([$host_os],
 134   [linux-gnu*], [
 135     # The glibc project has deprecated the <sys/sysctl.h> header and emits
 136     # warnings on its usage, and removed it in 2.32. The Linux kernel removed
 137     # support for it in 5.5.
 138   ], [
 139     # On other systems, we need to check whether to use it.
 140     AC_CHECK_HEADERS([\
 141       sys/sysctl.h \
 142     ])
 143   ]
 144 )
 145 DPKG_CHECK_HEADER_SYS_PROCFS
 146 AC_CHECK_HEADERS([sys/proc.h], [], [], [
 147 #ifdef HAVE_SYS_PARAM_H
 148 #include <sys/param.h>
 149 #endif
 150 ])
 151
 152 AS_IF([test "x$build_dselect" = "xyes"], [
 153   AC_LANG_PUSH([C++])
 154   AC_CHECK_HEADERS([cxxabi.h])
 155   AC_LANG_POP([C++])
 156 ])
 157
 158 # Checks for typedefs, structures, and compiler characteristics.
 159 DPKG_ARCH_ABI
 160 AC_C_CONST
 161 AC_C_INLINE
 162 AC_C_VOLATILE
 163 AC_TYPE_MODE_T
 164 AC_TYPE_PID_T
 165 AC_TYPE_SIZE_T
 166 DPKG_TYPE_PTRDIFF_T
 167 DPKG_TYPE_STRUCT_PSINFO
 168 DPKG_DECL_SYS_SIGLIST
 169 DPKG_DECL_SYS_ERRLIST
 170
 171 # Checks for library functions.
 172 DPKG_FUNC_VA_COPY
 173 DPKG_FUNC_C99_SNPRINTF
 174 DPKG_FUNC_FSYNC_DIR
 175 DPKG_CHECK_DECL([offsetof], [stddef.h])
 176 DPKG_CHECK_DECL([makedev], [sys/types.h])
 177 DPKG_CHECK_DECL([WCOREDUMP], [sys/wait.h])
 178 DPKG_CHECK_DECL([TIOCNOTTY], [sys/ioctl.h])
 179 DPKG_CHECK_DECL([O_NOFOLLOW], [fcntl.h])
 180 DPKG_CHECK_DECL([F_ALLOCSP64], [fcntl.h])
 181 DPKG_CHECK_DECL([F_PREALLOCATE], [fcntl.h])
 182 DPKG_CHECK_DECL([P_tmpdir], [stdio.h])
 183 DPKG_CHECK_PROGNAME
 184 DPKG_CHECK_COMPAT_FUNCS([\
 185   getopt \
 186   getopt_long \
 187   obstack_free \
 188   strchrnul \
 189   strnlen \
 190   strndup \
 191   strerror \
 192   strsignal \
 193   asprintf \
 194   scandir \
 195   alphasort \
 196   unsetenv \
 197 ])
 198 AC_CHECK_FUNCS([memcpy lchown],
 199   [], [AC_MSG_ERROR([missing required function])])
 200 AC_CHECK_FUNCS([\
 201   strtoimax \
 202   isascii \
 203   setsid \
 204   getdtablesize \
 205   getprocs64 \
 206   getprogname \
 207   getexecname \
 208   lutimes \
 209   fallocate \
 210   posix_fallocate \
 211   posix_fadvise \
 212   uselocale \
 213 ])
 214
 215 AS_IF([test "x$build_dselect" = "xyes"], [
 216   AC_LANG_PUSH([C++])
 217   AC_CHECK_FUNCS([__cxa_pure_virtual])
 218   AC_LANG_POP([C++])
 219 ])
 220
 221 DPKG_USE_MMAP
 222 DPKG_USE_DISK_PREALLOCATE
 223
 224 # Checks for the build machinery.
 225 AC_DEFINE([LIBDPKG_VOLATILE_API], [1], [Acknowledge the volatility of the API.])
 226 DPKG_COMPILER_WARNINGS
 227 DPKG_COMPILER_SANITIZER
 228 DPKG_COMPILER_ANALYZER
 229 DPKG_COMPILER_OPTIMIZATIONS
 230 DPKG_LINKER_OPTIMIZATIONS
 231 DPKG_ARCHITECTURE
 232 AC_DEFINE([PACKAGE_RELEASE], [PACKAGE_VERSION " (" ARCHITECTURE ")"],
 233   [Define the project release information, version and architecture])
 234
 235 AC_CONFIG_TESTDIR([src/at])
 236 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 237
 238 AC_CONFIG_FILES([
 239   Makefile
 240   dselect/Makefile
 241   dselect/methods/Makefile
 242   dselect/po/Makefile.in
 243   lib/Makefile
 244   lib/compat/Makefile
 245   lib/dpkg/Makefile
 246   lib/dpkg/libdpkg.pc
 247   doc/Doxyfile
 248   man/Makefile
 249   po/Makefile.in
 250   scripts/Build.PL
 251   scripts/Makefile
 252   scripts/README.cpan
 253   scripts/mk/Makefile
 254   scripts/po/Makefile.in
 255   src/Makefile
 256   src/at/atlocal
 257   utils/Makefile
 258 ])
 259 AC_CONFIG_HEADERS([config.h])
 260 AC_OUTPUT
 261
 262 # Print the current configuration
 263 cat <<CONFIG
 264
 265 Configuration:
 266   Arch attributes:
 267     cpu name  . . . . . . . . . . : ${cpu_type}
 268     os name . . . . . . . . . . . : ${os_type}
 269     arch name . . . . . . . . . . : ${dpkg_arch}
 270     arch bits . . . . . . . . . . : ${dpkg_arch_bits}
 271     arch endian . . . . . . . . . : ${dpkg_arch_endian}
 272     char bits . . . . . . . . . . : ${dpkg_char_bits}
 273     char sign . . . . . . . . . . : ${dpkg_char_sign}
 274     sizeof(short) . . . . . . . . : ${ac_cv_sizeof_short}
 275     sizeof(int) . . . . . . . . . : ${ac_cv_sizeof_int}
 276     sizeof(long)  . . . . . . . . : ${ac_cv_sizeof_long}
 277     sizeof(long long) . . . . . . : ${ac_cv_sizeof_long_long}
 278     sizeof(float) . . . . . . . . : ${ac_cv_sizeof_float}
 279     sizeof(double)  . . . . . . . : ${ac_cv_sizeof_double}
 280     sizeof(long double) . . . . . : ${ac_cv_sizeof_long_double}
 281     sizeof(void *)  . . . . . . . : ${ac_cv_sizeof_void_p}
 282     alignof(max_align_t)  . . . . : ${ac_cv_alignof_max_align_t}
 283
 284   Features:
 285     native language support . . . : $USE_NLS
 286     unicode support . . . . . . . : $USE_UNICODE
 287     development documentation . . : $build_devel_docs
 288     code coverage . . . . . . . . : $enable_coverage
 289     build shared libraries  . . . : $enable_shared
 290     mmap loaders  . . . . . . . . : $enable_mmap
 291     disk pre-allocation . . . . . : $enable_disk_preallocate
 292     default dpkg-deb compressor . : $with_deb_compressor
 293     default shell interpreter . . : $DPKG_SHELL
 294     default pager program . . . . : $DPKG_PAGER
 295
 296   Paths:
 297     devlibdir . . . . . . . . . . : $devlibdir
 298     pkgconfdir  . . . . . . . . . : $pkgconfdir
 299     admindir  . . . . . . . . . . : $admindir
 300     backupsdir  . . . . . . . . . : $backupsdir
 301     logdir  . . . . . . . . . . . : $logdir
 302     perl interpreter  . . . . . . : $PERL
 303     perl libdir . . . . . . . . . : $PERL_LIBDIR
 304
 305   Programs:
 306     update-alternatives . . . . . : $build_update_alternatives
 307     start-stop-daemon . . . . . . : $build_start_stop_daemon
 308     dselect . . . . . . . . . . . : $build_dselect
 309
 310   System Libraries:
 311     librt . . . . . . . . . . . . : $have_librt
 312     libsocket . . . . . . . . . . : ${have_libsocket:-no}
 313     libps . . . . . . . . . . . . : ${have_libps:-no}
 314     libkvm  . . . . . . . . . . . : ${have_libkvm:-no}
 315     libselinux  . . . . . . . . . : $have_libselinux
 316     libmd . . . . . . . . . . . . : $have_libmd
 317     libz  . . . . . . . . . . . . : $have_libz_impl
 318     liblzma . . . . . . . . . . . : $have_liblzma
 319     libzstd . . . . . . . . . . . : $have_libzstd
 320     libbz2  . . . . . . . . . . . : $have_libbz2
 321     libcurses . . . . . . . . . . : ${have_libcurses:-no}
 322 CONFIG