test/DebugInfo/Generic/dbg-value-lower-linenos.ll

   1 ; RUN: opt < %s -S -mem2reg -instcombine | FileCheck %s
   2
   3 ; The '%bar' alloca will be promoted to an SSA register by mem2reg: test that
   4 ; zero line number are assigned to the dbg.value intrinsics that are inserted
   5 ; to represent changes in variable value. No machine instructions are
   6 ; generated from these dbg.values so their lines are irrelevant, only the
   7 ; scope and inlining information must be correct.
   8
   9 ; In the second function here, LowerDbgDeclare will promote various variable
  10 ; accesses of a dbg.declare'd alloca into dbg.values. Check that their line
  11 ; numbers are sane too. (IR copied from DebugInfo/X86/formal_parameter.ll).
  12
  13 ; CHECK-LABEL: define i32 @foo
  14
  15 ; CHECK-LABEL: bb1:
  16 ; CHECK-NEXT:  %bar.0 = phi i32
  17 ; CHECK-NEXT:  dbg.value(metadata i32 %bar.0,{{.*}}), !dbg ![[UNKNOWN:[0-9]+]]
  18 ; CHECK-NEXT:  %totest = load
  19 ; CHECK-NEXT:  %add = add i32 %bar.0
  20 ; CHECK-NEXT:  dbg.value(metadata i32 %add, {{.*}}), !dbg ![[UNKNOWN]]
  21 ; CHECK-NEXT:  %cond = icmp ult
  22 ; CHECK-NEXT:  br i1 %cond, label %bb1, label %bb2
  23 ;
  24 ; CHECK-LABEL: bb2:
  25 ; CHECK-NEXT:  %toret = add i32 %bar.0, 3
  26 ; CHECK-NEXT:  dbg.value(metadata i32 %toret, {{.*}}), !dbg ![[UNKNOWN]]
  27 ; CHECK-NEXT:  ret i32 %toret
  28
  29 define i32 @foo(i32 *%bees, i32 *%output) {
  30 entry:
  31   %bar = alloca i32
  32   call void @llvm.dbg.declare(metadata i32 *%bar, metadata !7, metadata !DIExpression()), !dbg !6
  33   store i32 0, i32 *%bar
  34   br label %bb1, !dbg !6
  35
  36 bb1:
  37   %totest = load i32, i32 *%bees, !dbg !8
  38   %load1 = load i32, i32 *%bar, !dbg !9
  39   %add = add i32 %load1, 1, !dbg !10
  40   store i32 %add, i32 *%bar, !dbg !11
  41   %toret = add i32 %add, 2, !dbg !12
  42   %cond = icmp ult i32 %totest, %load1, !dbg !13
  43   br i1 %cond, label %bb1, label %bb2, !dbg !14
  44
  45 bb2:
  46   store i32 %toret, i32 *%bar, !dbg !16
  47   ret i32 %toret
  48 }
  49
  50 ; In the following, the dbg.value created for the store should get the stores
  51 ; line number, the other dbg.values should be unknown.
  52 ; CHECK-LABEL: define void @bar
  53 ;
  54 ; CHECK:      dbg.value(metadata i32 %map, metadata ![[MAPVAR:[0-9]+]],{{.*}}),
  55 ; CHECK-SAME:           !dbg ![[UNKNOWN2:[0-9]+]]
  56 ; CHECK-NEXT: store
  57 ; CHECK-NEXT: dbg.value(metadata i32* %map.addr, metadata ![[MAPVAR]],
  58 ; CHECK-SAME:           metadata !DIExpression(DW_OP_deref)),
  59 ; CHECK-SAME:           !dbg ![[UNKNOWN2]]
  60 ; CHECK-NEXT: call
  61 ; CHECK-NEXT: load
  62 ; CHECK-NEXT: dbg.value(metadata i32 %{{[0-9]+}}, metadata ![[MAPVAR]],
  63 ; CHECK-SAME:           !dbg ![[UNKNOWN2]]
  64
  65 define void @bar(i32 %map) !dbg !20 {
  66 entry:
  67   %map.addr = alloca i32, align 4
  68   store i32 %map, i32* %map.addr, align 4, !dbg !27
  69   call void @llvm.dbg.declare(metadata i32* %map.addr, metadata !21, metadata !DIExpression()), !dbg !22
  70   %call = call i32 (i32*, ...) bitcast (i32 (...)* @lookup to i32 (i32*, ...)*)(i32* %map.addr), !dbg !23
  71 %0 = load i32, i32* %map.addr, align 4, !dbg !24
  72   %call1 = call i32 (i32, ...) bitcast (i32 (...)* @verify to i32 (i32, ...)*)(i32 %0), !dbg !25
  73   ret void, !dbg !26
  74 }
  75
  76 declare void @llvm.dbg.value(metadata, metadata, metadata)
  77 declare void @llvm.dbg.declare(metadata, metadata, metadata)
  78 declare i32 @verify(...)
  79 declare i32 @lookup(...)
  80
  81 ; CHECK: ![[SUBPROG:[0-9]+]] = distinct !DISubprogram(name: "nope",
  82 ; CHECK: ![[UNKNOWN]] = !DILocation(line: 0, scope: ![[SUBPROG]])
  83
  84 ; CHECK: ![[SUBPROG2:[0-9]+]] = distinct !DISubprogram(name: "thin",
  85 ; CHECK: ![[MAPVAR]] = !DILocalVariable(name: "floogie",
  86 ; CHECK: ![[UNKNOWN2]] = !DILocation(line: 0
  87
  88 !llvm.module.flags = !{!4}
  89 !llvm.dbg.cu = !{!2}
  90 !1 = !DILocalVariable(name: "bees", scope: !5, type: null)
  91 !2 = distinct !DICompileUnit(language: DW_LANG_C_plus_plus, file: !3, producer: "beards", isOptimized: true, runtimeVersion: 4, emissionKind: FullDebug)
  92 !3 = !DIFile(filename: "bees.cpp", directory: "")
  93 !4 = !{i32 2, !"Debug Info Version", i32 3}
  94 !5 = distinct !DISubprogram(name: "nope", scope: !3, file: !3, line: 1, unit: !2)
  95 !6 = !DILocation(line: 1, scope: !5)
  96 !7 = !DILocalVariable(name: "flannel", scope: !5, type: null)
  97 !8 = !DILocation(line: 2, scope: !5)
  98 !9 = !DILocation(line: 3, scope: !5)
  99 !10 = !DILocation(line: 4, scope: !5)
 100 !11 = !DILocation(line: 5, scope: !5)
 101 !12 = !DILocation(line: 6, scope: !5)
 102 !13 = !DILocation(line: 7, scope: !5)
 103 !14 = !DILocation(line: 8, scope: !5)
 104 !15 = distinct !DISubprogram(name: "wat", scope: !2, file: !3, line: 10, unit: !2)
 105 !16 = !DILocation(line: 9, scope: !15, inlinedAt: !14)
 106 !20 = distinct !DISubprogram(name: "thin", scope: !3, file: !3, line: 20, unit: !2)
 107 !21 = !DILocalVariable(name: "floogie", scope: !20, type: null)
 108 !22 = !DILocation(line: 21, scope: !20)
 109 !23 = !DILocation(line: 22, scope: !20)
 110 !24 = !DILocation(line: 23, scope: !20)
 111 !25 = !DILocation(line: 24, scope: !20)
 112 !26 = !DILocation(line: 25, scope: !20)
 113 !27 = !DILocation(line: 20, scope: !20)