common/lib/libc/arch/vax/gen/urem.S

   1 /*-
   2  * Copyright (c) 1991, 1993
   3  *      The Regents of the University of California.  All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * Donn Seeley at UUNET Technologies, Inc.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  */
  32
  33 #if defined(LIBC_SCCS) && !defined(lint)
  34         /* .asciz "@(#)urem.s   8.1 (Berkeley) 6/4/93" */
  35         .asciz "$NetBSD: urem.S,v 1.2 2005/12/24 08:33:32 matt Exp $"
  36 #endif /* LIBC_SCCS and not lint */
  37
  38 #include <machine/asm.h>
  39
  40 /*
  41  * Unsigned modulus, PCC flavor.
  42  * urem() takes an ordinary dividend/divisor pair;
  43  * aurem() takes a pointer to a dividend and an ordinary divisor.
  44  */
  45
  46 #define DIVIDEND        4(%ap)
  47 #define DIVISOR         8(%ap)
  48
  49 #ifdef __ELF__
  50 ASENTRY(__urem,0)
  51 #else
  52 ASENTRY(urem,0)
  53 #endif
  54         movl    DIVISOR,%r2
  55         jlss    Leasy           # big divisor: settle by comparison
  56         movl    DIVIDEND,%r0
  57         jlss    Lhard           # big dividend: need extended division
  58         divl3   %r2,%r0,%r1     # small divisor and dividend: signed modulus
  59         mull2   %r2,%r1
  60         subl2   %r1,%r0
  61         ret
  62 Lhard:
  63         clrl    %r1
  64         ediv    %r2,%r0,%r1,%r0
  65         ret
  66 Leasy:
  67         subl3   %r2,DIVIDEND,%r0
  68         jcc     Ldifference     # if divisor goes in once, return difference
  69         movl    DIVIDEND,%r0    # if divisor is bigger, return dividend
  70 Ldifference:
  71         ret
  72
  73 #ifdef __ELF__
  74 ASENTRY(__aurem,0)
  75 #else
  76 ASENTRY(aurem,0)
  77 #endif
  78         movl    DIVIDEND,%r3
  79         movl    DIVISOR,%r2
  80         jlss    La_easy         # big divisor: settle by comparison
  81         movl    (%r3),%r0
  82         jlss    La_hard         # big dividend: need extended division
  83         divl3   %r2,%r0,%r1     # small divisor and dividend: signed modulus
  84         mull2   %r2,%r1
  85         subl2   %r1,%r0
  86         movl    %r0,(%r3)               # leave the value of the assignment in %r0
  87         ret
  88 La_hard:
  89         clrl    %r1
  90         ediv    %r2,%r0,%r1,%r0
  91         movl    %r0,(%r3)
  92         ret
  93 La_easy:
  94         subl3   %r2,(%r3),%r0
  95         jcs     La_dividend     # if divisor is bigger, leave dividend alone
  96         movl    %r0,(%r3)               # if divisor goes in once, store difference
  97         ret
  98 La_dividend:
  99         movl    (%r3),%r0
 100         ret