dev-cpp/glog/glog-0.6.0.ebuild

   1 # Copyright 2011-2024 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="8"
   5
   6 inherit cmake-multilib
   7
   8 if [[ "${PV}" == "9999" ]]; then
   9         inherit git-r3
  10
  11         EGIT_REPO_URI="https://github.com/google/glog"
  12 fi
  13
  14 DESCRIPTION="Google Logging library"
  15 HOMEPAGE="https://github.com/google/glog"
  16 if [[ "${PV}" == "9999" ]]; then
  17         SRC_URI=""
  18 else
  19         SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  20 fi
  21
  22 LICENSE="BSD"
  23 SLOT="0/1"
  24 KEYWORDS="amd64 ~arm ~arm64 ~hppa ~loong ~mips ppc ~ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
  25 IUSE="gflags +libunwind llvm-libunwind test"
  26 RESTRICT="!test? ( test )"
  27
  28 RDEPEND="gflags? ( dev-cpp/gflags:0=[${MULTILIB_USEDEP}] )
  29         libunwind? (
  30                 llvm-libunwind? ( llvm-runtimes/libunwind:0=[${MULTILIB_USEDEP}] )
  31                 !llvm-libunwind? ( sys-libs/libunwind:0=[${MULTILIB_USEDEP}] )
  32         )
  33 "
  34 DEPEND="${RDEPEND}
  35         test? ( >=dev-cpp/gtest-1.8.0[${MULTILIB_USEDEP}] )
  36 "
  37
  38 PATCHES=(
  39         "${FILESDIR}/${P}-disable-symbolize-test.patch" # bug 863599
  40         "${FILESDIR}/${P}-try-fix-logging-test.patch"
  41 )
  42
  43 src_configure() {
  44         local mycmakeargs=(
  45                 -DBUILD_TESTING=$(usex test ON OFF)
  46                 -DWITH_GFLAGS=$(usex gflags ON OFF)
  47                 -DWITH_GTEST=$(usex test ON OFF)
  48                 -DWITH_UNWIND=$(usex libunwind ON OFF)
  49         )
  50
  51         cmake-multilib_src_configure
  52 }
  53
  54 src_test() {
  55         cmake-multilib_src_test -j1
  56 }