common/lib/libc/arch/sh3/string/ffs.S

   1 /*      $NetBSD: ffs.S,v 1.2 2008/04/28 20:22:52 martin Exp $   */
   2
   3 /*-
   4  * Copyright (c) 2002 The NetBSD Foundation, Inc.
   5  * All rights reserved.
   6  *
   7  * This code is derived from software contributed to The NetBSD Foundation
   8  * by ITOH Yasufumi.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  20  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  21  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  22  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  23  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  24  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  25  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  26  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  27  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  28  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  29  * POSSIBILITY OF SUCH DAMAGE.
  30  */
  31
  32 #include <machine/asm.h>
  33
  34 #if defined(LIBC_SCCS) && !defined(lint)
  35         RCSID("$NetBSD: ffs.S,v 1.2 2008/04/28 20:22:52 martin Exp $")
  36 #endif
  37
  38 /*
  39  * ffs - find first bit set
  40  *
  41  * This code makes use of ``test 8bit'' and ``shift 8bit'' instructions.
  42  * The remaining 8bit is tested in every 2bit.
  43  */
  44
  45 ENTRY(ffs)
  46         mov     r4,r0           ! using r0 specific instructions
  47         tst     #0xff,r0
  48         bf/s    L8bit
  49         mov     #0+1,r1         ! ret = 1..8
  50
  51         tst     r0,r0           ! ffs(0) is 0
  52         bt      Lzero           ! testing here to accelerate ret=1..8 cases
  53
  54         shlr8   r0
  55         tst     #0xff,r0
  56         bf/s    L8bit
  57         mov     #8+1,r1         ! ret = 9..16
  58
  59         shlr8   r0
  60         tst     #0xff,r0
  61         bf/s    L8bit
  62         mov     #16+1,r1        ! ret = 17..24
  63
  64         shlr8   r0
  65         mov     #24+1,r1        ! ret = 25..32
  66
  67 L8bit:
  68         tst     #0x0f,r0
  69         bt      4f
  70
  71         tst     #0x03,r0
  72         bt      2f
  73         tst     #0x01,r0        ! not bit 0 -> T
  74         mov     #0,r0
  75         rts
  76          addc   r1,r0           ! 0 + r1 + T -> r0
  77
  78 2:      tst     #0x04,r0
  79         mov     #2,r0
  80         rts
  81          addc   r1,r0
  82
  83 4:      tst     #0x30,r0
  84         bt      6f
  85         tst     #0x10,r0
  86         mov     #4,r0
  87         rts
  88          addc   r1,r0
  89
  90 6:      tst     #0x40,r0
  91         mov     #6,r0
  92         rts
  93          addc   r1,r0
  94
  95 Lzero:  rts
  96          nop