test/Transforms/LoopVectorize/struct_access.ll

   1 ; RUN: opt < %s -loop-vectorize -force-vector-interleave=1 -force-vector-width=4 -instcombine -S | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64-S128"
   4
   5 %struct.coordinate = type { i32, i32 }
   6
   7 ; Make sure that we don't generate a wide load when accessing the struct.
   8 ; struct coordinate {
   9 ;  int x;
  10 ;  int y;
  11 ; };
  12 ;
  13 ;
  14 ; int foo(struct coordinate *A, int n) {
  15 ;
  16 ;   int sum = 0;
  17 ;   for (int i = 0; i < n; ++i)
  18 ;     sum += A[i].x;
  19 ;
  20 ;   return sum;
  21 ; }
  22
  23 ;CHECK-LABEL: @foo(
  24 ;CHECK-NOT: load <4 x i32>
  25 ;CHECK: ret
  26 define i32 @foo(%struct.coordinate* nocapture %A, i32 %n) nounwind uwtable readonly ssp {
  27 entry:
  28   %cmp4 = icmp sgt i32 %n, 0
  29   br i1 %cmp4, label %for.body, label %for.end
  30
  31 for.body:                                         ; preds = %entry, %for.body
  32   %indvars.iv = phi i64 [ %indvars.iv.next, %for.body ], [ 0, %entry ]
  33   %sum.05 = phi i32 [ %add, %for.body ], [ 0, %entry ]
  34   %x = getelementptr inbounds %struct.coordinate, %struct.coordinate* %A, i64 %indvars.iv, i32 0
  35   %0 = load i32, i32* %x, align 4
  36   %add = add nsw i32 %0, %sum.05
  37   %indvars.iv.next = add i64 %indvars.iv, 1
  38   %lftr.wideiv = trunc i64 %indvars.iv.next to i32
  39   %exitcond = icmp eq i32 %lftr.wideiv, %n
  40   br i1 %exitcond, label %for.end, label %for.body
  41
  42 for.end:                                          ; preds = %for.body, %entry
  43   %sum.0.lcssa = phi i32 [ 0, %entry ], [ %add, %for.body ]
  44   ret i32 %sum.0.lcssa
  45 }
  46
  47 %struct.lit = type { i32 }
  48
  49 ; Verify that we still vectorize the access if the struct has the same size as
  50 ; the loaded element.
  51 ; struct lit {
  52 ;  int x;
  53 ; };
  54 ;
  55 ;
  56 ; int bar(struct lit *A, int n) {
  57 ;
  58 ;   int sum = 0;
  59 ;   for (int i = 0; i < n; ++i)
  60 ;     sum += A[i].x;
  61 ;
  62 ;   return sum;
  63 ; }
  64
  65 ;CHECK-LABEL: @bar(
  66 ;CHECK: load <4 x i32>
  67 ;CHECK: ret
  68 define i32 @bar(%struct.lit* nocapture %A, i32 %n) nounwind uwtable readonly ssp {
  69 entry:
  70   %cmp4 = icmp sgt i32 %n, 0
  71   br i1 %cmp4, label %for.body, label %for.end
  72
  73 for.body:                                         ; preds = %entry, %for.body
  74   %indvars.iv = phi i64 [ %indvars.iv.next, %for.body ], [ 0, %entry ]
  75   %sum.05 = phi i32 [ %add, %for.body ], [ 0, %entry ]
  76   %x = getelementptr inbounds %struct.lit, %struct.lit* %A, i64 %indvars.iv, i32 0
  77   %0 = load i32, i32* %x, align 4
  78   %add = add nsw i32 %0, %sum.05
  79   %indvars.iv.next = add i64 %indvars.iv, 1
  80   %lftr.wideiv = trunc i64 %indvars.iv.next to i32
  81   %exitcond = icmp eq i32 %lftr.wideiv, %n
  82   br i1 %exitcond, label %for.end, label %for.body
  83
  84 for.end:                                          ; preds = %for.body, %entry
  85   %sum.0.lcssa = phi i32 [ 0, %entry ], [ %add, %for.body ]
  86   ret i32 %sum.0.lcssa
  87 }