libclc/generic/lib/math/clc_powr.cl

   1 /*
   2  * Copyright (c) 2014 Advanced Micro Devices, Inc.
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a copy
   5  * of this software and associated documentation files (the "Software"), to deal
   6  * in the Software without restriction, including without limitation the rights
   7  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
   8  * copies of the Software, and to permit persons to whom the Software is
   9  * furnished to do so, subject to the following conditions:
  10  *
  11  * The above copyright notice and this permission notice shall be included in
  12  * all copies or substantial portions of the Software.
  13  *
  14  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  17  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  18  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  19  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
  20  * THE SOFTWARE.
  21  */
  22
  23 #include <clc/clc.h>
  24
  25 #include "config.h"
  26 #include "math.h"
  27 #include "tables.h"
  28 #include "../clcmacro.h"
  29
  30 // compute pow using log and exp
  31 // x^y = exp(y * log(x))
  32 //
  33 // we take care not to lose precision in the intermediate steps
  34 //
  35 // When computing log, calculate it in splits,
  36 //
  37 // r = f * (p_invead + p_inv_tail)
  38 // r = rh + rt
  39 //
  40 // calculate log polynomial using r, in end addition, do
  41 // poly = poly + ((rh-r) + rt)
  42 //
  43 // lth = -r
  44 // ltt = ((xexp * log2_t) - poly) + logT
  45 // lt = lth + ltt
  46 //
  47 // lh = (xexp * log2_h) + logH
  48 // l = lh + lt
  49 //
  50 // Calculate final log answer as gh and gt,
  51 // gh = l & higher-half bits
  52 // gt = (((ltt - (lt - lth)) + ((lh - l) + lt)) + (l - gh))
  53 //
  54 // yh = y & higher-half bits
  55 // yt = y - yh
  56 //
  57 // Before entering computation of exp,
  58 // vs = ((yt*gt + yt*gh) + yh*gt)
  59 // v = vs + yh*gh
  60 // vt = ((yh*gh - v) + vs)
  61 //
  62 // In calculation of exp, add vt to r that is used for poly
  63 // At the end of exp, do
  64 // ((((expT * poly) + expT) + expH*poly) + expH)
  65
  66 _CLC_DEF _CLC_OVERLOAD float __clc_powr(float x, float y)
  67 {
  68     int ix = as_int(x);
  69     int ax = ix & EXSIGNBIT_SP32;
  70     int xpos = ix == ax;
  71
  72     int iy = as_int(y);
  73     int ay = iy & EXSIGNBIT_SP32;
  74     int ypos = iy == ay;
  75
  76     // Extra precise log calculation
  77     // First handle case that x is close to 1
  78     float r = 1.0f - as_float(ax);
  79     int near1 = fabs(r) < 0x1.0p-4f;
  80     float r2 = r*r;
  81
  82     // Coefficients are just 1/3, 1/4, 1/5 and 1/6
  83     float poly = mad(r,
  84                      mad(r,
  85                          mad(r,
  86                              mad(r, 0x1.24924ap-3f, 0x1.555556p-3f),
  87                              0x1.99999ap-3f),
  88                          0x1.000000p-2f),
  89                      0x1.555556p-2f);
  90
  91     poly *= r2*r;
  92
  93     float lth_near1 = -r2 * 0.5f;
  94     float ltt_near1 = -poly;
  95     float lt_near1 = lth_near1 + ltt_near1;
  96     float lh_near1 = -r;
  97     float l_near1 = lh_near1 + lt_near1;
  98
  99     // Computations for x not near 1
 100     int m = (int)(ax >> EXPSHIFTBITS_SP32) - EXPBIAS_SP32;
 101     float mf = (float)m;
 102     int ixs = as_int(as_float(ax | 0x3f800000) - 1.0f);
 103     float mfs = (float)((ixs >> EXPSHIFTBITS_SP32) - 253);
 104     int c = m == -127;
 105     int ixn = c ? ixs : ax;
 106     float mfn = c ? mfs : mf;
 107
 108     int indx = (ixn & 0x007f0000) + ((ixn & 0x00008000) << 1);
 109
 110     // F - Y
 111     float f = as_float(0x3f000000 | indx) - as_float(0x3f000000 | (ixn & MANTBITS_SP32));
 112
 113     indx = indx >> 16;
 114     float2 tv = USE_TABLE(log_inv_tbl_ep, indx);
 115     float rh = f * tv.s0;
 116     float rt = f * tv.s1;
 117     r = rh + rt;
 118
 119     poly = mad(r, mad(r, 0x1.0p-2f, 0x1.555556p-2f), 0x1.0p-1f) * (r*r);
 120     poly += (rh - r) + rt;
 121
 122     const float LOG2_HEAD = 0x1.62e000p-1f;  // 0.693115234
 123     const float LOG2_TAIL = 0x1.0bfbe8p-15f; // 0.0000319461833
 124     tv = USE_TABLE(loge_tbl, indx);
 125     float lth = -r;
 126     float ltt = mad(mfn, LOG2_TAIL, -poly) + tv.s1;
 127     float lt = lth + ltt;
 128     float lh = mad(mfn, LOG2_HEAD, tv.s0);
 129     float l = lh + lt;
 130
 131     // Select near 1 or not
 132     lth = near1 ? lth_near1 : lth;
 133     ltt = near1 ? ltt_near1 : ltt;
 134     lt = near1 ? lt_near1 : lt;
 135     lh = near1 ? lh_near1 : lh;
 136     l = near1 ? l_near1 : l;
 137
 138     float gh = as_float(as_int(l) & 0xfffff000);
 139     float gt = ((ltt - (lt - lth)) + ((lh - l) + lt)) + (l - gh);
 140
 141     float yh = as_float(iy & 0xfffff000);
 142
 143     float yt = y - yh;
 144
 145     float ylogx_s = mad(gt, yh, mad(gh, yt, yt*gt));
 146     float ylogx = mad(yh, gh, ylogx_s);
 147     float ylogx_t = mad(yh, gh, -ylogx) + ylogx_s;
 148
 149     // Extra precise exp of ylogx
 150     const float R_64_BY_LOG2 = 0x1.715476p+6f; // 64/log2 : 92.332482616893657
 151     int n = convert_int(ylogx * R_64_BY_LOG2);
 152     float nf = (float) n;
 153
 154     int j = n & 0x3f;
 155     m = n >> 6;
 156     int m2 = m << EXPSHIFTBITS_SP32;
 157
 158     const float R_LOG2_BY_64_LD = 0x1.620000p-7f;  // log2/64 lead: 0.0108032227
 159     const float R_LOG2_BY_64_TL = 0x1.c85fdep-16f; // log2/64 tail: 0.0000272020388
 160     r = mad(nf, -R_LOG2_BY_64_TL, mad(nf, -R_LOG2_BY_64_LD, ylogx)) + ylogx_t;
 161
 162     // Truncated Taylor series for e^r
 163     poly = mad(mad(mad(r, 0x1.555556p-5f, 0x1.555556p-3f), r, 0x1.000000p-1f), r*r, r);
 164
 165     tv = USE_TABLE(exp_tbl_ep, j);
 166
 167     float expylogx = mad(tv.s0, poly, mad(tv.s1, poly, tv.s1)) + tv.s0;
 168     float sexpylogx = expylogx * as_float(0x1 << (m + 149));
 169     float texpylogx = as_float(as_int(expylogx) + m2);
 170     expylogx = m < -125 ? sexpylogx : texpylogx;
 171
 172     // Result is +-Inf if (ylogx + ylogx_t) > 128*log2
 173     expylogx = ((ylogx > 0x1.62e430p+6f) | (ylogx == 0x1.62e430p+6f & ylogx_t > -0x1.05c610p-22f)) ? as_float(PINFBITPATT_SP32) : expylogx;
 174
 175     // Result is 0 if ylogx < -149*log2
 176     expylogx = ylogx <  -0x1.9d1da0p+6f ? 0.0f : expylogx;
 177
 178     // Classify y:
 179     //   inty = 0 means not an integer.
 180     //   inty = 1 means odd integer.
 181     //   inty = 2 means even integer.
 182
 183     int yexp = (int)(ay >> EXPSHIFTBITS_SP32) - EXPBIAS_SP32 + 1;
 184     int mask = (1 << (24 - yexp)) - 1;
 185     int yodd = ((iy >> (24 - yexp)) & 0x1) != 0;
 186     int inty = yodd ? 1 : 2;
 187     inty = (iy & mask) != 0 ? 0 : inty;
 188     inty = yexp < 1 ? 0 : inty;
 189     inty = yexp > 24 ? 2 : inty;
 190
 191     float signval = as_float((as_uint(expylogx) ^ SIGNBIT_SP32));
 192     expylogx = ((inty == 1) & !xpos) ? signval : expylogx;
 193     int ret = as_int(expylogx);
 194
 195     // Corner case handling
 196     ret = ax < 0x3f800000 & iy == NINFBITPATT_SP32 ? PINFBITPATT_SP32 : ret;
 197     ret = ax < 0x3f800000 & iy == PINFBITPATT_SP32 ? 0 : ret;
 198     ret = ax == 0x3f800000 & ay < PINFBITPATT_SP32 ? 0x3f800000 : ret;
 199     ret = ax == 0x3f800000 & ay == PINFBITPATT_SP32 ? QNANBITPATT_SP32 : ret;
 200     ret = ax > 0x3f800000 & iy == NINFBITPATT_SP32 ? 0 : ret;
 201     ret = ax > 0x3f800000 & iy == PINFBITPATT_SP32 ? PINFBITPATT_SP32 : ret;
 202     ret = ((ix < PINFBITPATT_SP32) & (ay == 0)) ? 0x3f800000 : ret;
 203     ret = ((ax == PINFBITPATT_SP32) & !ypos) ? 0 : ret;
 204     ret = ((ax == PINFBITPATT_SP32) & ypos) ? PINFBITPATT_SP32 : ret;
 205     ret = ((ax == PINFBITPATT_SP32) & (iy == PINFBITPATT_SP32)) ? PINFBITPATT_SP32 : ret;
 206     ret = ((ax == PINFBITPATT_SP32) & (ay == 0)) ? QNANBITPATT_SP32 : ret;
 207     ret = ((ax == 0) & !ypos) ? PINFBITPATT_SP32 : ret;
 208     ret = ((ax == 0) & ypos) ? 0 : ret;
 209     ret = ((ax == 0) & (ay == 0)) ? QNANBITPATT_SP32 : ret;
 210     ret = ((ax != 0) & !xpos) ? QNANBITPATT_SP32 : ret;
 211     ret = ax > PINFBITPATT_SP32 ? ix : ret;
 212     ret = ay > PINFBITPATT_SP32 ? iy : ret;
 213
 214     return as_float(ret);
 215 }
 216 _CLC_BINARY_VECTORIZE(_CLC_DEF _CLC_OVERLOAD, float, __clc_powr, float, float)
 217
 218 #ifdef cl_khr_fp64
 219 _CLC_DEF _CLC_OVERLOAD double __clc_powr(double x, double y)
 220 {
 221     const double real_log2_tail = 5.76999904754328540596e-08;
 222     const double real_log2_lead = 6.93147122859954833984e-01;
 223
 224     long ux = as_long(x);
 225     long ax = ux & (~SIGNBIT_DP64);
 226     int xpos = ax == ux;
 227
 228     long uy = as_long(y);
 229     long ay = uy & (~SIGNBIT_DP64);
 230     int ypos = ay == uy;
 231
 232     // Extended precision log
 233     double v, vt;
 234     {
 235         int exp = (int)(ax >> 52) - 1023;
 236         int mask_exp_1023 = exp == -1023;
 237         double xexp = (double) exp;
 238         long mantissa = ax & 0x000FFFFFFFFFFFFFL;
 239
 240         long temp_ux = as_long(as_double(0x3ff0000000000000L | mantissa) - 1.0);
 241         exp = ((temp_ux & 0x7FF0000000000000L) >> 52) - 2045;
 242         double xexp1 = (double) exp;
 243         long mantissa1 = temp_ux & 0x000FFFFFFFFFFFFFL;
 244
 245         xexp = mask_exp_1023 ? xexp1 : xexp;
 246         mantissa = mask_exp_1023 ? mantissa1 : mantissa;
 247
 248         long rax = (mantissa & 0x000ff00000000000) + ((mantissa & 0x0000080000000000) << 1);
 249         int index = rax >> 44;
 250
 251         double F = as_double(rax | 0x3FE0000000000000L);
 252         double Y = as_double(mantissa | 0x3FE0000000000000L);
 253         double f = F - Y;
 254         double2 tv = USE_TABLE(log_f_inv_tbl, index);
 255         double log_h = tv.s0;
 256         double log_t = tv.s1;
 257         double f_inv = (log_h + log_t) * f;
 258         double r1 = as_double(as_long(f_inv) & 0xfffffffff8000000L);
 259         double r2 = fma(-F, r1, f) * (log_h + log_t);
 260         double r = r1 + r2;
 261
 262         double poly = fma(r,
 263                           fma(r,
 264                               fma(r,
 265                                   fma(r, 1.0/7.0, 1.0/6.0),
 266                                   1.0/5.0),
 267                               1.0/4.0),
 268                           1.0/3.0);
 269         poly = poly * r * r * r;
 270
 271         double hr1r1 = 0.5*r1*r1;
 272         double poly0h = r1 + hr1r1;
 273         double poly0t = r1 - poly0h + hr1r1;
 274         poly = fma(r1, r2, fma(0.5*r2, r2, poly)) + r2 + poly0t;
 275
 276         tv = USE_TABLE(powlog_tbl, index);
 277         log_h = tv.s0;
 278         log_t = tv.s1;
 279
 280         double resT_t = fma(xexp, real_log2_tail, + log_t) - poly;
 281         double resT = resT_t - poly0h;
 282         double resH = fma(xexp, real_log2_lead, log_h);
 283         double resT_h = poly0h;
 284
 285         double H = resT + resH;
 286         double H_h = as_double(as_long(H) & 0xfffffffff8000000L);
 287         double T = (resH - H + resT) + (resT_t - (resT + resT_h)) + (H - H_h);
 288         H = H_h;
 289
 290         double y_head = as_double(uy & 0xfffffffff8000000L);
 291         double y_tail = y - y_head;
 292
 293         double temp = fma(y_tail, H, fma(y_head, T, y_tail*T));
 294         v = fma(y_head, H, temp);
 295         vt = fma(y_head, H, -v) + temp;
 296     }
 297
 298     // Now calculate exp of (v,vt)
 299
 300     double expv;
 301     {
 302         const double max_exp_arg = 709.782712893384;
 303         const double min_exp_arg = -745.1332191019411;
 304         const double sixtyfour_by_lnof2 = 92.33248261689366;
 305         const double lnof2_by_64_head = 0.010830424260348081;
 306         const double lnof2_by_64_tail = -4.359010638708991e-10;
 307
 308         double temp = v * sixtyfour_by_lnof2;
 309         int n = (int)temp;
 310         double dn = (double)n;
 311         int j = n & 0x0000003f;
 312         int m = n >> 6;
 313
 314         double2 tv = USE_TABLE(two_to_jby64_ep_tbl, j);
 315         double f1 = tv.s0;
 316         double f2 = tv.s1;
 317         double f = f1 + f2;
 318
 319         double r1 = fma(dn, -lnof2_by_64_head, v);
 320         double r2 = dn * lnof2_by_64_tail;
 321         double r = (r1 + r2) + vt;
 322
 323         double q = fma(r,
 324                        fma(r,
 325                            fma(r,
 326                                fma(r, 1.38889490863777199667e-03, 8.33336798434219616221e-03),
 327                                4.16666666662260795726e-02),
 328                            1.66666666665260878863e-01),
 329                        5.00000000000000008883e-01);
 330         q = fma(r*r, q, r);
 331
 332         expv = fma(f, q, f2) + f1;
 333               expv = ldexp(expv, m);
 334
 335         expv = v > max_exp_arg ? as_double(0x7FF0000000000000L) : expv;
 336         expv = v < min_exp_arg ? 0.0 : expv;
 337     }
 338
 339     // See whether y is an integer.
 340     // inty = 0 means not an integer.
 341     // inty = 1 means odd integer.
 342     // inty = 2 means even integer.
 343
 344     int inty;
 345     {
 346         int yexp = (int)(ay >> EXPSHIFTBITS_DP64) - EXPBIAS_DP64 + 1;
 347         inty = yexp < 1 ? 0 : 2;
 348         inty = yexp > 53 ? 2 : inty;
 349         long mask = (1L << (53 - yexp)) - 1L;
 350         int inty1 = (((ay & ~mask) >> (53 - yexp)) & 1L) == 1L ? 1 : 2;
 351         inty1 = (ay & mask) != 0 ? 0 : inty1;
 352         inty = !(yexp < 1) & !(yexp > 53) ? inty1 : inty;
 353     }
 354
 355     expv *= ((inty == 1) & !xpos) ? -1.0 : 1.0;
 356
 357     long ret = as_long(expv);
 358
 359     // Now all the edge cases
 360     ret = ax < 0x3ff0000000000000L & uy == NINFBITPATT_DP64 ? PINFBITPATT_DP64 : ret;
 361     ret = ax < 0x3ff0000000000000L & uy == PINFBITPATT_DP64 ? 0L : ret;
 362     ret = ax == 0x3ff0000000000000L & ay < PINFBITPATT_DP64 ? 0x3ff0000000000000L : ret;
 363     ret = ax == 0x3ff0000000000000L & ay == PINFBITPATT_DP64 ? QNANBITPATT_DP64 : ret;
 364     ret = ax > 0x3ff0000000000000L & uy == NINFBITPATT_DP64 ? 0L : ret;
 365     ret = ax > 0x3ff0000000000000L & uy == PINFBITPATT_DP64 ? PINFBITPATT_DP64 : ret;
 366     ret = ux < PINFBITPATT_DP64 & ay == 0L ? 0x3ff0000000000000L : ret;
 367     ret = ((ax == PINFBITPATT_DP64) & !ypos) ? 0L : ret;
 368     ret = ((ax == PINFBITPATT_DP64) & ypos) ? PINFBITPATT_DP64 : ret;
 369     ret = ((ax == PINFBITPATT_DP64) & (uy == PINFBITPATT_DP64)) ? PINFBITPATT_DP64 : ret;
 370     ret = ((ax == PINFBITPATT_DP64) & (ay == 0L)) ? QNANBITPATT_DP64 : ret;
 371     ret = ((ax == 0L) & !ypos) ? PINFBITPATT_DP64 : ret;
 372     ret = ((ax == 0L) & ypos) ? 0L : ret;
 373     ret = ((ax == 0L) & (ay == 0L)) ? QNANBITPATT_DP64 : ret;
 374     ret = ((ax != 0L) & !xpos) ? QNANBITPATT_DP64 : ret;
 375     ret = ax > PINFBITPATT_DP64 ? ux : ret;
 376     ret = ay > PINFBITPATT_DP64 ? uy : ret;
 377
 378     return as_double(ret);
 379 }
 380 _CLC_BINARY_VECTORIZE(_CLC_DEF _CLC_OVERLOAD, double, __clc_powr, double, double)
 381 #endif