utils/benchmark/test/CMakeLists.txt

   1 # Enable the tests
   2
   3 find_package(Threads REQUIRED)
   4 include(CheckCXXCompilerFlag)
   5
   6 # NOTE: Some tests use `<cassert>` to perform the test. Therefore we must
   7 # strip -DNDEBUG from the default CMake flags in DEBUG mode.
   8 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   9 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  10   add_definitions( -UNDEBUG )
  11   add_definitions(-DTEST_BENCHMARK_LIBRARY_HAS_NO_ASSERTIONS)
  12   # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  13   foreach (flags_var_to_scrub
  14       CMAKE_CXX_FLAGS_RELEASE
  15       CMAKE_CXX_FLAGS_RELWITHDEBINFO
  16       CMAKE_CXX_FLAGS_MINSIZEREL
  17       CMAKE_C_FLAGS_RELEASE
  18       CMAKE_C_FLAGS_RELWITHDEBINFO
  19       CMAKE_C_FLAGS_MINSIZEREL)
  20     string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  21       "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  22   endforeach()
  23 endif()
  24
  25 check_cxx_compiler_flag(-O3 BENCHMARK_HAS_O3_FLAG)
  26 set(BENCHMARK_O3_FLAG "")
  27 if (BENCHMARK_HAS_O3_FLAG)
  28   set(BENCHMARK_O3_FLAG "-O3")
  29 endif()
  30
  31 # NOTE: These flags must be added after find_package(Threads REQUIRED) otherwise
  32 # they will break the configuration check.
  33 if (DEFINED BENCHMARK_CXX_LINKER_FLAGS)
  34   list(APPEND CMAKE_EXE_LINKER_FLAGS ${BENCHMARK_CXX_LINKER_FLAGS})
  35 endif()
  36
  37 add_library(output_test_helper STATIC output_test_helper.cc output_test.h)
  38
  39 macro(compile_benchmark_test name)
  40   add_executable(${name} "${name}.cc")
  41   target_link_libraries(${name} benchmark ${CMAKE_THREAD_LIBS_INIT})
  42 endmacro(compile_benchmark_test)
  43
  44 macro(compile_benchmark_test_with_main name)
  45   add_executable(${name} "${name}.cc")
  46   target_link_libraries(${name} benchmark_main)
  47 endmacro(compile_benchmark_test_with_main)
  48
  49 macro(compile_output_test name)
  50   add_executable(${name} "${name}.cc" output_test.h)
  51   target_link_libraries(${name} output_test_helper benchmark
  52           ${BENCHMARK_CXX_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
  53 endmacro(compile_output_test)
  54
  55 # Demonstration executable
  56 compile_benchmark_test(benchmark_test)
  57 add_test(benchmark benchmark_test --benchmark_min_time=0.01)
  58
  59 compile_benchmark_test(filter_test)
  60 macro(add_filter_test name filter expect)
  61   add_test(${name} filter_test --benchmark_min_time=0.01 --benchmark_filter=${filter} ${expect})
  62   add_test(${name}_list_only filter_test --benchmark_list_tests --benchmark_filter=${filter} ${expect})
  63 endmacro(add_filter_test)
  64
  65 add_filter_test(filter_simple "Foo" 3)
  66 add_filter_test(filter_simple_negative "-Foo" 2)
  67 add_filter_test(filter_suffix "BM_.*" 4)
  68 add_filter_test(filter_suffix_negative "-BM_.*" 1)
  69 add_filter_test(filter_regex_all ".*" 5)
  70 add_filter_test(filter_regex_all_negative "-.*" 0)
  71 add_filter_test(filter_regex_blank "" 5)
  72 add_filter_test(filter_regex_blank_negative "-" 0)
  73 add_filter_test(filter_regex_none "monkey" 0)
  74 add_filter_test(filter_regex_none_negative "-monkey" 5)
  75 add_filter_test(filter_regex_wildcard ".*Foo.*" 3)
  76 add_filter_test(filter_regex_wildcard_negative "-.*Foo.*" 2)
  77 add_filter_test(filter_regex_begin "^BM_.*" 4)
  78 add_filter_test(filter_regex_begin_negative "-^BM_.*" 1)
  79 add_filter_test(filter_regex_begin2 "^N" 1)
  80 add_filter_test(filter_regex_begin2_negative "-^N" 4)
  81 add_filter_test(filter_regex_end ".*Ba$" 1)
  82 add_filter_test(filter_regex_end_negative "-.*Ba$" 4)
  83
  84 compile_benchmark_test(options_test)
  85 add_test(options_benchmarks options_test --benchmark_min_time=0.01)
  86
  87 compile_benchmark_test(basic_test)
  88 add_test(basic_benchmark basic_test --benchmark_min_time=0.01)
  89
  90 compile_benchmark_test(diagnostics_test)
  91 add_test(diagnostics_test diagnostics_test --benchmark_min_time=0.01)
  92
  93 compile_benchmark_test(skip_with_error_test)
  94 add_test(skip_with_error_test skip_with_error_test --benchmark_min_time=0.01)
  95
  96 compile_benchmark_test(donotoptimize_test)
  97 # Some of the issues with DoNotOptimize only occur when optimization is enabled
  98 check_cxx_compiler_flag(-O3 BENCHMARK_HAS_O3_FLAG)
  99 if (BENCHMARK_HAS_O3_FLAG)
 100   set_target_properties(donotoptimize_test PROPERTIES COMPILE_FLAGS "-O3")
 101 endif()
 102 add_test(donotoptimize_test donotoptimize_test --benchmark_min_time=0.01)
 103
 104 compile_benchmark_test(fixture_test)
 105 add_test(fixture_test fixture_test --benchmark_min_time=0.01)
 106
 107 compile_benchmark_test(register_benchmark_test)
 108 add_test(register_benchmark_test register_benchmark_test --benchmark_min_time=0.01)
 109
 110 compile_benchmark_test(map_test)
 111 add_test(map_test map_test --benchmark_min_time=0.01)
 112
 113 compile_benchmark_test(multiple_ranges_test)
 114 add_test(multiple_ranges_test multiple_ranges_test --benchmark_min_time=0.01)
 115
 116 compile_benchmark_test_with_main(link_main_test)
 117 add_test(link_main_test link_main_test --benchmark_min_time=0.01)
 118
 119 compile_output_test(reporter_output_test)
 120 add_test(reporter_output_test reporter_output_test --benchmark_min_time=0.01)
 121
 122 compile_output_test(templated_fixture_test)
 123 add_test(templated_fixture_test templated_fixture_test --benchmark_min_time=0.01)
 124
 125 compile_output_test(user_counters_test)
 126 add_test(user_counters_test user_counters_test --benchmark_min_time=0.01)
 127
 128 compile_output_test(user_counters_tabular_test)
 129 add_test(user_counters_tabular_test user_counters_tabular_test --benchmark_counters_tabular=true --benchmark_min_time=0.01)
 130
 131 check_cxx_compiler_flag(-std=c++03 BENCHMARK_HAS_CXX03_FLAG)
 132 if (BENCHMARK_HAS_CXX03_FLAG)
 133   compile_benchmark_test(cxx03_test)
 134   set_target_properties(cxx03_test
 135       PROPERTIES
 136       COMPILE_FLAGS "-std=c++03")
 137   # libstdc++ provides different definitions within <map> between dialects. When
 138   # LTO is enabled and -Werror is specified GCC diagnoses this ODR violation
 139   # causing the test to fail to compile. To prevent this we explicitly disable
 140   # the warning.
 141   check_cxx_compiler_flag(-Wno-odr BENCHMARK_HAS_WNO_ODR)
 142   if (BENCHMARK_ENABLE_LTO AND BENCHMARK_HAS_WNO_ODR)
 143     set_target_properties(cxx03_test
 144         PROPERTIES
 145         LINK_FLAGS "-Wno-odr")
 146   endif()
 147   add_test(cxx03 cxx03_test --benchmark_min_time=0.01)
 148 endif()
 149
 150 # Attempt to work around flaky test failures when running on Appveyor servers.
 151 if (DEFINED ENV{APPVEYOR})
 152   set(COMPLEXITY_MIN_TIME "0.5")
 153 else()
 154   set(COMPLEXITY_MIN_TIME "0.01")
 155 endif()
 156 compile_output_test(complexity_test)
 157 add_test(complexity_benchmark complexity_test --benchmark_min_time=${COMPLEXITY_MIN_TIME})
 158
 159 ###############################################################################
 160 # GoogleTest Unit Tests
 161 ###############################################################################
 162
 163 if (BENCHMARK_ENABLE_GTEST_TESTS)
 164   macro(compile_gtest name)
 165     add_executable(${name} "${name}.cc")
 166     if (TARGET googletest)
 167       add_dependencies(${name} googletest)
 168     endif()
 169     if (GTEST_INCLUDE_DIRS)
 170       target_include_directories(${name} PRIVATE ${GTEST_INCLUDE_DIRS})
 171     endif()
 172     target_link_libraries(${name} benchmark
 173         ${GTEST_BOTH_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
 174   endmacro(compile_gtest)
 175
 176   macro(add_gtest name)
 177     compile_gtest(${name})
 178     add_test(${name} ${name})
 179   endmacro()
 180
 181   add_gtest(benchmark_gtest)
 182   add_gtest(statistics_gtest)
 183 endif(BENCHMARK_ENABLE_GTEST_TESTS)
 184
 185 ###############################################################################
 186 # Assembly Unit Tests
 187 ###############################################################################
 188
 189 if (BENCHMARK_ENABLE_ASSEMBLY_TESTS)
 190   if (NOT LLVM_FILECHECK_EXE)
 191     message(FATAL_ERROR "LLVM FileCheck is required when including this file")
 192   endif()
 193   include(AssemblyTests.cmake)
 194   add_filecheck_test(donotoptimize_assembly_test)
 195   add_filecheck_test(state_assembly_test)
 196   add_filecheck_test(clobber_memory_assembly_test)
 197 endif()
 198
 199
 200
 201 ###############################################################################
 202 # Code Coverage Configuration
 203 ###############################################################################
 204
 205 # Add the coverage command(s)
 206 if(CMAKE_BUILD_TYPE)
 207   string(TOLOWER ${CMAKE_BUILD_TYPE} CMAKE_BUILD_TYPE_LOWER)
 208 endif()
 209 if (${CMAKE_BUILD_TYPE_LOWER} MATCHES "coverage")
 210   find_program(GCOV gcov)
 211   find_program(LCOV lcov)
 212   find_program(GENHTML genhtml)
 213   find_program(CTEST ctest)
 214   if (GCOV AND LCOV AND GENHTML AND CTEST AND HAVE_CXX_FLAG_COVERAGE)
 215     add_custom_command(
 216       OUTPUT ${CMAKE_BINARY_DIR}/lcov/index.html
 217       COMMAND ${LCOV} -q -z -d .
 218       COMMAND ${LCOV} -q --no-external -c -b "${CMAKE_SOURCE_DIR}" -d . -o before.lcov -i
 219       COMMAND ${CTEST} --force-new-ctest-process
 220       COMMAND ${LCOV} -q --no-external -c -b "${CMAKE_SOURCE_DIR}" -d . -o after.lcov
 221       COMMAND ${LCOV} -q -a before.lcov -a after.lcov --output-file final.lcov
 222       COMMAND ${LCOV} -q -r final.lcov "'${CMAKE_SOURCE_DIR}/test/*'" -o final.lcov
 223       COMMAND ${GENHTML} final.lcov -o lcov --demangle-cpp --sort -p "${CMAKE_BINARY_DIR}" -t benchmark
 224       DEPENDS filter_test benchmark_test options_test basic_test fixture_test cxx03_test complexity_test
 225       WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 226       COMMENT "Running LCOV"
 227     )
 228     add_custom_target(coverage
 229       DEPENDS ${CMAKE_BINARY_DIR}/lcov/index.html
 230       COMMENT "LCOV report at lcov/index.html"
 231     )
 232     message(STATUS "Coverage command added")
 233   else()
 234     if (HAVE_CXX_FLAG_COVERAGE)
 235       set(CXX_FLAG_COVERAGE_MESSAGE supported)
 236     else()
 237       set(CXX_FLAG_COVERAGE_MESSAGE unavailable)
 238     endif()
 239     message(WARNING
 240       "Coverage not available:\n"
 241       "  gcov: ${GCOV}\n"
 242       "  lcov: ${LCOV}\n"
 243       "  genhtml: ${GENHTML}\n"
 244       "  ctest: ${CTEST}\n"
 245       "  --coverage flag: ${CXX_FLAG_COVERAGE_MESSAGE}")
 246   endif()
 247 endif()