games-arcade/conveysdl/conveysdl-1.3-r2.ebuild

   1 # Copyright 1999-2022 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=8
   5
   6 inherit desktop flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="Guide the blob along the conveyer belt collecting the red blobs"
   9 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
  10 SRC_URI="
  11         mirror://gentoo/${P/-/.}.tar
  12         https://dev.gentoo.org/~ionen/distfiles/${PN}.png"
  13 S="${WORKDIR}"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18
  19 RDEPEND="
  20         media-libs/libsdl[sound,video]
  21         media-libs/sdl-mixer"
  22 DEPEND="${RDEPEND}"
  23 BDEPEND="virtual/pkgconfig"
  24
  25 PATCHES=(
  26         "${FILESDIR}"/${P}-arrays.patch
  27         "${FILESDIR}"/${P}-audio.patch
  28         "${FILESDIR}"/${P}-speed.patch
  29         "${FILESDIR}"/${P}-clang16.patch
  30 )
  31
  32 src_compile() {
  33         tc-export CC
  34
  35         append-cppflags $($(tc-getPKG_CONFIG) --cflags sdl SDL_mixer || die) \
  36                 -DDATA_PREFIX="'\"${EPREFIX}/usr/share/${PN}/\"'" \
  37                 -DENABLE_SOUND
  38         append-libs $($(tc-getPKG_CONFIG) --libs sdl SDL_mixer || die)
  39
  40         emake main LDLIBS="${LIBS}"
  41 }
  42
  43 src_install() {
  44         newbin main ${PN}
  45
  46         insinto /usr/share/${PN}
  47         doins -r gfx levels sounds
  48
  49         doicon "${DISTDIR}"/${PN}.png
  50         make_desktop_entry ${PN} Convey
  51
  52         dodoc readme
  53 }