llvm/test/Transforms/GlobalOpt/tls.ll

   1 ; RUN: opt < %s -passes=globalopt -S | FileCheck %s
   2 ; RUN: opt -emulated-tls < %s -passes=globalopt -S | FileCheck %s
   3
   4 declare void @wait()
   5 declare void @signal()
   6 declare void @start_thread(ptr)
   7
   8 @x = internal thread_local global [100 x i32] zeroinitializer, align 16
   9 @ip = internal global ptr null, align 8
  10
  11 ; PR14309: GlobalOpt would think that the value of @ip is always the address of
  12 ; x[1]. However, that address is different for different threads so @ip cannot
  13 ; be replaced with a constant.
  14
  15 define i32 @f() {
  16 entry:
  17   ; Set @ip to point to x[1] for thread 1.
  18   store ptr getelementptr inbounds ([100 x i32], ptr @x, i64 0, i64 1), ptr @ip, align 8
  19
  20   ; Run g on a new thread.
  21   tail call void @start_thread(ptr @g) nounwind
  22   tail call void @wait() nounwind
  23
  24   ; Reset x[1] for thread 1.
  25   store i32 0, ptr getelementptr inbounds ([100 x i32], ptr @x, i64 0, i64 1), align 4
  26
  27   ; Read the value of @ip, which now points at x[1] for thread 2.
  28   %0 = load ptr, ptr @ip, align 8
  29
  30   %1 = load i32, ptr %0, align 4
  31   ret i32 %1
  32
  33 ; CHECK-LABEL: @f(
  34 ; Make sure that the load from @ip hasn't been removed.
  35 ; CHECK: load ptr, ptr @ip
  36 ; CHECK: ret
  37 }
  38
  39 define internal void @g() nounwind uwtable {
  40 entry:
  41   ; Set @ip to point to x[1] for thread 2.
  42   store ptr getelementptr inbounds ([100 x i32], ptr @x, i64 0, i64 1), ptr @ip, align 8
  43
  44   ; Store 50 in x[1] for thread 2.
  45   store i32 50, ptr getelementptr inbounds ([100 x i32], ptr @x, i64 0, i64 1), align 4
  46
  47   tail call void @signal() nounwind
  48   ret void
  49
  50 ; CHECK-LABEL: @g(
  51 ; Make sure that the store to @ip hasn't been removed.
  52 ; CHECK: store {{.*}} @ip
  53 ; CHECK: ret
  54 }