mlir/test/mlir-vulkan-runner/time.mlir

   1 // RUN: mlir-opt %s -test-vulkan-runner-pipeline \
   2 // RUN:   | mlir-vulkan-runner - --shared-libs=%vulkan-runtime-wrappers,%mlir_runner_utils --entry-point-result=void | FileCheck %s
   3
   4 // CHECK: Compute shader execution time
   5 // CHECK: Command buffer submit time
   6 // CHECK: Wait idle time
   7
   8 module attributes {
   9   gpu.container_module,
  10   spirv.target_env = #spirv.target_env<
  11     #spirv.vce<v1.0, [Shader], [SPV_KHR_storage_buffer_storage_class]>, #spirv.resource_limits<>>
  12 } {
  13   gpu.module @kernels {
  14     gpu.func @kernel_add(%arg0 : memref<16384xf32>, %arg1 : memref<16384xf32>, %arg2 : memref<16384xf32>)
  15       kernel attributes { spirv.entry_point_abi = #spirv.entry_point_abi<workgroup_size = [128, 1, 1]>} {
  16       %bid = gpu.block_id x
  17       %tid = gpu.thread_id x
  18       %cst = arith.constant 128 : index
  19       %b = arith.muli %bid, %cst : index
  20       %0 = arith.addi %b, %tid : index
  21       %1 = memref.load %arg0[%0] : memref<16384xf32>
  22       %2 = memref.load %arg1[%0] : memref<16384xf32>
  23       %3 = arith.addf %1, %2 : f32
  24       memref.store %3, %arg2[%0] : memref<16384xf32>
  25       gpu.return
  26     }
  27   }
  28
  29   func.func @main() {
  30     %arg0 = memref.alloc() : memref<16384xf32>
  31     %arg1 = memref.alloc() : memref<16384xf32>
  32     %arg2 = memref.alloc() : memref<16384xf32>
  33     %0 = arith.constant 0 : i32
  34     %1 = arith.constant 1 : i32
  35     %2 = arith.constant 2 : i32
  36     %value0 = arith.constant 0.0 : f32
  37     %value1 = arith.constant 1.1 : f32
  38     %value2 = arith.constant 2.2 : f32
  39     %arg3 = memref.cast %arg0 : memref<16384xf32> to memref<?xf32>
  40     %arg4 = memref.cast %arg1 : memref<16384xf32> to memref<?xf32>
  41     %arg5 = memref.cast %arg2 : memref<16384xf32> to memref<?xf32>
  42     call @fillResource1DFloat(%arg3, %value1) : (memref<?xf32>, f32) -> ()
  43     call @fillResource1DFloat(%arg4, %value2) : (memref<?xf32>, f32) -> ()
  44     call @fillResource1DFloat(%arg5, %value0) : (memref<?xf32>, f32) -> ()
  45
  46     %cst1 = arith.constant 1 : index
  47     %cst128 = arith.constant 128 : index
  48     gpu.launch_func @kernels::@kernel_add
  49         blocks in (%cst128, %cst1, %cst1) threads in (%cst128, %cst1, %cst1)
  50         args(%arg0 : memref<16384xf32>, %arg1 : memref<16384xf32>, %arg2 : memref<16384xf32>)
  51     %arg6 = memref.cast %arg5 : memref<?xf32> to memref<*xf32>
  52     return
  53   }
  54   func.func private @fillResource1DFloat(%0 : memref<?xf32>, %1 : f32)
  55   func.func private @printMemrefF32(%ptr : memref<*xf32>)
  56 }
  57