utils/gn/secondary/llvm/unittests/DebugInfo/PDB/BUILD.gn

   1 import("//llvm/utils/unittest/unittest.gni")
   2
   3 unittest("DebugInfoPDBTests") {
   4   deps = [
   5     "//llvm/lib/DebugInfo/CodeView",
   6     "//llvm/lib/DebugInfo/MSF",
   7     "//llvm/lib/DebugInfo/PDB",
   8     "//llvm/lib/Testing/Support",
   9   ]
  10   sources = [
  11     "HashTableTest.cpp",
  12     "NativeSymbolReuseTest.cpp",
  13     "PDBApiTest.cpp",
  14     "StringTableBuilderTest.cpp",
  15   ]
  16
  17   # DebugInfoPDBTests uses llvm::getInputFileDirectory(), which expects
  18   # a file called llvm.srcdir.txt next to the test executable that contains
  19   # the path of the source directory (which contains this file).
  20   # lit doesn't change the cwd while running googletests, so the cwd isn't
  21   # well-defined. This means this has to be an absolute path.
  22   # FIXME: This doesn't work with swarming. This should really be a data
  23   # dependency, and the cwd while tests requiring input files run should
  24   # be required to be some fixed directory.
  25   # FIXME: Also, the GN way is to write this file at build time. But since
  26   # there's only one use of this, and since this is a pattern that hopefully
  27   # will disappear again, and since it doesn't have any measurable performance
  28   # hit, write the file at GN time.
  29   # Note: This line here implicitly depends on unittest() setting output_dir to
  30   # target_out_dir.
  31   write_file("$target_out_dir/llvm.srcdir.txt", rebase_path("."))
  32 }