gio/gdbus-2.0/codegen/meson.build

   1 gdbus_codegen_files = [
   2   '__init__.py',
   3   'codegen.py',
   4   'codegen_main.py',
   5   'codegen_docbook.py',
   6   'dbustypes.py',
   7   'parser.py',
   8   'utils.py',
   9 ]
  10
  11 gdbus_codegen_conf = configuration_data()
  12 gdbus_codegen_conf.set('VERSION', glib_version)
  13 gdbus_codegen_conf.set('PYTHON', python.path())
  14 gdbus_codegen_conf.set('DATADIR', glib_datadir)
  15
  16 # Install gdbus-codegen executable
  17 gdbus_codegen = configure_file(input : 'gdbus-codegen.in',
  18   output : 'gdbus-codegen',
  19   install : true,
  20   install_dir : get_option('bindir'),
  21   configuration : gdbus_codegen_conf
  22 )
  23
  24 codegen_dir = join_paths(get_option('datadir'), 'glib-2.0/codegen')
  25
  26 gdbus_codegen_built_files = []
  27 gdbus_codegen_built_files += configure_file(input : 'config.py.in',
  28                                             output : 'config.py',
  29                                             install : true,
  30                                             install_dir : codegen_dir,
  31                                             configuration : gdbus_codegen_conf)
  32
  33 foreach f : gdbus_codegen_files
  34   # Copy these into the builddir so that gdbus-codegen can be used uninstalled
  35   # and then install it too so that it can be used after installation
  36   gdbus_codegen_built_files += configure_file(input : f, output : f,
  37                                               install : true,
  38                                               install_dir : codegen_dir,
  39                                               copy : true)
  40 endforeach