llvm/projects/CMakeLists.txt

   1 # Discover the projects that use CMake in the subdirectories.
   2 # Note that explicit cmake invocation is required every time a new project is
   3 # added or removed.
   4 file(GLOB entries *)
   5 foreach(entry ${entries})
   6   if(IS_DIRECTORY ${entry} AND EXISTS ${entry}/CMakeLists.txt)
   7     if((NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/compiler-rt) AND
   8        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/dragonegg) AND
   9        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/libcxx) AND
  10        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/libcxxabi) AND
  11        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/libunwind) AND
  12        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/test-suite) AND
  13        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/openmp) AND
  14        (NOT ${entry} STREQUAL ${CMAKE_CURRENT_SOURCE_DIR}/cross-project-tests))
  15       get_filename_component(entry_name "${entry}" NAME)
  16       add_llvm_external_project(${entry_name})
  17     endif()
  18   endif()
  19 endforeach(entry)
  20
  21 # Also add in libc++ and compiler-rt trees if present (and we have
  22 # a sufficiently recent version of CMake where required).
  23 if(${LLVM_BUILD_RUNTIME})
  24   # MSVC isn't quite working with libc++ yet, disable it until issues are
  25   # fixed.
  26   # FIXME: LLVM_FORCE_BUILD_RUNTIME is currently used by libc++ to force
  27   # enable the in-tree build when targeting clang-cl.
  28   if(NOT MSVC OR LLVM_FORCE_BUILD_RUNTIME)
  29     # Add the projects in reverse order of their dependencies so that the
  30     # dependent projects can see the target names of their dependencies.
  31     add_llvm_external_project(libunwind)
  32     add_llvm_external_project(pstl)
  33     add_llvm_external_project(libc)
  34     add_llvm_external_project(libcxxabi)
  35     add_llvm_external_project(libcxx)
  36   endif()
  37   if(NOT LLVM_BUILD_EXTERNAL_COMPILER_RT)
  38     add_llvm_external_project(compiler-rt)
  39   endif()
  40 endif()
  41
  42 add_llvm_external_project(dragonegg)
  43 add_llvm_external_project(openmp)
  44
  45 if(LLVM_INCLUDE_TESTS)
  46   add_llvm_external_project(cross-project-tests)
  47 endif()