configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AM_PATH_PYTHON
  22 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  23 test "$CLANG_FORMAT" = no && CLANG_FORMAT=true
  24
  25 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  26
  27 AC_PREFIX_DEFAULT(/usr/heimdal)
  28
  29 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  30 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  31
  32 AC_CANONICAL_HOST
  33 CANONICAL_HOST=$host
  34 AC_SUBST(CANONICAL_HOST)
  35
  36 rk_SYS_LARGEFILE
  37
  38 rk_AIX
  39 rk_IRIX
  40 rk_SUNOS
  41
  42 dnl
  43 dnl this is needed to run the configure tests against glibc
  44 dnl
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46         [Define to enable extensions on glibc-based systems such as Linux.])
  47
  48 AC_OBJEXT
  49 AC_EXEEXT
  50
  51 dnl
  52 dnl this is needed when der-protos.h or der-private.h has to be generated
  53 dnl
  54 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  55    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  56     AC_KRB_PROG_PERL
  57     AC_KRB_PERL_MOD(Getopt::Std)
  58     AC_KRB_PERL_MOD(File::Compare)
  59     AC_KRB_PERL_MOD(JSON)
  60 fi
  61
  62 AC_KRB_PROG_YACC
  63 dnl AC_PROG_YACC
  64 AM_PROG_LEX
  65 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  66       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  67       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  68 dnl AC_PROG_RANLIB
  69 AC_PROG_AWK
  70 AC_KRB_PROG_LN_S
  71
  72 AC_MIPS_ABI
  73 CC="$CC $abi"
  74 libdir="$libdir$abilibdirext"
  75
  76 AC_C___ATTRIBUTE__
  77
  78 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  79 rk_VERSIONSCRIPT
  80
  81 dnl Code coverage
  82 AC_ARG_ENABLE([gcov],
  83         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  84 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  85
  86
  87 dnl
  88 dnl Helper bits for cross compiling
  89 dnl
  90
  91 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  92
  93 AC_ARG_WITH(cross-tools,
  94         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  95         [if test "$withval" = "yes"; then
  96                 AC_MSG_ERROR([Need path to cross tools])
  97         fi
  98         with_cross_tools="${with_cross_tools}/"
  99         ])
 100
 101 if test "${cross_compiling}" != yes ; then
 102
 103    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 104    SLC="\$(top_builddir)/lib/sl/slc"
 105
 106    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 107    SLC_DEP="\$(SLC)"
 108 else
 109    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 110    SLC="${with_cross_tools}slc"
 111
 112    ASN1_COMPILE_DEP=
 113    SLC_DEP=
 114
 115    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 116
 117 fi
 118
 119 AX_CHECK_COMPILE_FLAG([-Wno-error=enum-conversion],
 120                       [WFLAGS_ENUM_CONV=-Wno-error=enum-conversion],
 121                       [WFLAGS_ENUM_CONV=], [-Werror])
 122 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable],
 123                       [WFLAGS_UNUSED_BUT_SET_VAR=-Wno-unused-but-set-variable],
 124                       [WFLAGS_UNUSED_BUT_SET_VAR=], [-Werror])
 125
 126 AC_SUBST([WFLAGS_ENUM_CONV])
 127 AC_SUBST([ASN1_COMPILE])
 128 AC_SUBST([ASN1_COMPILE_DEP])
 129 AC_SUBST([SLC])
 130 AC_SUBST([SLC_DEP])
 131
 132 dnl ---
 133
 134 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 135
 136 rk_TEST_PACKAGE(openldap,
 137 [#include <lber.h>
 138 #include <ldap.h>],
 139 [-lldap -llber],,,OPENLDAP)
 140 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 141
 142 AC_ARG_ENABLE(hdb-openldap-module,
 143         AS_HELP_STRING([--enable-hdb-openldap-module],
 144                 [if you want support to build openldap hdb as shared object]))
 145 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 146     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 147 fi
 148 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 149
 150 AC_ARG_ENABLE(asn1-templating,
 151         AS_HELP_STRING([--disable-asn1-templating],
 152                 [if you want disable to use of the ASN.1 templating compiler]))
 153 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 154
 155 dnl
 156 dnl Optional modules, pk-init, digest, kx509
 157 dnl
 158
 159 AC_ARG_ENABLE(pk-init,
 160         AS_HELP_STRING([--disable-pk-init],
 161                 [if you want disable to PK-INIT support]))
 162 if test "$enable_pk_init" != no ;then
 163         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 164 fi
 165 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 166
 167 AC_ARG_ENABLE(digest,
 168         AS_HELP_STRING([--disable-digest],
 169                 [if you want disable to DIGEST support]))
 170 if test "$enable_digest" != no ;then
 171         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 172 fi
 173
 174 AC_ARG_ENABLE(kx509,
 175         AS_HELP_STRING([--disable-kx509],
 176                 [if you want disable to kx509 support]))
 177 if test "$enable_kx509" != no ;then
 178         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 179 fi
 180
 181 dnl Need to test if pkg-config exists
 182 PKG_PROG_PKG_CONFIG
 183
 184 dnl libcap-ng
 185 AC_ARG_WITH([capng],
 186   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 187   [],
 188   [with_capng=check])
 189 if test "$with_capng" != "no"; then
 190   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 191                     [with_capng=yes],[with_capng=no])
 192 fi
 193 if test "$with_capng" = "yes"; then
 194   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 195 fi
 196 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 197 AC_SUBST([CAPNG_CFLAGS])
 198 AC_SUBST([CAPNG_LIBS])
 199
 200 dnl libmicrohttpd
 201 AC_ARG_WITH([microhttpd],
 202   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 203   [],
 204   [with_microhttpd=check])
 205 if test "$with_microhttpd" != "no"; then
 206   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 207                     [with_microhttpd=yes],[with_microhttpd=no])
 208 fi
 209 if test "$with_microhttpd" = "yes"; then
 210   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 211 fi
 212 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 213 AC_SUBST([MICROHTTPD_CFLAGS])
 214 AC_SUBST([MICROHTTPD_LIBS])
 215
 216 dnl libcjwt
 217 AC_ARG_WITH([cjwt],
 218   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 219   [],
 220   [with_cjwt=check])
 221 if test "$with_cjwt" != "no"; then
 222   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 223                     [with_cjwt=yes],[with_cjwt=no])
 224 fi
 225 if test "$with_cjwt" = "yes"; then
 226   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 227 fi
 228 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 229 AC_SUBST([CJWT_CFLAGS])
 230 AC_SUBST([CJWT_LIBS])
 231
 232 dnl libcjson
 233 AC_ARG_WITH([cjson],
 234   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 235   [],
 236   [with_cjson=check])
 237 if test "$with_cjson" != "no"; then
 238   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 239                     [with_cjson=yes],[with_cjson=no])
 240 fi
 241 if test "$with_cjson" = "yes"; then
 242   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 243 fi
 244 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 245 AC_SUBST([CJSON_CFLAGS])
 246 AC_SUBST([CJSON_LIBS])
 247
 248 dnl mitkrb5
 249 AC_ARG_WITH([mitkrb5],
 250   AC_HELP_STRING([--with-mitkrb5], [Path to MIT Kerberos for interop testing @<:@default=check@:>@]),
 251   [],
 252   [with_mikrb5=check])
 253 AM_CONDITIONAL([MITKRB5], [test "$with_mitkrb5" != "no"])
 254
 255 dnl Check for sqlite
 256 rk_TEST_PACKAGE(sqlite3,
 257 [#include <sqlite3.h>
 258 #ifndef SQLITE_OPEN_CREATE
 259 #error "old version"
 260 #endif],
 261 [-lsqlite3],,,SQLITE3)
 262
 263 if test "X$with_sqlite3" != Xyes ; then
 264    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 265    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 266 fi
 267 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 268
 269 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 270
 271 AC_ARG_ENABLE(sqlite-cache,
 272         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 273 if test "$enable_sqlite_cache" != no; then
 274     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 275 fi
 276 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 277
 278
 279 dnl check for libintl
 280 rk_TEST_PACKAGE(libintl,
 281 [#include <libintl.h>],
 282 [-lintl],,,LIBINTL)
 283
 284 dnl path where the hdb directory is stored
 285 AC_ARG_WITH([hdbdir],
 286         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 287         [],
 288         [with_hdbdir=/var/heimdal])
 289 DIR_hdbdir="$with_hdbdir"
 290 AC_SUBST([DIR_hdbdir])
 291
 292
 293 AM_CONDITIONAL(KRB5, true)
 294 AM_CONDITIONAL(do_roken_rename, true)
 295
 296 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 297
 298
 299 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 300 AC_SUBST(LIB_kdb)dnl
 301
 302 KRB_CRYPTO
 303
 304 KRB_PTHREADS
 305
 306 AC_ARG_ENABLE(dce,
 307         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 308 if test "$enable_dce" = yes; then
 309     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 310 fi
 311 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 312
 313 ## XXX quite horrible:
 314 if test -f /etc/ibmcxx.cfg; then
 315         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 316         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 317         dpagaix_ldflags=
 318 else
 319         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 320         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 321         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 322 fi
 323 AC_SUBST(dpagaix_cflags)
 324 AC_SUBST(dpagaix_ldadd)
 325 AC_SUBST(dpagaix_ldflags)
 326
 327 AC_ARG_ENABLE([afs-support],
 328         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 329 if test "$enable_afs_support" = no; then
 330         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 331         NO_AFS="1"
 332 fi
 333 AC_SUBST(NO_AFS)dnl
 334 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 335
 336 rk_DB
 337
 338 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 339
 340 rk_ROKEN(lib/roken)
 341 LIBADD_roken="$LIB_roken"
 342 AC_SUBST(LIBADD_roken)dnl
 343 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 344
 345 rk_OTP
 346
 347 rk_LIBDISPATCH
 348
 349 AC_CHECK_OSFC2
 350
 351 AC_ARG_ENABLE(mmap,
 352         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 353 if test "$enable_mmap" = "no"; then
 354         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 355 fi
 356
 357 AC_ARG_ENABLE(afs-string-to-key,
 358         AS_HELP_STRING([--disable-afs-string-to-key],
 359         [disable use of weak AFS string-to-key functions]),
 360         [], [enable_afs_string_to_key=yes])
 361
 362 if test "$enable_afs_string_to_key" = "yes"; then
 363         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 364         ENABLE_AFS_STRING_TO_KEY=1
 365 fi
 366 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 367
 368
 369 rk_CHECK_MAN
 370
 371 rk_TEST_PACKAGE(readline,
 372 [#include <stdio.h>
 373 #if defined(HAVE_READLINE_READLINE_H)
 374 #include <readline/readline.h>
 375 #elif defined(HAVE_READLINE_H)
 376 #include <readline.h>
 377 #endif
 378 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 379
 380 rk_TEST_PACKAGE(libedit,
 381 [#include <stdio.h>
 382 #if defined(HAVE_READLINE_READLINE_H)
 383 #include <readline/readline.h>
 384 #elif defined(HAVE_READLINE_H)
 385 #include <readline.h>
 386 #elif defined(HAVE_EDITLINE_READLINE_H)
 387 #include <editline/readline.h>
 388 #endif
 389 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 390
 391 AC_CONFIG_SUBDIRS([lib/libedit])
 392
 393 KRB_C_BIGENDIAN
 394 AC_C_INLINE
 395
 396 dnl AM_C_PROTOTYPES
 397
 398 dnl Checks for typedefs, structures, and compiler characteristics.
 399 AC_C_CONST
 400 AC_TYPE_OFF_T
 401 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 402 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 403 AC_HAVE_TYPE([long long])
 404 AC_HEADER_TIME
 405 AC_STRUCT_TM
 406
 407 dnl Checks for header files.
 408 AC_HEADER_STDC
 409
 410 AC_CHECK_HEADERS([\
 411         CommonCrypto/CommonDigest.h             \
 412         CommonCrypto/CommonCryptor.h            \
 413         arpa/telnet.h                           \
 414         bind/bitypes.h                          \
 415         bsdsetjmp.h                             \
 416         curses.h                                \
 417         dlfcn.h                                 \
 418         execinfo.h                              \
 419         fnmatch.h                               \
 420         inttypes.h                              \
 421         io.h                                    \
 422         keyutils.h                              \
 423         libutil.h                               \
 424         limits.h                                \
 425         maillock.h                              \
 426         netgroup.h                              \
 427         netinet/in6_machtypes.h                 \
 428         netinet/tcp.h                           \
 429         pthread.h                               \
 430         pty.h                                   \
 431         sac.h                                   \
 432         sgtty.h                                 \
 433         siad.h                                  \
 434         signal.h                                \
 435         strings.h                               \
 436         stropts.h                               \
 437         stdatomic.h                             \
 438         sys/bitypes.h                           \
 439         sys/category.h                          \
 440         sys/file.h                              \
 441         sys/filio.h                             \
 442         sys/ioccom.h                            \
 443         sys/mman.h                              \
 444         sys/param.h                             \
 445         sys/pty.h                               \
 446         sys/ptyio.h                             \
 447         sys/select.h                            \
 448         sys/socket.h                            \
 449         sys/str_tty.h                           \
 450         sys/stream.h                            \
 451         sys/stropts.h                           \
 452         sys/syscall.h                           \
 453         sys/termio.h                            \
 454         sys/timeb.h                             \
 455         sys/times.h                             \
 456         sys/types.h                             \
 457         sys/un.h                                \
 458         locale.h                                \
 459         termcap.h                               \
 460         termio.h                                \
 461         termios.h                               \
 462         time.h                                  \
 463         tmpdir.h                                \
 464         udb.h                                   \
 465         util.h                                  \
 466 ])
 467
 468 dnl On Solaris 8 there's a compilation warning for term.h because
 469 dnl it doesn't define `bool'.
 470 AC_CHECK_HEADERS(term.h, , , -)
 471
 472 dnl aix have asl.h (A/IX screen library) that we don't want
 473 AC_CHECK_HEADERS(asl.h, , , [
 474 #include <asl.h>
 475 #ifndef ASL_STRING_EMERG
 476 #error ASL_STRING_EMERG missing
 477 #endif])
 478
 479 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 480 #if HAVE_SYS_SOCKET_H
 481 #include <sys/socket.h>
 482 #endif])
 483
 484 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 485 #if HAVE_SYS_TTY_H
 486 #include <sys/tty.h>
 487 #endif])
 488
 489 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 490 #if HAVE_TERMIOS_H
 491 #include <termios.h>
 492 #endif
 493 #if HAVE_SYS_STREAM_H
 494 #include <sys/stream.h>
 495 #endif])
 496
 497 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 498 #if HAVE_SYS_TYPES_H
 499 #include <sys/types.h>
 500 #endif
 501 #if HAVE_SYS_PARAM_H
 502 #include <sys/param.h>
 503 #endif])
 504
 505 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 506 #include <security/pam_appl.h>
 507 ])
 508
 509 dnl export symbols
 510 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 511 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 512 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 513 rk_WIN32_EXPORT(BUILD_KDC_LIB, KDC_LIB)
 514
 515 dnl Deal with switch fallthrough warnings
 516 AH_TOP([
 517 #if defined(DISPATCH_FALLTHROUGH)
 518 # define HEIM_FALLTHROUGH DISPATCH_FALLTHROUGH
 519 #else
 520 # if defined(__GNUC__)
 521 #  if __GNUC__ >= 7
 522 #   define HEIM_FALLTHROUGH __attribute__((fallthrough))
 523 #  else
 524 #   define HEIM_FALLTHROUGH do {} while (0) /* fallthrough */
 525 #  endif
 526 # else
 527 #  define HEIM_FALLTHROUGH do {} while (0) /* fallthrough */
 528 # endif
 529 #endif
 530 ])
 531
 532 dnl Checks for libraries.
 533
 534 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 535 #ifdef HAVE_UTIL_H
 536 #include <util.h>
 537 #endif
 538 ],[0,0,0,0,0])
 539
 540 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 541 #ifdef HAVE_TERMCAP_H
 542 #include <termcap.h>
 543 #endif
 544 #ifdef HAVE_CURSES_H
 545 #include <curses.h>
 546 #endif
 547 ],[0,0])
 548
 549 dnl Checks for library functions.
 550
 551 AC_CHECK_FUNCS([                                \
 552         _scrsize                                \
 553         arc4random                              \
 554         backtrace                               \
 555         fcntl                                   \
 556         fork                                    \
 557         fseeko                                  \
 558         ftello                                  \
 559         getpeereid                              \
 560         getpeerucred                            \
 561         getresgid                               \
 562         getresuid                               \
 563         grantpt                                 \
 564         ptsname_r                               \
 565         rand                                    \
 566         setitimer                               \
 567         setregid                                \
 568         setresgid                               \
 569         setresuid                               \
 570         setreuid                                \
 571         setsid                                  \
 572         sigaction                               \
 573         unlockpt                                \
 574         waitpid                                 \
 575 ])
 576
 577 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 578 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 579         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 580         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 581 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 582         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 583 fi
 584 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 585
 586 AC_FUNC_MMAP
 587
 588 rk_DLADDR
 589
 590 AC_CHECK_GETPWNAM_R_POSIX
 591 AC_CHECK_GETPWUID_R_POSIX
 592
 593 dnl detect doors on solaris
 594 if test "$enable_pthread_support" != no; then
 595    saved_LIBS="$LIBS"
 596    LIBS="$LIBS $PTHREADS_LIBS"
 597    AC_FIND_FUNC_NO_LIBS(door_create, door)
 598    LIBS="$saved_LIBS"
 599 fi
 600
 601 AC_ARG_ENABLE(kcm,
 602         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 603 ,[enable_kcm=yes])
 604
 605 if test "$enable_kcm" = yes ; then
 606    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 607         enable_kcm=no
 608    fi
 609 fi
 610 if test "$enable_kcm" = yes; then
 611        AC_DEFINE(HAVE_KCM, 1,
 612                [Define if you want to use the Kerberos Credentials Manager.])
 613 fi
 614 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 615
 616 dnl detect keyring on Linux
 617 if test "$ac_cv_header_keyutils_h" = yes; then
 618     AC_CHECK_SIZEOF([key_serial_t],,[
 619         #ifdef HAVE_INTTYPES_H
 620         #include <inttypes.h>
 621         #endif
 622         #ifdef HAVE_SYS_TYPES_H
 623         #include <sys/types.h>
 624         #endif
 625         #include <keyutils.h>
 626     ])
 627 fi
 628
 629 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 630 if test -n "$LIB_add_key"; then
 631     saved_LIBS="$LIBS"
 632     LIBS="$LIBS $LIB_add_key"
 633     AC_CHECK_FUNCS(keyctl_get_persistent)
 634     LIBS="$saved_LIBS"
 635 fi
 636 AM_CONDITIONAL(HAVE_KEYUTILS, test "$ac_cv_func_keyctl_get_persistent" = yes)
 637
 638 AC_CHECK_SIZEOF([time_t])
 639
 640 AX_CHECK_SIGN([time_t],
 641   [ AC_DEFINE(TIME_T_SIGNED, 1, [Define if time_t is signed]) ],
 642   [ AC_DEFINE(TIME_T_UNSIGNED, 1, [Define if time_t is unsigned]) ], [
 643 #ifdef HAVE_TIME_H
 644 #include <time.h>
 645 #endif
 646 ])
 647
 648
 649 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 650         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 651         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 652 #ifdef HAVE_INTTYPES_H
 653 #include <inttypes.h>
 654 #endif
 655 #ifdef HAVE_SYS_TYPES_H
 656 #include <sys/types.h>
 657 #endif
 658 #ifdef HAVE_SYS_BITYPES_H
 659 #include <sys/bitypes.h>
 660 #endif
 661 #ifdef HAVE_BIND_BITYPES_H
 662 #include <bind/bitypes.h>
 663 #endif
 664 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 665 #include <netinet/in6_machtypes.h>
 666 #endif
 667 ])
 668
 669 rk_FRAMEWORK_SECURITY
 670 rk_FRAMEWORK_COREFOUNDATION
 671
 672 KRB_READLINE
 673
 674 rk_TELNET
 675
 676 dnl Some operating systems already have com_err and compile_et
 677 CHECK_COMPILE_ET
 678
 679 rk_AUTH_MODULES([sia afskauthlib])
 680
 681 rk_DESTDIRS
 682
 683 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 684
 685
 686 AH_BOTTOM([#ifdef __APPLE__
 687 #include <AvailabilityMacros.h>
 688 #endif])
 689
 690 AH_BOTTOM([#ifdef ROKEN_RENAME
 691 #include "roken_rename.h"
 692 #endif])
 693
 694 AC_ARG_ENABLE(heimdal-documentation,
 695         AS_HELP_STRING([--disable-heimdal-documentation],
 696                 [if you want disable to heimdal documentation]))
 697 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 698
 699 AC_CONFIG_FILES(Makefile                \
 700         etc/Makefile                    \
 701         include/Makefile                \
 702         include/gssapi/Makefile         \
 703         include/hcrypto/Makefile        \
 704         include/kadm5/Makefile          \
 705         lib/Makefile                    \
 706         lib/base/Makefile                       \
 707         lib/asn1/Makefile               \
 708         lib/com_err/Makefile            \
 709         lib/hcrypto/Makefile            \
 710         lib/hx509/Makefile              \
 711         lib/gssapi/Makefile             \
 712         lib/ntlm/Makefile               \
 713         lib/hdb/Makefile                \
 714         lib/ipc/Makefile                \
 715         lib/kadm5/Makefile              \
 716         lib/kafs/Makefile               \
 717         lib/kdfs/Makefile               \
 718         lib/krb5/Makefile               \
 719         lib/otp/Makefile                \
 720         lib/roken/Makefile              \
 721         lib/sl/Makefile                 \
 722         lib/sqlite/Makefile             \
 723         lib/vers/Makefile               \
 724         lib/wind/Makefile               \
 725         lib/gss_preauth/Makefile        \
 726         po/Makefile                     \
 727         kuser/Makefile                  \
 728         kpasswd/Makefile                \
 729         kadmin/Makefile                 \
 730         admin/Makefile                  \
 731         kcm/Makefile                    \
 732         kdc/Makefile                    \
 733         appl/Makefile                   \
 734         appl/afsutil/Makefile           \
 735         appl/dbutils/Makefile           \
 736         appl/gssmask/Makefile           \
 737         appl/otp/Makefile               \
 738         appl/test/Makefile              \
 739         appl/kf/Makefile                \
 740         appl/dceutils/Makefile          \
 741         tests/Makefile                  \
 742         tests/bin/Makefile              \
 743         tests/can/Makefile              \
 744         tests/db/Makefile               \
 745         tests/kdc/Makefile              \
 746         tests/ldap/Makefile             \
 747         tests/gss/Makefile              \
 748         tests/java/Makefile             \
 749         tests/plugin/Makefile           \
 750         packages/Makefile               \
 751         packages/mac/Makefile           \
 752         doc/Makefile                    \
 753         tools/Makefile                  \
 754 )
 755
 756 AC_OUTPUT
 757
 758 dnl
 759 dnl This is the release version name-number[beta]
 760 dnl
 761
 762 if test -d "$srcdir/.git"; then
 763     cat > include/newversion.h.in <<EOF
 764 #ifndef VERSION_HIDDEN
 765 #define VERSION_HIDDEN
 766 #endif
 767 VERSION_HIDDEN const char *const heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 768 VERSION_HIDDEN const char *const heimdal_version = "AC_PACKAGE_STRING";
 769 EOF
 770 else
 771     cat > include/newversion.h.in <<EOF
 772 #ifndef VERSION_HIDDEN
 773 #define VERSION_HIDDEN
 774 #endif
 775 VERSION_HIDDEN const char *const heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 776 VERSION_HIDDEN const char *const heimdal_version = "AC_PACKAGE_STRING";
 777 EOF
 778 fi
 779
 780 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 781         echo "include/version.h is unchanged"
 782         rm -f include/newversion.h.in
 783 else
 784         echo "creating include/version.h"
 785         if test -n "$SOURCE_DATE_EPOCH"; then
 786             Date=`
 787                   # BSD, OS X
 788                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 789                   # Linux
 790                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 791                   # Illumos -- sorry, no -r/-d here
 792                   date -u ||
 793                   date`
 794         else
 795             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 796         fi
 797         if test -n "$SOURCE_HOST"; then
 798             Host=$SOURCE_HOST
 799         else
 800             Host=`uname -n`
 801         fi
 802         if test -n "$SOURCE_USER"; then
 803             User=$SOURCE_USER
 804         else
 805             User=${USER:-${LOGNAME:-`id -nu`}}
 806         fi
 807         if test -d "$srcdir/.git"; then
 808             GitCommit=`cd $srcdir && git rev-parse HEAD`
 809             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 810             if test "x$GitBranch" = master; then
 811                 GitDesc=`cd $srcdir && git describe --all --dirty`
 812             else
 813                 GitDesc=`cd $srcdir && \
 814                          git describe --tags --match 'heimdal-*' --dirty`
 815             fi
 816         else
 817             GitCommit='<commit-unknown>'
 818             GitBranch='<branch-unknown>'
 819             GitDesc='<tag-unknown>'
 820         fi
 821         mv -f include/newversion.h.in include/version.h.in
 822         sed -e "s/@HOST@/$Host/" \
 823             -e "s;@USER@;$User;" \
 824             -e "s;@DATE@;$Date;" \
 825             -e "s;@BRANCH@;$GitBranch;" \
 826             -e "s;@TAG@;$GitDesc;" \
 827             -e "s;@COMMIT@;$GitCommit;" \
 828             include/version.h.in > include/version.h
 829 fi