lib/Target/X86/X86InstrMMX.td

   1 //====- X86InstrMMX.td - Describe the X86 Instruction Set --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 MMX instruction set, defining the instructions,
  11 // and properties of the instructions which are needed for code generation,
  12 // machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // MMX Pattern Fragments
  18 //===----------------------------------------------------------------------===//
  19
  20 def load_mmx : PatFrag<(ops node:$ptr), (v1i64 (load node:$ptr))>;
  21
  22 def bc_v8i8  : PatFrag<(ops node:$in), (v8i8  (bitconvert node:$in))>;
  23 def bc_v4i16 : PatFrag<(ops node:$in), (v4i16 (bitconvert node:$in))>;
  24 def bc_v2i32 : PatFrag<(ops node:$in), (v2i32 (bitconvert node:$in))>;
  25 def bc_v1i64 : PatFrag<(ops node:$in), (v1i64 (bitconvert node:$in))>;
  26
  27 //===----------------------------------------------------------------------===//
  28 // MMX Masks
  29 //===----------------------------------------------------------------------===//
  30
  31 // MMX_SHUFFLE_get_shuf_imm xform function: convert vector_shuffle mask to
  32 // PSHUFW imm.
  33 def MMX_SHUFFLE_get_shuf_imm : SDNodeXForm<vector_shuffle, [{
  34   return getI8Imm(X86::getShuffleSHUFImmediate(N));
  35 }]>;
  36
  37 // Patterns for: vector_shuffle v1, v2, <2, 6, 3, 7, ...>
  38 def mmx_unpckh : PatFrag<(ops node:$lhs, node:$rhs),
  39                          (vector_shuffle node:$lhs, node:$rhs), [{
  40   return X86::isUNPCKHMask(cast<ShuffleVectorSDNode>(N));
  41 }]>;
  42
  43 // Patterns for: vector_shuffle v1, v2, <0, 4, 2, 5, ...>
  44 def mmx_unpckl : PatFrag<(ops node:$lhs, node:$rhs),
  45                          (vector_shuffle node:$lhs, node:$rhs), [{
  46   return X86::isUNPCKLMask(cast<ShuffleVectorSDNode>(N));
  47 }]>;
  48
  49 // Patterns for: vector_shuffle v1, <undef>, <0, 0, 1, 1, ...>
  50 def mmx_unpckh_undef : PatFrag<(ops node:$lhs, node:$rhs),
  51                                (vector_shuffle node:$lhs, node:$rhs), [{
  52   return X86::isUNPCKH_v_undef_Mask(cast<ShuffleVectorSDNode>(N));
  53 }]>;
  54
  55 // Patterns for: vector_shuffle v1, <undef>, <2, 2, 3, 3, ...>
  56 def mmx_unpckl_undef : PatFrag<(ops node:$lhs, node:$rhs),
  57                                (vector_shuffle node:$lhs, node:$rhs), [{
  58   return X86::isUNPCKL_v_undef_Mask(cast<ShuffleVectorSDNode>(N));
  59 }]>;
  60
  61 def mmx_pshufw : PatFrag<(ops node:$lhs, node:$rhs),
  62                          (vector_shuffle node:$lhs, node:$rhs), [{
  63   return X86::isPSHUFDMask(cast<ShuffleVectorSDNode>(N));
  64 }], MMX_SHUFFLE_get_shuf_imm>;
  65
  66 //===----------------------------------------------------------------------===//
  67 // MMX Multiclasses
  68 //===----------------------------------------------------------------------===//
  69
  70 let isTwoAddress = 1 in {
  71   // MMXI_binop_rm - Simple MMX binary operator.
  72   multiclass MMXI_binop_rm<bits<8> opc, string OpcodeStr, SDNode OpNode,
  73                            ValueType OpVT, bit Commutable = 0> {
  74     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
  75                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  76                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1, VR64:$src2)))]> {
  77       let isCommutable = Commutable;
  78     }
  79     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
  80                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  81                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1,
  82                                          (bitconvert
  83                                           (load_mmx addr:$src2)))))]>;
  84   }
  85
  86   multiclass MMXI_binop_rm_int<bits<8> opc, string OpcodeStr, Intrinsic IntId,
  87                                bit Commutable = 0> {
  88     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
  89                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  90                  [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]> {
  91       let isCommutable = Commutable;
  92     }
  93     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
  94                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  95                  [(set VR64:$dst, (IntId VR64:$src1,
  96                                    (bitconvert (load_mmx addr:$src2))))]>;
  97   }
  98
  99   // MMXI_binop_rm_v1i64 - Simple MMX binary operator whose type is v1i64.
 100   //
 101   // FIXME: we could eliminate this and use MMXI_binop_rm instead if tblgen knew
 102   // to collapse (bitconvert VT to VT) into its operand.
 103   //
 104   multiclass MMXI_binop_rm_v1i64<bits<8> opc, string OpcodeStr, SDNode OpNode,
 105                                  bit Commutable = 0> {
 106     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 107                                   (ins VR64:$src1, VR64:$src2),
 108                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 109                   [(set VR64:$dst, (v1i64 (OpNode VR64:$src1, VR64:$src2)))]> {
 110       let isCommutable = Commutable;
 111     }
 112     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 113                                   (ins VR64:$src1, i64mem:$src2),
 114                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 115                   [(set VR64:$dst,
 116                     (OpNode VR64:$src1,(load_mmx addr:$src2)))]>;
 117   }
 118
 119   multiclass MMXI_binop_rmi_int<bits<8> opc, bits<8> opc2, Format ImmForm,
 120                                 string OpcodeStr, Intrinsic IntId,
 121                                 Intrinsic IntId2> {
 122     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 123                                   (ins VR64:$src1, VR64:$src2),
 124                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 125                   [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]>;
 126     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 127                                   (ins VR64:$src1, i64mem:$src2),
 128                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 129                   [(set VR64:$dst, (IntId VR64:$src1,
 130                                     (bitconvert (load_mmx addr:$src2))))]>;
 131     def ri : MMXIi8<opc2, ImmForm, (outs VR64:$dst),
 132                                    (ins VR64:$src1, i32i8imm:$src2),
 133                     !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 134            [(set VR64:$dst, (IntId2 VR64:$src1, (i32 imm:$src2)))]>;
 135   }
 136 }
 137
 138 //===----------------------------------------------------------------------===//
 139 // MMX EMMS & FEMMS Instructions
 140 //===----------------------------------------------------------------------===//
 141
 142 def MMX_EMMS  : MMXI<0x77, RawFrm, (outs), (ins), "emms",  [(int_x86_mmx_emms)]>;
 143 def MMX_FEMMS : MMXI<0x0E, RawFrm, (outs), (ins), "femms", [(int_x86_mmx_femms)]>;
 144
 145 //===----------------------------------------------------------------------===//
 146 // MMX Scalar Instructions
 147 //===----------------------------------------------------------------------===//
 148
 149 // Data Transfer Instructions
 150 def MMX_MOVD64rr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 151                         "movd\t{$src, $dst|$dst, $src}",
 152                         [(set VR64:$dst, (v2i32 (scalar_to_vector GR32:$src)))]>;
 153 let canFoldAsLoad = 1, isReMaterializable = 1 in
 154 def MMX_MOVD64rm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 155                         "movd\t{$src, $dst|$dst, $src}",
 156               [(set VR64:$dst, (v2i32 (scalar_to_vector (loadi32 addr:$src))))]>;
 157 let mayStore = 1 in
 158 def MMX_MOVD64mr : MMXI<0x7E, MRMDestMem, (outs), (ins i32mem:$dst, VR64:$src),
 159                         "movd\t{$src, $dst|$dst, $src}", []>;
 160
 161 let neverHasSideEffects = 1 in
 162 def MMX_MOVD64to64rr : MMXRI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR64:$src),
 163                              "movd\t{$src, $dst|$dst, $src}",
 164                              []>;
 165
 166 let neverHasSideEffects = 1 in
 167 // These are 64 bit moves, but since the OS X assembler doesn't
 168 // recognize a register-register movq, we write them as
 169 // movd.
 170 def MMX_MOVD64from64rr : MMXRI<0x7E, MRMDestReg,
 171                                (outs GR64:$dst), (ins VR64:$src),
 172                                "movd\t{$src, $dst|$dst, $src}", []>;
 173 def MMX_MOVD64rrv164 : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR64:$src),
 174                             "movd\t{$src, $dst|$dst, $src}",
 175                             [(set VR64:$dst, (v1i64 (scalar_to_vector GR64:$src)))]>;
 176
 177 let neverHasSideEffects = 1 in
 178 def MMX_MOVQ64rr : MMXI<0x6F, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src),
 179                         "movq\t{$src, $dst|$dst, $src}", []>;
 180 let canFoldAsLoad = 1, isReMaterializable = 1, mayHaveSideEffects = 1 in
 181 def MMX_MOVQ64rm : MMXI<0x6F, MRMSrcMem, (outs VR64:$dst), (ins i64mem:$src),
 182                         "movq\t{$src, $dst|$dst, $src}",
 183                         [(set VR64:$dst, (load_mmx addr:$src))]>;
 184 def MMX_MOVQ64mr : MMXI<0x7F, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 185                         "movq\t{$src, $dst|$dst, $src}",
 186                         [(store (v1i64 VR64:$src), addr:$dst)]>;
 187
 188 def MMX_MOVDQ2Qrr : SDIi8<0xD6, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 189                           "movdq2q\t{$src, $dst|$dst, $src}",
 190                           [(set VR64:$dst,
 191                             (v1i64 (bitconvert
 192                             (i64 (vector_extract (v2i64 VR128:$src),
 193                                   (iPTR 0))))))]>;
 194
 195 def MMX_MOVQ2DQrr : SSDIi8<0xD6, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 196                            "movq2dq\t{$src, $dst|$dst, $src}",
 197           [(set VR128:$dst,
 198             (movl immAllZerosV,
 199                   (v2i64 (scalar_to_vector (i64 (bitconvert VR64:$src))))))]>;
 200
 201 let neverHasSideEffects = 1 in
 202 def MMX_MOVQ2FR64rr: SSDIi8<0xD6, MRMSrcReg, (outs FR64:$dst), (ins VR64:$src),
 203                            "movq2dq\t{$src, $dst|$dst, $src}", []>;
 204
 205 def MMX_MOVNTQmr  : MMXI<0xE7, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 206                          "movntq\t{$src, $dst|$dst, $src}",
 207                          [(int_x86_mmx_movnt_dq addr:$dst, VR64:$src)]>;
 208
 209 let AddedComplexity = 15 in
 210 // movd to MMX register zero-extends
 211 def MMX_MOVZDI2PDIrr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 212                              "movd\t{$src, $dst|$dst, $src}",
 213               [(set VR64:$dst,
 214                     (v2i32 (X86vzmovl (v2i32 (scalar_to_vector GR32:$src)))))]>;
 215 let AddedComplexity = 20 in
 216 def MMX_MOVZDI2PDIrm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 217                              "movd\t{$src, $dst|$dst, $src}",
 218           [(set VR64:$dst,
 219                 (v2i32 (X86vzmovl (v2i32
 220                                    (scalar_to_vector (loadi32 addr:$src))))))]>;
 221
 222 // Arithmetic Instructions
 223
 224 // -- Addition
 225 defm MMX_PADDB : MMXI_binop_rm<0xFC, "paddb", add, v8i8,  1>;
 226 defm MMX_PADDW : MMXI_binop_rm<0xFD, "paddw", add, v4i16, 1>;
 227 defm MMX_PADDD : MMXI_binop_rm<0xFE, "paddd", add, v2i32, 1>;
 228 defm MMX_PADDQ : MMXI_binop_rm<0xD4, "paddq", add, v1i64, 1>;
 229
 230 defm MMX_PADDSB  : MMXI_binop_rm_int<0xEC, "paddsb" , int_x86_mmx_padds_b, 1>;
 231 defm MMX_PADDSW  : MMXI_binop_rm_int<0xED, "paddsw" , int_x86_mmx_padds_w, 1>;
 232
 233 defm MMX_PADDUSB : MMXI_binop_rm_int<0xDC, "paddusb", int_x86_mmx_paddus_b, 1>;
 234 defm MMX_PADDUSW : MMXI_binop_rm_int<0xDD, "paddusw", int_x86_mmx_paddus_w, 1>;
 235
 236 // -- Subtraction
 237 defm MMX_PSUBB : MMXI_binop_rm<0xF8, "psubb", sub, v8i8>;
 238 defm MMX_PSUBW : MMXI_binop_rm<0xF9, "psubw", sub, v4i16>;
 239 defm MMX_PSUBD : MMXI_binop_rm<0xFA, "psubd", sub, v2i32>;
 240 defm MMX_PSUBQ : MMXI_binop_rm<0xFB, "psubq", sub, v1i64>;
 241
 242 defm MMX_PSUBSB  : MMXI_binop_rm_int<0xE8, "psubsb" , int_x86_mmx_psubs_b>;
 243 defm MMX_PSUBSW  : MMXI_binop_rm_int<0xE9, "psubsw" , int_x86_mmx_psubs_w>;
 244
 245 defm MMX_PSUBUSB : MMXI_binop_rm_int<0xD8, "psubusb", int_x86_mmx_psubus_b>;
 246 defm MMX_PSUBUSW : MMXI_binop_rm_int<0xD9, "psubusw", int_x86_mmx_psubus_w>;
 247
 248 // -- Multiplication
 249 defm MMX_PMULLW  : MMXI_binop_rm<0xD5, "pmullw", mul, v4i16, 1>;
 250
 251 defm MMX_PMULHW  : MMXI_binop_rm_int<0xE5, "pmulhw",  int_x86_mmx_pmulh_w,  1>;
 252 defm MMX_PMULHUW : MMXI_binop_rm_int<0xE4, "pmulhuw", int_x86_mmx_pmulhu_w, 1>;
 253 defm MMX_PMULUDQ : MMXI_binop_rm_int<0xF4, "pmuludq", int_x86_mmx_pmulu_dq, 1>;
 254
 255 // -- Miscellanea
 256 defm MMX_PMADDWD : MMXI_binop_rm_int<0xF5, "pmaddwd", int_x86_mmx_pmadd_wd, 1>;
 257
 258 defm MMX_PAVGB   : MMXI_binop_rm_int<0xE0, "pavgb", int_x86_mmx_pavg_b, 1>;
 259 defm MMX_PAVGW   : MMXI_binop_rm_int<0xE3, "pavgw", int_x86_mmx_pavg_w, 1>;
 260
 261 defm MMX_PMINUB  : MMXI_binop_rm_int<0xDA, "pminub", int_x86_mmx_pminu_b, 1>;
 262 defm MMX_PMINSW  : MMXI_binop_rm_int<0xEA, "pminsw", int_x86_mmx_pmins_w, 1>;
 263
 264 defm MMX_PMAXUB  : MMXI_binop_rm_int<0xDE, "pmaxub", int_x86_mmx_pmaxu_b, 1>;
 265 defm MMX_PMAXSW  : MMXI_binop_rm_int<0xEE, "pmaxsw", int_x86_mmx_pmaxs_w, 1>;
 266
 267 defm MMX_PSADBW  : MMXI_binop_rm_int<0xF6, "psadbw", int_x86_mmx_psad_bw, 1>;
 268
 269 // Logical Instructions
 270 defm MMX_PAND : MMXI_binop_rm_v1i64<0xDB, "pand", and, 1>;
 271 defm MMX_POR  : MMXI_binop_rm_v1i64<0xEB, "por" , or,  1>;
 272 defm MMX_PXOR : MMXI_binop_rm_v1i64<0xEF, "pxor", xor, 1>;
 273
 274 let isTwoAddress = 1 in {
 275   def MMX_PANDNrr : MMXI<0xDF, MRMSrcReg,
 276                          (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 277                          "pandn\t{$src2, $dst|$dst, $src2}",
 278                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 279                                                   VR64:$src2)))]>;
 280   def MMX_PANDNrm : MMXI<0xDF, MRMSrcMem,
 281                          (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 282                          "pandn\t{$src2, $dst|$dst, $src2}",
 283                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 284                                                   (load addr:$src2))))]>;
 285 }
 286
 287 // Shift Instructions
 288 defm MMX_PSRLW : MMXI_binop_rmi_int<0xD1, 0x71, MRM2r, "psrlw",
 289                                     int_x86_mmx_psrl_w, int_x86_mmx_psrli_w>;
 290 defm MMX_PSRLD : MMXI_binop_rmi_int<0xD2, 0x72, MRM2r, "psrld",
 291                                     int_x86_mmx_psrl_d, int_x86_mmx_psrli_d>;
 292 defm MMX_PSRLQ : MMXI_binop_rmi_int<0xD3, 0x73, MRM2r, "psrlq",
 293                                     int_x86_mmx_psrl_q, int_x86_mmx_psrli_q>;
 294
 295 defm MMX_PSLLW : MMXI_binop_rmi_int<0xF1, 0x71, MRM6r, "psllw",
 296                                     int_x86_mmx_psll_w, int_x86_mmx_pslli_w>;
 297 defm MMX_PSLLD : MMXI_binop_rmi_int<0xF2, 0x72, MRM6r, "pslld",
 298                                     int_x86_mmx_psll_d, int_x86_mmx_pslli_d>;
 299 defm MMX_PSLLQ : MMXI_binop_rmi_int<0xF3, 0x73, MRM6r, "psllq",
 300                                     int_x86_mmx_psll_q, int_x86_mmx_pslli_q>;
 301
 302 defm MMX_PSRAW : MMXI_binop_rmi_int<0xE1, 0x71, MRM4r, "psraw",
 303                                     int_x86_mmx_psra_w, int_x86_mmx_psrai_w>;
 304 defm MMX_PSRAD : MMXI_binop_rmi_int<0xE2, 0x72, MRM4r, "psrad",
 305                                     int_x86_mmx_psra_d, int_x86_mmx_psrai_d>;
 306
 307 // Shift up / down and insert zero's.
 308 def : Pat<(v1i64 (X86vshl     VR64:$src, (i8 imm:$amt))),
 309           (v1i64 (MMX_PSLLQri VR64:$src, imm:$amt))>;
 310 def : Pat<(v1i64 (X86vshr     VR64:$src, (i8 imm:$amt))),
 311           (v1i64 (MMX_PSRLQri VR64:$src, imm:$amt))>;
 312
 313 // Comparison Instructions
 314 defm MMX_PCMPEQB : MMXI_binop_rm_int<0x74, "pcmpeqb", int_x86_mmx_pcmpeq_b>;
 315 defm MMX_PCMPEQW : MMXI_binop_rm_int<0x75, "pcmpeqw", int_x86_mmx_pcmpeq_w>;
 316 defm MMX_PCMPEQD : MMXI_binop_rm_int<0x76, "pcmpeqd", int_x86_mmx_pcmpeq_d>;
 317
 318 defm MMX_PCMPGTB : MMXI_binop_rm_int<0x64, "pcmpgtb", int_x86_mmx_pcmpgt_b>;
 319 defm MMX_PCMPGTW : MMXI_binop_rm_int<0x65, "pcmpgtw", int_x86_mmx_pcmpgt_w>;
 320 defm MMX_PCMPGTD : MMXI_binop_rm_int<0x66, "pcmpgtd", int_x86_mmx_pcmpgt_d>;
 321
 322 // Conversion Instructions
 323
 324 // -- Unpack Instructions
 325 let isTwoAddress = 1 in {
 326   // Unpack High Packed Data Instructions
 327   def MMX_PUNPCKHBWrr : MMXI<0x68, MRMSrcReg,
 328                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 329                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 330                              [(set VR64:$dst,
 331                                (v8i8 (mmx_unpckh VR64:$src1, VR64:$src2)))]>;
 332   def MMX_PUNPCKHBWrm : MMXI<0x68, MRMSrcMem,
 333                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 334                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 335                              [(set VR64:$dst,
 336                                (v8i8 (mmx_unpckh VR64:$src1,
 337                                       (bc_v8i8 (load_mmx addr:$src2)))))]>;
 338
 339   def MMX_PUNPCKHWDrr : MMXI<0x69, MRMSrcReg,
 340                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 341                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 342                              [(set VR64:$dst,
 343                                (v4i16 (mmx_unpckh VR64:$src1, VR64:$src2)))]>;
 344   def MMX_PUNPCKHWDrm : MMXI<0x69, MRMSrcMem,
 345                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 346                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 347                              [(set VR64:$dst,
 348                                (v4i16 (mmx_unpckh VR64:$src1,
 349                                        (bc_v4i16 (load_mmx addr:$src2)))))]>;
 350
 351   def MMX_PUNPCKHDQrr : MMXI<0x6A, MRMSrcReg,
 352                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 353                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 354                              [(set VR64:$dst,
 355                                (v2i32 (mmx_unpckh VR64:$src1, VR64:$src2)))]>;
 356   def MMX_PUNPCKHDQrm : MMXI<0x6A, MRMSrcMem,
 357                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 358                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 359                              [(set VR64:$dst,
 360                                (v2i32 (mmx_unpckh VR64:$src1,
 361                                        (bc_v2i32 (load_mmx addr:$src2)))))]>;
 362
 363   // Unpack Low Packed Data Instructions
 364   def MMX_PUNPCKLBWrr : MMXI<0x60, MRMSrcReg,
 365                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 366                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 367                              [(set VR64:$dst,
 368                                (v8i8 (mmx_unpckl VR64:$src1, VR64:$src2)))]>;
 369   def MMX_PUNPCKLBWrm : MMXI<0x60, MRMSrcMem,
 370                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 371                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 372                              [(set VR64:$dst,
 373                                (v8i8 (mmx_unpckl VR64:$src1,
 374                                       (bc_v8i8 (load_mmx addr:$src2)))))]>;
 375
 376   def MMX_PUNPCKLWDrr : MMXI<0x61, MRMSrcReg,
 377                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 378                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 379                              [(set VR64:$dst,
 380                                (v4i16 (mmx_unpckl VR64:$src1, VR64:$src2)))]>;
 381   def MMX_PUNPCKLWDrm : MMXI<0x61, MRMSrcMem,
 382                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 383                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 384                              [(set VR64:$dst,
 385                                (v4i16 (mmx_unpckl VR64:$src1,
 386                                        (bc_v4i16 (load_mmx addr:$src2)))))]>;
 387
 388   def MMX_PUNPCKLDQrr : MMXI<0x62, MRMSrcReg,
 389                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 390                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 391                              [(set VR64:$dst,
 392                                (v2i32 (mmx_unpckl VR64:$src1, VR64:$src2)))]>;
 393   def MMX_PUNPCKLDQrm : MMXI<0x62, MRMSrcMem,
 394                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 395                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 396                              [(set VR64:$dst,
 397                                (v2i32 (mmx_unpckl VR64:$src1,
 398                                        (bc_v2i32 (load_mmx addr:$src2)))))]>;
 399 }
 400
 401 // -- Pack Instructions
 402 defm MMX_PACKSSWB : MMXI_binop_rm_int<0x63, "packsswb", int_x86_mmx_packsswb>;
 403 defm MMX_PACKSSDW : MMXI_binop_rm_int<0x6B, "packssdw", int_x86_mmx_packssdw>;
 404 defm MMX_PACKUSWB : MMXI_binop_rm_int<0x67, "packuswb", int_x86_mmx_packuswb>;
 405
 406 // -- Shuffle Instructions
 407 def MMX_PSHUFWri : MMXIi8<0x70, MRMSrcReg,
 408                           (outs VR64:$dst), (ins VR64:$src1, i8imm:$src2),
 409                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 410                           [(set VR64:$dst,
 411                             (v4i16 (mmx_pshufw:$src2 VR64:$src1, (undef))))]>;
 412 def MMX_PSHUFWmi : MMXIi8<0x70, MRMSrcMem,
 413                           (outs VR64:$dst), (ins i64mem:$src1, i8imm:$src2),
 414                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 415                           [(set VR64:$dst,
 416                             (mmx_pshufw:$src2 (bc_v4i16 (load_mmx addr:$src1)),
 417                                               (undef)))]>;
 418
 419 // -- Conversion Instructions
 420 let neverHasSideEffects = 1 in {
 421 def MMX_CVTPD2PIrr  : MMX2I<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 422                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 423 let mayLoad = 1 in
 424 def MMX_CVTPD2PIrm  : MMX2I<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f128mem:$src),
 425                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 426
 427 def MMX_CVTPI2PDrr  : MMX2I<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 428                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 429 let mayLoad = 1 in
 430 def MMX_CVTPI2PDrm  : MMX2I<0x2A, MRMSrcMem, (outs VR128:$dst), (ins i64mem:$src),
 431                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 432
 433 def MMX_CVTPI2PSrr  : MMXI<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 434                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 435 let mayLoad = 1 in
 436 def MMX_CVTPI2PSrm  : MMXI<0x2A, MRMSrcMem, (outs VR128:$dst), (ins i64mem:$src),
 437                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 438
 439 def MMX_CVTPS2PIrr  : MMXI<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 440                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 441 let mayLoad = 1 in
 442 def MMX_CVTPS2PIrm  : MMXI<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 443                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 444
 445 def MMX_CVTTPD2PIrr : MMX2I<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 446                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 447 let mayLoad = 1 in
 448 def MMX_CVTTPD2PIrm : MMX2I<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f128mem:$src),
 449                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 450
 451 def MMX_CVTTPS2PIrr : MMXI<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 452                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 453 let mayLoad = 1 in
 454 def MMX_CVTTPS2PIrm : MMXI<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 455                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 456 } // end neverHasSideEffects
 457
 458
 459 // Extract / Insert
 460 def MMX_X86pextrw : SDNode<"X86ISD::PEXTRW", SDTypeProfile<1, 2, []>, []>;
 461 def MMX_X86pinsrw : SDNode<"X86ISD::PINSRW", SDTypeProfile<1, 3, []>, []>;
 462
 463 def MMX_PEXTRWri  : MMXIi8<0xC5, MRMSrcReg,
 464                            (outs GR32:$dst), (ins VR64:$src1, i16i8imm:$src2),
 465                            "pextrw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 466                            [(set GR32:$dst, (MMX_X86pextrw (v4i16 VR64:$src1),
 467                                              (iPTR imm:$src2)))]>;
 468 let isTwoAddress = 1 in {
 469   def MMX_PINSRWrri : MMXIi8<0xC4, MRMSrcReg,
 470                       (outs VR64:$dst), (ins VR64:$src1, GR32:$src2, i16i8imm:$src3),
 471                       "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 472                       [(set VR64:$dst, (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 473                                                GR32:$src2, (iPTR imm:$src3))))]>;
 474   def MMX_PINSRWrmi : MMXIi8<0xC4, MRMSrcMem,
 475                      (outs VR64:$dst), (ins VR64:$src1, i16mem:$src2, i16i8imm:$src3),
 476                      "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 477                      [(set VR64:$dst,
 478                        (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 479                                (i32 (anyext (loadi16 addr:$src2))),
 480                                (iPTR imm:$src3))))]>;
 481 }
 482
 483 // Mask creation
 484 def MMX_PMOVMSKBrr : MMXI<0xD7, MRMSrcReg, (outs GR32:$dst), (ins VR64:$src),
 485                           "pmovmskb\t{$src, $dst|$dst, $src}",
 486                           [(set GR32:$dst, (int_x86_mmx_pmovmskb VR64:$src))]>;
 487
 488 // Misc.
 489 let Uses = [EDI] in
 490 def MMX_MASKMOVQ : MMXI<0xF7, MRMSrcReg, (outs), (ins VR64:$src, VR64:$mask),
 491                         "maskmovq\t{$mask, $src|$src, $mask}",
 492                         [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, EDI)]>;
 493 let Uses = [RDI] in
 494 def MMX_MASKMOVQ64: MMXI64<0xF7, MRMSrcReg, (outs), (ins VR64:$src, VR64:$mask),
 495                            "maskmovq\t{$mask, $src|$src, $mask}",
 496                            [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, RDI)]>;
 497
 498 //===----------------------------------------------------------------------===//
 499 // Alias Instructions
 500 //===----------------------------------------------------------------------===//
 501
 502 // Alias instructions that map zero vector to pxor.
 503 let isReMaterializable = 1 in {
 504   def MMX_V_SET0       : MMXI<0xEF, MRMInitReg, (outs VR64:$dst), (ins),
 505                               "pxor\t$dst, $dst",
 506                               [(set VR64:$dst, (v2i32 immAllZerosV))]>;
 507   def MMX_V_SETALLONES : MMXI<0x76, MRMInitReg, (outs VR64:$dst), (ins),
 508                               "pcmpeqd\t$dst, $dst",
 509                               [(set VR64:$dst, (v2i32 immAllOnesV))]>;
 510 }
 511
 512 let Predicates = [HasMMX] in {
 513   def : Pat<(v1i64 immAllZerosV), (MMX_V_SET0)>;
 514   def : Pat<(v4i16 immAllZerosV), (MMX_V_SET0)>;
 515   def : Pat<(v8i8  immAllZerosV), (MMX_V_SET0)>;
 516 }
 517
 518 //===----------------------------------------------------------------------===//
 519 // Non-Instruction Patterns
 520 //===----------------------------------------------------------------------===//
 521
 522 // Store 64-bit integer vector values.
 523 def : Pat<(store (v8i8  VR64:$src), addr:$dst),
 524           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 525 def : Pat<(store (v4i16 VR64:$src), addr:$dst),
 526           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 527 def : Pat<(store (v2i32 VR64:$src), addr:$dst),
 528           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 529 def : Pat<(store (v2f32 VR64:$src), addr:$dst),
 530           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 531 def : Pat<(store (v1i64 VR64:$src), addr:$dst),
 532           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 533
 534 // Bit convert.
 535 def : Pat<(v8i8  (bitconvert (v1i64 VR64:$src))), (v8i8  VR64:$src)>;
 536 def : Pat<(v8i8  (bitconvert (v2i32 VR64:$src))), (v8i8  VR64:$src)>;
 537 def : Pat<(v8i8  (bitconvert (v2f32 VR64:$src))), (v8i8  VR64:$src)>;
 538 def : Pat<(v8i8  (bitconvert (v4i16 VR64:$src))), (v8i8  VR64:$src)>;
 539 def : Pat<(v4i16 (bitconvert (v1i64 VR64:$src))), (v4i16 VR64:$src)>;
 540 def : Pat<(v4i16 (bitconvert (v2i32 VR64:$src))), (v4i16 VR64:$src)>;
 541 def : Pat<(v4i16 (bitconvert (v2f32 VR64:$src))), (v4i16 VR64:$src)>;
 542 def : Pat<(v4i16 (bitconvert (v8i8  VR64:$src))), (v4i16 VR64:$src)>;
 543 def : Pat<(v2i32 (bitconvert (v1i64 VR64:$src))), (v2i32 VR64:$src)>;
 544 def : Pat<(v2i32 (bitconvert (v2f32 VR64:$src))), (v2i32 VR64:$src)>;
 545 def : Pat<(v2i32 (bitconvert (v4i16 VR64:$src))), (v2i32 VR64:$src)>;
 546 def : Pat<(v2i32 (bitconvert (v8i8  VR64:$src))), (v2i32 VR64:$src)>;
 547 def : Pat<(v2f32 (bitconvert (v1i64 VR64:$src))), (v2f32 VR64:$src)>;
 548 def : Pat<(v2f32 (bitconvert (v2i32 VR64:$src))), (v2f32 VR64:$src)>;
 549 def : Pat<(v2f32 (bitconvert (v4i16 VR64:$src))), (v2f32 VR64:$src)>;
 550 def : Pat<(v2f32 (bitconvert (v8i8  VR64:$src))), (v2f32 VR64:$src)>;
 551 def : Pat<(v1i64 (bitconvert (v2i32 VR64:$src))), (v1i64 VR64:$src)>;
 552 def : Pat<(v1i64 (bitconvert (v2f32 VR64:$src))), (v1i64 VR64:$src)>;
 553 def : Pat<(v1i64 (bitconvert (v4i16 VR64:$src))), (v1i64 VR64:$src)>;
 554 def : Pat<(v1i64 (bitconvert (v8i8  VR64:$src))), (v1i64 VR64:$src)>;
 555
 556 // 64-bit bit convert.
 557 def : Pat<(v1i64 (bitconvert (i64 GR64:$src))),
 558           (MMX_MOVD64to64rr GR64:$src)>;
 559 def : Pat<(v2i32 (bitconvert (i64 GR64:$src))),
 560           (MMX_MOVD64to64rr GR64:$src)>;
 561 def : Pat<(v2f32 (bitconvert (i64 GR64:$src))),
 562           (MMX_MOVD64to64rr GR64:$src)>;
 563 def : Pat<(v4i16 (bitconvert (i64 GR64:$src))),
 564           (MMX_MOVD64to64rr GR64:$src)>;
 565 def : Pat<(v8i8  (bitconvert (i64 GR64:$src))),
 566           (MMX_MOVD64to64rr GR64:$src)>;
 567 def : Pat<(i64 (bitconvert (v1i64 VR64:$src))),
 568           (MMX_MOVD64from64rr VR64:$src)>;
 569 def : Pat<(i64 (bitconvert (v2i32 VR64:$src))),
 570           (MMX_MOVD64from64rr VR64:$src)>;
 571 def : Pat<(i64 (bitconvert (v2f32 VR64:$src))),
 572           (MMX_MOVD64from64rr VR64:$src)>;
 573 def : Pat<(i64 (bitconvert (v4i16 VR64:$src))),
 574           (MMX_MOVD64from64rr VR64:$src)>;
 575 def : Pat<(i64  (bitconvert (v8i8 VR64:$src))),
 576           (MMX_MOVD64from64rr VR64:$src)>;
 577 def : Pat<(f64 (bitconvert (v1i64 VR64:$src))),
 578           (MMX_MOVQ2FR64rr VR64:$src)>;
 579 def : Pat<(f64 (bitconvert (v2i32 VR64:$src))),
 580           (MMX_MOVQ2FR64rr VR64:$src)>;
 581 def : Pat<(f64 (bitconvert (v4i16 VR64:$src))),
 582           (MMX_MOVQ2FR64rr VR64:$src)>;
 583 def : Pat<(f64 (bitconvert (v8i8 VR64:$src))),
 584           (MMX_MOVQ2FR64rr VR64:$src)>;
 585
 586 let AddedComplexity = 20 in {
 587   def : Pat<(v2i32 (X86vzmovl (bc_v2i32 (load_mmx addr:$src)))),
 588             (MMX_MOVZDI2PDIrm addr:$src)>;
 589 }
 590
 591 // Clear top half.
 592 let AddedComplexity = 15 in {
 593   def : Pat<(v2i32 (X86vzmovl VR64:$src)),
 594             (MMX_PUNPCKLDQrr VR64:$src, (MMX_V_SET0))>;
 595 }
 596
 597 // Patterns to perform canonical versions of vector shuffling.
 598 let AddedComplexity = 10 in {
 599   def : Pat<(v8i8  (mmx_unpckl_undef VR64:$src, (undef))),
 600             (MMX_PUNPCKLBWrr VR64:$src, VR64:$src)>;
 601   def : Pat<(v4i16 (mmx_unpckl_undef VR64:$src, (undef))),
 602             (MMX_PUNPCKLWDrr VR64:$src, VR64:$src)>;
 603   def : Pat<(v2i32 (mmx_unpckl_undef VR64:$src, (undef))),
 604             (MMX_PUNPCKLDQrr VR64:$src, VR64:$src)>;
 605 }
 606
 607 let AddedComplexity = 10 in {
 608   def : Pat<(v8i8  (mmx_unpckh_undef VR64:$src, (undef))),
 609             (MMX_PUNPCKHBWrr VR64:$src, VR64:$src)>;
 610   def : Pat<(v4i16 (mmx_unpckh_undef VR64:$src, (undef))),
 611             (MMX_PUNPCKHWDrr VR64:$src, VR64:$src)>;
 612   def : Pat<(v2i32 (mmx_unpckh_undef VR64:$src, (undef))),
 613             (MMX_PUNPCKHDQrr VR64:$src, VR64:$src)>;
 614 }
 615
 616 // Patterns to perform vector shuffling with a zeroed out vector.
 617 let AddedComplexity = 20 in {
 618   def : Pat<(bc_v2i32 (mmx_unpckl immAllZerosV,
 619                        (v2i32 (scalar_to_vector (load_mmx addr:$src))))),
 620             (MMX_PUNPCKLDQrm VR64:$src, VR64:$src)>;
 621 }
 622
 623 // Some special case PANDN patterns.
 624 // FIXME: Get rid of these.
 625 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 626                   VR64:$src2)),
 627           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 628 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 629                   VR64:$src2)),
 630           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 631 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 632                   VR64:$src2)),
 633           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 634
 635 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 636                   (load addr:$src2))),
 637           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 638 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 639                   (load addr:$src2))),
 640           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 641 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 642                   (load addr:$src2))),
 643           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 644
 645 // Move MMX to lower 64-bit of XMM
 646 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v8i8 VR64:$src))))),
 647           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 648 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v4i16 VR64:$src))))),
 649           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 650 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v2i32 VR64:$src))))),
 651           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 652 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert (v1i64 VR64:$src))))),
 653           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 654
 655 // Move lower 64-bit of XMM to MMX.
 656 def : Pat<(v2i32 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 657                                                   (iPTR 0))))),
 658           (v2i32 (MMX_MOVDQ2Qrr VR128:$src))>;
 659 def : Pat<(v4i16 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 660                                                   (iPTR 0))))),
 661           (v4i16 (MMX_MOVDQ2Qrr VR128:$src))>;
 662 def : Pat<(v8i8 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 663                                                   (iPTR 0))))),
 664           (v8i8 (MMX_MOVDQ2Qrr VR128:$src))>;
 665
 666 // Patterns for vector comparisons
 667 def : Pat<(v8i8 (X86pcmpeqb VR64:$src1, VR64:$src2)),
 668           (MMX_PCMPEQBrr VR64:$src1, VR64:$src2)>;
 669 def : Pat<(v8i8 (X86pcmpeqb VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 670           (MMX_PCMPEQBrm VR64:$src1, addr:$src2)>;
 671 def : Pat<(v4i16 (X86pcmpeqw VR64:$src1, VR64:$src2)),
 672           (MMX_PCMPEQWrr VR64:$src1, VR64:$src2)>;
 673 def : Pat<(v4i16 (X86pcmpeqw VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 674           (MMX_PCMPEQWrm VR64:$src1, addr:$src2)>;
 675 def : Pat<(v2i32 (X86pcmpeqd VR64:$src1, VR64:$src2)),
 676           (MMX_PCMPEQDrr VR64:$src1, VR64:$src2)>;
 677 def : Pat<(v2i32 (X86pcmpeqd VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 678           (MMX_PCMPEQDrm VR64:$src1, addr:$src2)>;
 679
 680 def : Pat<(v8i8 (X86pcmpgtb VR64:$src1, VR64:$src2)),
 681           (MMX_PCMPGTBrr VR64:$src1, VR64:$src2)>;
 682 def : Pat<(v8i8 (X86pcmpgtb VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 683           (MMX_PCMPGTBrm VR64:$src1, addr:$src2)>;
 684 def : Pat<(v4i16 (X86pcmpgtw VR64:$src1, VR64:$src2)),
 685           (MMX_PCMPGTWrr VR64:$src1, VR64:$src2)>;
 686 def : Pat<(v4i16 (X86pcmpgtw VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 687           (MMX_PCMPGTWrm VR64:$src1, addr:$src2)>;
 688 def : Pat<(v2i32 (X86pcmpgtd VR64:$src1, VR64:$src2)),
 689           (MMX_PCMPGTDrr VR64:$src1, VR64:$src2)>;
 690 def : Pat<(v2i32 (X86pcmpgtd VR64:$src1, (bitconvert (load_mmx addr:$src2)))),
 691           (MMX_PCMPGTDrm VR64:$src1, addr:$src2)>;
 692
 693 // CMOV* - Used to implement the SELECT DAG operation.  Expanded by the
 694 // scheduler into a branch sequence.
 695 // These are expanded by the scheduler.
 696 let Uses = [EFLAGS], usesCustomDAGSchedInserter = 1 in {
 697   def CMOV_V1I64 : I<0, Pseudo,
 698                     (outs VR64:$dst), (ins VR64:$t, VR64:$f, i8imm:$cond),
 699                     "#CMOV_V1I64 PSEUDO!",
 700                     [(set VR64:$dst,
 701                       (v1i64 (X86cmov VR64:$t, VR64:$f, imm:$cond,
 702                                           EFLAGS)))]>;
 703 }