configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AM_PATH_PYTHON
  22 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  23 test "$CLANG_FORMAT" = no && CLANG_FORMAT=true
  24
  25 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  26
  27 AC_PREFIX_DEFAULT(/usr/heimdal)
  28
  29 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  30 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  31
  32 AC_CANONICAL_HOST
  33 CANONICAL_HOST=$host
  34 AC_SUBST(CANONICAL_HOST)
  35
  36 rk_SYS_LARGEFILE
  37
  38 rk_AIX
  39 rk_IRIX
  40 rk_SUNOS
  41
  42 dnl
  43 dnl this is needed to run the configure tests against glibc
  44 dnl
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46         [Define to enable extensions on glibc-based systems such as Linux.])
  47
  48 AC_OBJEXT
  49 AC_EXEEXT
  50
  51 dnl
  52 dnl this is needed when der-protos.h or der-private.h has to be generated
  53 dnl
  54 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  55    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  56     AC_KRB_PROG_PERL
  57     AC_KRB_PERL_MOD(Getopt::Std)
  58     AC_KRB_PERL_MOD(File::Compare)
  59     AC_KRB_PERL_MOD(JSON)
  60 fi
  61
  62 AC_KRB_PROG_YACC
  63 dnl AC_PROG_YACC
  64 AM_PROG_LEX
  65 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  66       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  67       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  68 dnl AC_PROG_RANLIB
  69 AC_PROG_AWK
  70 AC_KRB_PROG_LN_S
  71
  72 AC_MIPS_ABI
  73 CC="$CC $abi"
  74 libdir="$libdir$abilibdirext"
  75
  76 AC_C___ATTRIBUTE__
  77
  78 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  79 rk_VERSIONSCRIPT
  80
  81 dnl Code coverage
  82 AC_ARG_ENABLE([gcov],
  83         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  84 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  85
  86
  87 dnl
  88 dnl Helper bits for cross compiling
  89 dnl
  90
  91 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  92
  93 AC_ARG_WITH(cross-tools,
  94         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  95         [if test "$withval" = "yes"; then
  96                 AC_MSG_ERROR([Need path to cross tools])
  97         fi
  98         with_cross_tools="${with_cross_tools}/"
  99         ])
 100
 101 if test "${cross_compiling}" != yes ; then
 102
 103    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 104    SLC="\$(top_builddir)/lib/sl/slc"
 105
 106    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 107    SLC_DEP="\$(SLC)"
 108 else
 109    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 110    SLC="${with_cross_tools}slc"
 111
 112    ASN1_COMPILE_DEP=
 113    SLC_DEP=
 114
 115    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 116
 117 fi
 118
 119 AX_CHECK_COMPILE_FLAG([-Wno-error=enum-conversion],
 120                       [WFLAGS_ENUM_CONV=-Wno-error=enum-conversion],
 121                       [WFLAGS_ENUM_CONV=], [-Werror])
 122 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable],
 123                       [WFLAGS_UNUSED_BUT_SET_VAR=-Wno-unused-but-set-variable],
 124                       [WFLAGS_UNUSED_BUT_SET_VAR=], [-Werror])
 125
 126 AC_SUBST([WFLAGS_ENUM_CONV])
 127 AC_SUBST([ASN1_COMPILE])
 128 AC_SUBST([ASN1_COMPILE_DEP])
 129 AC_SUBST([SLC])
 130 AC_SUBST([SLC_DEP])
 131
 132 dnl ---
 133
 134 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 135
 136 rk_TEST_PACKAGE(openldap,
 137 [#include <lber.h>
 138 #include <ldap.h>],
 139 [-lldap -llber],,,OPENLDAP)
 140 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 141
 142 AC_ARG_ENABLE(hdb-openldap-module,
 143         AS_HELP_STRING([--enable-hdb-openldap-module],
 144                 [if you want support to build openldap hdb as shared object]))
 145 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 146     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 147 fi
 148 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 149
 150 AC_ARG_ENABLE(asn1-templating,
 151         AS_HELP_STRING([--disable-asn1-templating],
 152                 [if you want disable to use of the ASN.1 templating compiler]))
 153 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 154
 155 dnl
 156 dnl Optional modules, pk-init, digest, kx509
 157 dnl
 158
 159 AC_ARG_ENABLE(pk-init,
 160         AS_HELP_STRING([--disable-pk-init],
 161                 [if you want disable to PK-INIT support]))
 162 if test "$enable_pk_init" != no ;then
 163         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 164 fi
 165 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 166
 167 AC_ARG_ENABLE(digest,
 168         AS_HELP_STRING([--disable-digest],
 169                 [if you want disable to DIGEST support]))
 170 if test "$enable_digest" != no ;then
 171         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 172 fi
 173
 174 AC_ARG_ENABLE(kx509,
 175         AS_HELP_STRING([--disable-kx509],
 176                 [if you want disable to kx509 support]))
 177 if test "$enable_kx509" != no ;then
 178         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 179 fi
 180
 181 dnl Need to test if pkg-config exists
 182 PKG_PROG_PKG_CONFIG
 183
 184 dnl libcap-ng
 185 AC_ARG_WITH([capng],
 186   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 187   [],
 188   [with_capng=check])
 189 if test "$with_capng" != "no"; then
 190   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 191                     [with_capng=yes],[with_capng=no])
 192 fi
 193 if test "$with_capng" = "yes"; then
 194   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 195 fi
 196 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 197 AC_SUBST([CAPNG_CFLAGS])
 198 AC_SUBST([CAPNG_LIBS])
 199
 200 dnl libmicrohttpd
 201 AC_ARG_WITH([microhttpd],
 202   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 203   [],
 204   [with_microhttpd=check])
 205 if test "$with_microhttpd" != "no"; then
 206   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 207                     [with_microhttpd=yes],[with_microhttpd=no])
 208 fi
 209 if test "$with_microhttpd" = "yes"; then
 210   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 211 fi
 212 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 213 AC_SUBST([MICROHTTPD_CFLAGS])
 214 AC_SUBST([MICROHTTPD_LIBS])
 215
 216 dnl libcjwt
 217 AC_ARG_WITH([cjwt],
 218   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 219   [],
 220   [with_cjwt=check])
 221 if test "$with_cjwt" != "no"; then
 222   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 223                     [with_cjwt=yes],[with_cjwt=no])
 224 fi
 225 if test "$with_cjwt" = "yes"; then
 226   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 227 fi
 228 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 229 AC_SUBST([CJWT_CFLAGS])
 230 AC_SUBST([CJWT_LIBS])
 231
 232 dnl libcjson
 233 AC_ARG_WITH([cjson],
 234   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 235   [],
 236   [with_cjson=check])
 237 if test "$with_cjson" != "no"; then
 238   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 239                     [with_cjson=yes],[with_cjson=no])
 240 fi
 241 if test "$with_cjson" = "yes"; then
 242   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 243 fi
 244 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 245 AC_SUBST([CJSON_CFLAGS])
 246 AC_SUBST([CJSON_LIBS])
 247
 248 dnl Check for sqlite
 249 rk_TEST_PACKAGE(sqlite3,
 250 [#include <sqlite3.h>
 251 #ifndef SQLITE_OPEN_CREATE
 252 #error "old version"
 253 #endif],
 254 [-lsqlite3],,,SQLITE3)
 255
 256 if test "X$with_sqlite3" != Xyes ; then
 257    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 258    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 259 fi
 260 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 261
 262 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 263
 264 AC_ARG_ENABLE(sqlite-cache,
 265         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 266 if test "$enable_sqlite_cache" != no; then
 267     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 268 fi
 269 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 270
 271
 272 dnl check for libintl
 273 rk_TEST_PACKAGE(libintl,
 274 [#include <libintl.h>],
 275 [-lintl],,,LIBINTL)
 276
 277 dnl path where the hdb directory is stored
 278 AC_ARG_WITH([hdbdir],
 279         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 280         [],
 281         [with_hdbdir=/var/heimdal])
 282 DIR_hdbdir="$with_hdbdir"
 283 AC_SUBST([DIR_hdbdir])
 284
 285
 286 AM_CONDITIONAL(KRB5, true)
 287 AM_CONDITIONAL(do_roken_rename, true)
 288
 289 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 290
 291
 292 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 293 AC_SUBST(LIB_kdb)dnl
 294
 295 KRB_CRYPTO
 296
 297 KRB_PTHREADS
 298
 299 AC_ARG_ENABLE(dce,
 300         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 301 if test "$enable_dce" = yes; then
 302     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 303 fi
 304 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 305
 306 ## XXX quite horrible:
 307 if test -f /etc/ibmcxx.cfg; then
 308         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 309         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 310         dpagaix_ldflags=
 311 else
 312         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 313         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 314         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 315 fi
 316 AC_SUBST(dpagaix_cflags)
 317 AC_SUBST(dpagaix_ldadd)
 318 AC_SUBST(dpagaix_ldflags)
 319
 320 AC_ARG_ENABLE([afs-support],
 321         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 322 if test "$enable_afs_support" = no; then
 323         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 324         NO_AFS="1"
 325 fi
 326 AC_SUBST(NO_AFS)dnl
 327 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 328
 329 rk_DB
 330
 331 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 332
 333 rk_ROKEN(lib/roken)
 334 LIBADD_roken="$LIB_roken"
 335 AC_SUBST(LIBADD_roken)dnl
 336 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 337
 338 rk_OTP
 339
 340 rk_LIBDISPATCH
 341
 342 AC_CHECK_OSFC2
 343
 344 AC_ARG_ENABLE(mmap,
 345         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 346 if test "$enable_mmap" = "no"; then
 347         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 348 fi
 349
 350 AC_ARG_ENABLE(afs-string-to-key,
 351         AS_HELP_STRING([--disable-afs-string-to-key],
 352         [disable use of weak AFS string-to-key functions]),
 353         [], [enable_afs_string_to_key=yes])
 354
 355 if test "$enable_afs_string_to_key" = "yes"; then
 356         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 357         ENABLE_AFS_STRING_TO_KEY=1
 358 fi
 359 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 360
 361
 362 rk_CHECK_MAN
 363
 364 rk_TEST_PACKAGE(readline,
 365 [#include <stdio.h>
 366 #if defined(HAVE_READLINE_READLINE_H)
 367 #include <readline/readline.h>
 368 #elif defined(HAVE_READLINE_H)
 369 #include <readline.h>
 370 #endif
 371 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 372
 373 rk_TEST_PACKAGE(libedit,
 374 [#include <stdio.h>
 375 #if defined(HAVE_READLINE_READLINE_H)
 376 #include <readline/readline.h>
 377 #elif defined(HAVE_READLINE_H)
 378 #include <readline.h>
 379 #elif defined(HAVE_EDITLINE_READLINE_H)
 380 #include <editline/readline.h>
 381 #endif
 382 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 383
 384 AC_CONFIG_SUBDIRS([lib/libedit])
 385
 386 KRB_C_BIGENDIAN
 387 AC_C_INLINE
 388
 389 dnl AM_C_PROTOTYPES
 390
 391 dnl Checks for typedefs, structures, and compiler characteristics.
 392 AC_C_CONST
 393 AC_TYPE_OFF_T
 394 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 395 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 396 AC_HAVE_TYPE([long long])
 397 AC_HEADER_TIME
 398 AC_STRUCT_TM
 399
 400 dnl Checks for header files.
 401 AC_HEADER_STDC
 402
 403 AC_CHECK_HEADERS([\
 404         CommonCrypto/CommonDigest.h             \
 405         CommonCrypto/CommonCryptor.h            \
 406         arpa/telnet.h                           \
 407         bind/bitypes.h                          \
 408         bsdsetjmp.h                             \
 409         curses.h                                \
 410         dlfcn.h                                 \
 411         execinfo.h                              \
 412         fnmatch.h                               \
 413         inttypes.h                              \
 414         io.h                                    \
 415         keyutils.h                              \
 416         libutil.h                               \
 417         limits.h                                \
 418         maillock.h                              \
 419         netgroup.h                              \
 420         netinet/in6_machtypes.h                 \
 421         netinet/tcp.h                           \
 422         pthread.h                               \
 423         pty.h                                   \
 424         sac.h                                   \
 425         sgtty.h                                 \
 426         siad.h                                  \
 427         signal.h                                \
 428         strings.h                               \
 429         stropts.h                               \
 430         stdatomic.h                             \
 431         sys/bitypes.h                           \
 432         sys/category.h                          \
 433         sys/file.h                              \
 434         sys/filio.h                             \
 435         sys/ioccom.h                            \
 436         sys/mman.h                              \
 437         sys/param.h                             \
 438         sys/pty.h                               \
 439         sys/ptyio.h                             \
 440         sys/select.h                            \
 441         sys/socket.h                            \
 442         sys/str_tty.h                           \
 443         sys/stream.h                            \
 444         sys/stropts.h                           \
 445         sys/syscall.h                           \
 446         sys/termio.h                            \
 447         sys/timeb.h                             \
 448         sys/times.h                             \
 449         sys/types.h                             \
 450         sys/un.h                                \
 451         locale.h                                \
 452         termcap.h                               \
 453         termio.h                                \
 454         termios.h                               \
 455         time.h                                  \
 456         tmpdir.h                                \
 457         udb.h                                   \
 458         util.h                                  \
 459 ])
 460
 461 dnl On Solaris 8 there's a compilation warning for term.h because
 462 dnl it doesn't define `bool'.
 463 AC_CHECK_HEADERS(term.h, , , -)
 464
 465 dnl aix have asl.h (A/IX screen library) that we don't want
 466 AC_CHECK_HEADERS(asl.h, , , [
 467 #include <asl.h>
 468 #ifndef ASL_STRING_EMERG
 469 #error ASL_STRING_EMERG missing
 470 #endif])
 471
 472 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 473 #if HAVE_SYS_SOCKET_H
 474 #include <sys/socket.h>
 475 #endif])
 476
 477 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 478 #if HAVE_SYS_TTY_H
 479 #include <sys/tty.h>
 480 #endif])
 481
 482 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 483 #if HAVE_TERMIOS_H
 484 #include <termios.h>
 485 #endif
 486 #if HAVE_SYS_STREAM_H
 487 #include <sys/stream.h>
 488 #endif])
 489
 490 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 491 #if HAVE_SYS_TYPES_H
 492 #include <sys/types.h>
 493 #endif
 494 #if HAVE_SYS_PARAM_H
 495 #include <sys/param.h>
 496 #endif])
 497
 498 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 499 #include <security/pam_appl.h>
 500 ])
 501
 502 dnl export symbols
 503 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 504 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 505 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 506 rk_WIN32_EXPORT(BUILD_KDC_LIB, KDC_LIB)
 507
 508 dnl Deal with switch FALLTHROUGH
 509 AH_TOP([
 510 #if defined(__GNUC__)
 511 #if __GNUC__ >= 7
 512 # define fallthrough __attribute__((fallthrough))
 513 #else
 514 # define fallthrough do {} while (0) /* fallthrough */
 515 #endif
 516 #else
 517 # define fallthrough  do {} while (0) /* fallthrough */
 518 #endif
 519 ])
 520
 521 dnl Checks for libraries.
 522
 523 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 524 #ifdef HAVE_UTIL_H
 525 #include <util.h>
 526 #endif
 527 ],[0,0,0,0,0])
 528
 529 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 530 #ifdef HAVE_TERMCAP_H
 531 #include <termcap.h>
 532 #endif
 533 #ifdef HAVE_CURSES_H
 534 #include <curses.h>
 535 #endif
 536 ],[0,0])
 537
 538 dnl Checks for library functions.
 539
 540 AC_CHECK_FUNCS([                                \
 541         _scrsize                                \
 542         arc4random                              \
 543         backtrace                               \
 544         fcntl                                   \
 545         fork                                    \
 546         fseeko                                  \
 547         ftello                                  \
 548         getpeereid                              \
 549         getpeerucred                            \
 550         getresgid                               \
 551         getresuid                               \
 552         grantpt                                 \
 553         ptsname_r                               \
 554         rand                                    \
 555         setitimer                               \
 556         setregid                                \
 557         setresgid                               \
 558         setresuid                               \
 559         setreuid                                \
 560         setsid                                  \
 561         sigaction                               \
 562         unlockpt                                \
 563         waitpid                                 \
 564 ])
 565
 566 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 567 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 568         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 569         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 570 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 571         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 572 fi
 573 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 574
 575 AC_FUNC_MMAP
 576
 577 rk_DLADDR
 578
 579 AC_CHECK_GETPWNAM_R_POSIX
 580 AC_CHECK_GETPWUID_R_POSIX
 581
 582 dnl detect doors on solaris
 583 if test "$enable_pthread_support" != no; then
 584    saved_LIBS="$LIBS"
 585    LIBS="$LIBS $PTHREADS_LIBS"
 586    AC_FIND_FUNC_NO_LIBS(door_create, door)
 587    LIBS="$saved_LIBS"
 588 fi
 589
 590 AC_ARG_ENABLE(kcm,
 591         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 592 ,[enable_kcm=yes])
 593
 594 if test "$enable_kcm" = yes ; then
 595    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 596         enable_kcm=no
 597    fi
 598 fi
 599 if test "$enable_kcm" = yes; then
 600        AC_DEFINE(HAVE_KCM, 1,
 601                [Define if you want to use the Kerberos Credentials Manager.])
 602 fi
 603 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 604
 605 dnl detect keyring on Linux
 606 if test "$ac_cv_header_keyutils_h" = yes; then
 607     AC_CHECK_SIZEOF([key_serial_t],,[
 608         #ifdef HAVE_INTTYPES_H
 609         #include <inttypes.h>
 610         #endif
 611         #ifdef HAVE_SYS_TYPES_H
 612         #include <sys/types.h>
 613         #endif
 614         #include <keyutils.h>
 615     ])
 616 fi
 617
 618 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 619 if test -n "$LIB_add_key"; then
 620     saved_LIBS="$LIBS"
 621     LIBS="$LIBS $LIB_add_key"
 622     AC_CHECK_FUNCS(keyctl_get_persistent)
 623     LIBS="$saved_LIBS"
 624 fi
 625 AM_CONDITIONAL(HAVE_KEYUTILS, test "$ac_cv_func_keyctl_get_persistent" = yes)
 626
 627 AC_CHECK_SIZEOF([time_t])
 628
 629 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 630         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 631         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 632 #ifdef HAVE_INTTYPES_H
 633 #include <inttypes.h>
 634 #endif
 635 #ifdef HAVE_SYS_TYPES_H
 636 #include <sys/types.h>
 637 #endif
 638 #ifdef HAVE_SYS_BITYPES_H
 639 #include <sys/bitypes.h>
 640 #endif
 641 #ifdef HAVE_BIND_BITYPES_H
 642 #include <bind/bitypes.h>
 643 #endif
 644 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 645 #include <netinet/in6_machtypes.h>
 646 #endif
 647 ])
 648
 649 rk_FRAMEWORK_SECURITY
 650 rk_FRAMEWORK_COREFOUNDATION
 651
 652 KRB_READLINE
 653
 654 rk_TELNET
 655
 656 dnl Some operating systems already have com_err and compile_et
 657 CHECK_COMPILE_ET
 658
 659 rk_AUTH_MODULES([sia afskauthlib])
 660
 661 rk_DESTDIRS
 662
 663 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 664
 665
 666 AH_BOTTOM([#ifdef __APPLE__
 667 #include <AvailabilityMacros.h>
 668 #endif])
 669
 670 AH_BOTTOM([#ifdef ROKEN_RENAME
 671 #include "roken_rename.h"
 672 #endif])
 673
 674 AC_ARG_ENABLE(heimdal-documentation,
 675         AS_HELP_STRING([--disable-heimdal-documentation],
 676                 [if you want disable to heimdal documentation]))
 677 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 678
 679 AC_CONFIG_FILES(Makefile                \
 680         etc/Makefile                    \
 681         include/Makefile                \
 682         include/gssapi/Makefile         \
 683         include/hcrypto/Makefile        \
 684         include/kadm5/Makefile          \
 685         lib/Makefile                    \
 686         lib/base/Makefile                       \
 687         lib/asn1/Makefile               \
 688         lib/com_err/Makefile            \
 689         lib/hcrypto/Makefile            \
 690         lib/hx509/Makefile              \
 691         lib/gssapi/Makefile             \
 692         lib/ntlm/Makefile               \
 693         lib/hdb/Makefile                \
 694         lib/ipc/Makefile                \
 695         lib/kadm5/Makefile              \
 696         lib/kafs/Makefile               \
 697         lib/kdfs/Makefile               \
 698         lib/krb5/Makefile               \
 699         lib/otp/Makefile                \
 700         lib/roken/Makefile              \
 701         lib/sl/Makefile                 \
 702         lib/sqlite/Makefile             \
 703         lib/vers/Makefile               \
 704         lib/wind/Makefile               \
 705         lib/gss_preauth/Makefile        \
 706         po/Makefile                     \
 707         kuser/Makefile                  \
 708         kpasswd/Makefile                \
 709         kadmin/Makefile                 \
 710         admin/Makefile                  \
 711         kcm/Makefile                    \
 712         kdc/Makefile                    \
 713         appl/Makefile                   \
 714         appl/afsutil/Makefile           \
 715         appl/dbutils/Makefile           \
 716         appl/gssmask/Makefile           \
 717         appl/otp/Makefile               \
 718         appl/test/Makefile              \
 719         appl/kf/Makefile                \
 720         appl/dceutils/Makefile          \
 721         tests/Makefile                  \
 722         tests/bin/Makefile              \
 723         tests/can/Makefile              \
 724         tests/db/Makefile               \
 725         tests/kdc/Makefile              \
 726         tests/ldap/Makefile             \
 727         tests/gss/Makefile              \
 728         tests/java/Makefile             \
 729         tests/plugin/Makefile           \
 730         packages/Makefile               \
 731         packages/mac/Makefile           \
 732         doc/Makefile                    \
 733         tools/Makefile                  \
 734 )
 735
 736 AC_OUTPUT
 737
 738 dnl
 739 dnl This is the release version name-number[beta]
 740 dnl
 741
 742 if test -d "$srcdir/.git"; then
 743     cat > include/newversion.h.in <<EOF
 744 #ifndef VERSION_HIDDEN
 745 #define VERSION_HIDDEN
 746 #endif
 747 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 748 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 749 EOF
 750 else
 751     cat > include/newversion.h.in <<EOF
 752 #ifndef VERSION_HIDDEN
 753 #define VERSION_HIDDEN
 754 #endif
 755 VERSION_HIDDEN const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 756 VERSION_HIDDEN const char *heimdal_version = "AC_PACKAGE_STRING";
 757 EOF
 758 fi
 759
 760 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 761         echo "include/version.h is unchanged"
 762         rm -f include/newversion.h.in
 763 else
 764         echo "creating include/version.h"
 765         if test -n "$SOURCE_DATE_EPOCH"; then
 766             Date=`
 767                   # BSD, OS X
 768                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 769                   # Linux
 770                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 771                   # Illumos -- sorry, no -r/-d here
 772                   date -u ||
 773                   date`
 774         else
 775             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 776         fi
 777         if test -n "$SOURCE_HOST"; then
 778             Host=$SOURCE_HOST
 779         else
 780             Host=`uname -n`
 781         fi
 782         if test -n "$SOURCE_USER"; then
 783             User=$SOURCE_USER
 784         else
 785             User=${USER:-${LOGNAME:-`id -nu`}}
 786         fi
 787         if test -d "$srcdir/.git"; then
 788             GitCommit=`cd $srcdir && git rev-parse HEAD`
 789             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 790             if test "x$GitBranch" = master; then
 791                 GitDesc=`cd $srcdir && git describe --all --dirty`
 792             else
 793                 GitDesc=`cd $srcdir && \
 794                          git describe --tags --match 'heimdal-*' --dirty`
 795             fi
 796         else
 797             GitCommit='<commit-unknown>'
 798             GitBranch='<branch-unknown>'
 799             GitDesc='<tag-unknown>'
 800         fi
 801         mv -f include/newversion.h.in include/version.h.in
 802         sed -e "s/@HOST@/$Host/" \
 803             -e "s;@USER@;$User;" \
 804             -e "s;@DATE@;$Date;" \
 805             -e "s;@BRANCH@;$GitBranch;" \
 806             -e "s;@TAG@;$GitDesc;" \
 807             -e "s;@COMMIT@;$GitCommit;" \
 808             include/version.h.in > include/version.h
 809 fi