src/set_lang.vbs

   1 '******************************************************
   2 '*                                                    *
   3 '*  set_lang.vbs  -- sets LANG environment variable   *
   4 '*                   according to current locale      *
   5 '*                                                    *
   6 '*  > cscript //nologo set_lang.vbs                   *
   7 '*                                                    *
   8 '******************************************************
   9
  10 LCID = GetLocale
  11
  12 CC=""
  13
  14 Select Case LCID
  15   ' English
  16   Case 1033, 2057, 3081, 10249, 4105, 9225, 15369, 16393, 14345, _
  17        6153, 8201, 17417, 5129, 13321, 18441, 7177, 11273, 12297
  18     CC="en"
  19
  20   ' Spanish
  21   Case 1034, 3082, 11274, 16394, 13322, 9226, 5130, 7178, 12298, _
  22        17418, 4106, 18442, 58378, 2058, 19466, 6154, 15370, 10250, _
  23        20490, 21514, 14346, 8202
  24     CC="es"
  25
  26   ' Portuguese
  27   Case 1046, 2070
  28     CC="pt"
  29
  30   ' German
  31   Case 1031, 3079, 5127, 4103, 2055
  32     CC="de"
  33
  34   ' Franch
  35   Case 1036, 2060, 11276, 3084, 9228, 12300, 15372, 5132, 13324, 6156, _
  36        14348, 58380, 8204, 10252, 4108, 7180, 1122
  37     CC="fr"
  38
  39   ' Italian
  40   Case 1040, 2064
  41     CC="it"
  42
  43   ' Russian
  44   Case 1049, 2073
  45     CC="ru"
  46
  47 End Select
  48
  49 '------------------------------------------------------------------------------------------------------------------
  50 '
  51 '  Types of environment:
  52 '
  53 '    SYSTEM   - Applies to all users of the computer and is saved between logoffs and restarts
  54 '                HKLM\System\CurrentControlSet\Control\Session Manager\Environment
  55 '
  56 '    USER     - Applies to the user currently logged on to the computer and is saved between logoffs and restarts
  57 '                HKCU\Environment
  58 '
  59 '    VOLATILE - Applies to current logon session and is not saved between logoffs and restarts
  60 '                HKCU\VolatileEnvironment
  61 '
  62 '    PROCESS  - Applies to current process and might be passed to child processes
  63 '                Not stored in the registry
  64 '
  65 '-----------------------------------------------------------------------------------------------------------------
  66
  67 If CC<>"" Then
  68   Set WS = CreateObject("WScript.Shell")
  69   Set WPE = WS.Environment("VOLATILE")
  70   WPE("LANG") = CC
  71 End if
  72